Résolu - 1ère cellule vide avec Index

[Calvus]

Bonjour à tous,

J'ai l'habitude d'établir des listes sans doublons avec Index.

INDEX($A$1:$A$30;MIN(SI(ESTTEXTE(Cat_1);SI(NB.SI(H2:H$2;Cat_1)=0;LIGNE(Cat_1)))))&""

Or cela ne fonctionne correctement que si la 1ère cellule de la BD est vide.

J'ai donc adapté la formule pour contourner le problème avec une condition

SI(INDEX($A$1:$A$30;MIN(SI(ESTTEXTE(Cat_1);SI(NB.SI(I2:I$2;Cat_1)=0;LIGNE(Cat_1)))))&""="toto";"";INDEX($A$1:$A$30;MIN(SI(ESTTEXTE(Cat_1);SI(NB.SI(I2:I$2;Cat_1)=0;LIGNE(Cat_1))))))&""

Y a t'il un autre moyen (formule plus courte) pour éviter la répétition du titre de colonne ?
Vous avez une idée de ce qui coince ?

J'ai mis les 3 exemples sur le fichier

1. Liste titre redondant
2. Liste formule bricolée
3. Liste 1ère cellule vide

Ce que j'aimerais évidemment, si c'est possible, c'est avoir ma 1ère formule avec aucune ligne vide.

Merci

 

[R@chid]

Re : 1ère cellule vide avec Index

Bonjour,
en L2 :

=SIERREUR(DECALER(Cat_1;EQUIV(0;NB.SI(L$1:L1;Cat_1);0)-1;;1)&"";"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas


@ + +

 

[Calvus]

Re : 1ère cellule vide avec Index

Bonjour Rachid,

Merci. Parfait comme d'habitude. Je n'ai plus qu'à bien analyser la formule.
Bonne journée.

 

[Calvus]

Re : 1ère cellule vide avec Index

Re,

J'ai parlé trop vite.
La formule ne fonctionne pas si on a des lignes vides en Col A. J'aurais dû en mettre dans mon exemple.
Merci

 

[R@chid]

Re : 1ère cellule vide avec Index

Re,
en L2 :

=SIERREUR(INDEX(Cat_1;PETITE.VALEUR(SI((Cat_1<>"")*(NB.SI(L$1:L1;Cat_1)=0);LIGNE(INDIRECT("1:"&LIGNES(Cat_1))));1));"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas


@ + +

 

[Calvus]

Re : 1ère cellule vide avec Index

Re,

Merci. Impeccable !

Bonne journée