Reconnaitre des dates et les séparées par une lign

[crapoto]

Bonjours à tout le forum

voici ce qui me dirige vers votre aide
J'ai un tableau avec en colonne A des dates
Je voudrait essayer de les séparer par une ligne qui indique le mois.
Je joint un fichier pour plus de clarté ;-)

Je vous remercie de vous etre arreter sur mon probleme
A+ [file name=mois.zip size=2118]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/mois.zip[/file]

 

[myDearFriend!]

Bonsoir crapoto,

Ci-joint une tentative pour répondre à ton problème...

J'ai utilisé le code ci-dessous :

Sub Traitement()
Dim TabTemp As Variant
Dim D As Date
Dim L As Long
      With ActiveSheet
            'Charge les données dans un tableau variant temporaire
            L = .Range('A65536').End(xlUp).Row
            TabTemp = .Range(.Cells(1, 1), .Cells(L, 1)).Value
            'Date de référence = dernière date du tableau
            D = TabTemp(L, 1)
            'On parcourt chaque ligne en partant de la fin
            For L = UBound(TabTemp, 1) To 1 Step -1
                  'Si c'est une date
                  If IsDate(TabTemp(L, 1)) Then
                        'Si Mois de référence <> Mois en cours de lecture
                        If Month(D) <> Month(TabTemp(L, 1)) Then
                              'On insère une ligne
                              InsereLigne L + 1, D
                              'On redéfinit la date de référence
                              D = TabTemp(L, 1)
                        End If
                  Else
                        InsereLigne L + 1, D
                        Exit For
                  End If
            Next L
            'S'il n'y a pas de ligne de titre (dates commencent en ligne 1)
            If L = 0 Then InsereLigne 1, D
      End With
End Sub

Sub InsereLigne(Lig As Long, M As Date)
      With ActiveSheet
            'Insertion de la ligne
            .Rows(Lig).Insert
            'Cellules grisées
            .Range(.Cells(Lig, 1), .Cells(Lig, 10)).Interior.ColorIndex = 15
            'Mois
            .Cells(Lig, 1).Value = Application.WorksheetFunction.Proper(Format(M, 'mmmm yyyy'))
      End With
End Sub

Cordialement, [file name=mDF_mois.zip size=12451]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/mDF_mois.zip[/file]

 

[Philippe]

Re:Reconnaitre des dates et les séparées par une l

Salut les amis,

ci joint ton fichier avec un séparateur de dates, bien sur si tu étends ta plage, tu adaptes dans le code

A +
Philippe [file name=mois2xls.zip size=13724]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/mois2xls.zip[/file]

 

[crapoto]

Re:Reconnaitre des dates et les séparées par une l

Un grand merci à vous deux
J'ai éssayer les deux solutions et ça marche parfaitement.
J'ai chercher pendand des heures, et vous vous me regler ça en un tour de main----Bravo----
en plus ça corrige les fautes
Bonne journée
A+

Message édité par: crapoto, à: 09/06/2005 05:10