RechercheH et décaler le résultat à récupérer

[safranien]

Bonjour à tous,

je lutte depuis qques temps sur une fonction que je n'arrive pas à réaliser. J'explique:

dans une feuille, j'ai un menu déroulant avec plusieurs dates. Lorsque je choisis une date, j'extrapole le mois dans une cellule, et en fonction du mois, j'ai une formule dans une autre cellule qui va me chercher la valeur souhaitée dans un des 5 autres onglets où il faut chercher (5 onglets qui s'appellent NOVEMBRE, DECEMBRE, JANVIER, FEVRIER et MARS). Formule qui est:

=SI(OU(ESTVIDE($A11);ESTVIDE($O$1));"-";SI($Q$1=11;RECHERCHEH($O$1;'Relevés NOVEMBRE'!$C$2:$CW$40;15;0)*1000;SI($Q$1=12;RECHERCHEH($O$1;'Relevés DECEMBRE'!$C$2:$CW$40;15;0)*1000;SI($Q$1=1;RECHERCHEH($O$1;'Relevés JANVIER'!$C$2:$CW$40;15;0)*1000;SI($Q$1=2;RECHERCHEH($O$1;'Relevés FEVRIER'!$C$2:$CW$40;15;0)*1000;RECHERCHEH($O$1;'Relevés MARS'!$C$2:$CW$40;15;0)*1000)))))

Mon soucis est que je fais un rechercheh sur une ligne dont les dates sont fusionnées sur 3 cellules. Par exemple, en A1 j'ai le 01/11/2012 fusionné sur A1, B1, C1. Mon soucis est que pour certaines valeurs que je veux raptrier sur mon autre onglet, avec un rechercheh, il va me chercher forcément les valeurs de la colonne A (ou D, G, J etc) alors que je voudrais la valeur de la cellule se situant en B.

Est ce possible de dire à rechercheh que, lorsqu'il trouve la date, il cherche la valeur X lignes plus bas puis la cellule d'à côté à droite?

J'espère avoir réussi à bien expliquer et que vous pourrez m'apporter vos lumières.

Bonne journée

 

[Modeste]

Re : RechercheH et décaler le résultat à récupérer

Bonjour safranien,

Est ce possible de dire à rechercheh que, lorsqu'il trouve la date, il cherche la valeur X lignes plus bas puis la cellule d'à côté à droite?

... peut-être ... mais serait-il possible de fournir un petit exemple qui aiderait à visualiser le "chantier"?

 

[safranien]

Re : RechercheH et décaler le résultat à récupérer

Bonjour modeste,

effectivement, j'aurais pu mettre un exemple. Je viens de trouver comment faire avec EQUIV et INDEX
=INDEX(PLAGEMARS;14;EQUIV($O$1;DATEMARS;0)+1). Ca à l'air de fonctionner ainsi.

Merci pour ta réponse et désolé pour le dérangement. Je joins un exemple que j'ai pu trouver et qui servira peut être à d'autres.

Bonne journée.

 

[Modeste]

Re : RechercheH et décaler le résultat à récupérer

Re-bonjour,

Content que tu aies trouvé et merci de penser aux suivants
Mais ... plus de feuilles Novembre, Décembre, etc...

Je m'apprêtais à proposer, au regard de ta formule initiale, quelque chose comme:

=INDEX(INDIRECT(CHOISIR($Q$1;"janvier";"février";"mars";"avril";"mai";"juin";"juillet";"août";"septembre";"octobre";"novembre";"décembre")&"!A16:CW16");1;EQUIV($O$1;INDIRECT(CHOISIR($Q$1;"janvier";"février";"mars";"avril";"mai";"juin";"juillet";"août";"septembre";"octobre";"novembre";"décembre")&"!A2:CW2");0)+1)

... mais on en est loin!?

 

[safranien]

Re : RechercheH et décaler le résultat à récupérer

Voilà mon fichier. Onglet 'Import Energy", cellules I10 et I11. A partir de la date saisie en O1, je veux aller récupérer des valeurs dans l'onglet qui contient cette date.

Au passage si tu as une astuce pour que je puisse mettre toutes les dates dans mon menu déroulant en faisant autrement que ce que j'ai fait (onglet feuil3)

Merci

 

[Modeste]

Re : RechercheH et décaler le résultat à récupérer

Re-bonjour safranien,

En I10 et I11, les formules que tu as insérées donnent le bon résultat? En tout cas, en J11, j'obtiens le même avec ma précédente formule adaptée (en utilisant les infos que tu as saisies en Feuil3, colonnes C & D):

=INDEX(INDIRECT("'Relevés "&INDEX(Feuil3!$D$1:$D$5;EQUIV($Q$1;Feuil3!$C$1:$C$5;0))&"'!A16:CW16");1;EQUIV($O$1;INDIRECT("'Relevés "&INDEX(Feuil3!$D$1:$D$5;EQUIV($Q$1;Feuil3!$C$1:$C$5;0))&"'!A2:CW2");0)+1)

Pour les dates de ta liste déroulante, en dehors du fait que tu pourrais créer une plage nommée dynamique, je ne vois pas trop ce que tu pourrais changer, ne connaissant pas le "contexte".
Maintenant, si tu veux soigner la présentation et faciliter la saisie, tu peux aussi utiliser le calendrier proposé par BrunoM45 et mromain ici

 

[safranien]

Re : RechercheH et décaler le résultat à récupérer

ca a l'air de fonctionner. je regarderai plus en detail demain. parce que là je comprends pas la formule lol

merci beaucoup pour ton aide

bonne soiree