recherche de dates dans excel

[stepy73]

Bonjour, bonsoir à tous, Voici ci-dessous la macro qui me permet de faire une recherche sur toute les feuilles de texte.

je voudrais savoir si il est possible d'avoir de type de marco mais pour rechercher une date et non pas du texte ? Exemple 14/10/2011

Est ce qu'un expert peut me dire comment résoudre cela ?

d'avance merci pour votre aide


Sub TrouverMotChoix()
Dim Mot As String
Dim Ws As Object
Dim Nbre As Long
Dim Cycle As Long
Dim Trouvé As Variant
Dim CellAddress As Variant
Dim MyValue As String

'Définition de la variable à rechercher
Mot = InputBox("Saisir la valeur à chercher sur déclenchement d'alarme.", Title:="Recherche")
'Vérification si existante
If Mot = "" Then Exit Sub
For Each Ws In Worksheets
Nbre = Nbre + Application.CountIf(Ws.UsedRange, "*" & Mot & "*")
Next Ws
'Message en cas de mot inexistant
If Nbre = 0 Then
MyValue = MsgBox(" La valeur " & Mot & " n'est pas enregistrée ", vbOKOnly, " Message ")
Else
Cycle = 0
'Recherche et arrêt sur les cellules contenant le Mot
For Each Ws In Worksheets
With Ws
.Activate
Set Trouvé = .Cells.Find(what:=Mot, After:=ActiveCell, LookIn:=xlValues, LookAt:=xlPart)
If Not Trouvé Is Nothing Then
CellAddress = Trouvé.Address
Do
Cycle = Cycle + 1
Trouvé.Activate
If Nbre = 1 Then
MyValue = MsgBox(" La valeur " & Mot & " est enregistrée 1 seule fois ", vbOKOnly, " Message ")
Exit Sub
End If
If Cycle = Nbre Then
MyValue = MsgBox(" La valeur " & Mot & " sélectionnée est la dernière !", vbOKOnly, "Message")
Sheets("sheet1").Activate
Range("A1").Select
Exit Sub
Else
MyValue = MsgBox(" La valeur " & Mot & " sélectionnée est la " & Cycle & " sur " & Nbre & " existantes. " & vbLf & _
" Voulez vous continuer la recherche ? ", vbYesNo, "Message")
If MyValue = vbNo Then Exit For
Set Trouvé = .Cells.FindNext(After:=Trouvé)
End If
Loop While Not Trouvé Is Nothing And Trouvé.Address <> CellAddress
End If
End With
Next Ws
End If
End Sub


d'avance merci de prendre un peu de votre temps pour me repondre.

 

[BOISGONTIER]

Re : recherche de dates dans excel

Bonjour,

Recherche de dates
http://boisgontierjacques.free.fr/fichiers/FindDates.xls

JB

 

[stepy73]

Re : recherche de dates dans excel

Merci pour ta réponse, mais cela ne fonctionne pas pour moi, dans la même cellule j’ai la date et heure.
J’aimerai simplement avoir le même type de macro que ci-joint, mais avec une fonctionne recherche DATE.
Merci pour ton aide, ses petits liens me seront très utiles. Bon dimanche

 

[BOISGONTIER]

Re : recherche de dates dans excel

Recherche d'une date
Les cellules contiennent la date & l'heure

Sub RechercheDateFind()
  d = InputBox("Date? jj/mm/aa")
  If d <> "" Then
    On Error Resume Next
    Set temp = [L:L].Find(What:=CDate(d), LookIn:=xlValues, LookAt:=xlPart)
    If Not temp Is Nothing Then
      temp.Select
    Else
      MsgBox "Non trouvé"
    End If
  End If
End Sub

http://boisgontierjacques.free.fr/fichiers/Formulaire/FormChercheMotToutClasseurFind.xls

Private Sub B_ok_Click()
   If Me.TextBox1 = "" Then Exit Sub
   Application.DisplayAlerts = False
   On Error Resume Next
   Sheets("Temp").Delete
   On Error GoTo 0
   Sheets.Add after:=Sheets(Sheets.Count)
   ActiveSheet.Name = "Temp"
   [A1] = Me.TextBox1
   ligne = 2
   For i = 1 To Sheets.Count - 1
    With Sheets(i).Cells
      If IsDate(Me.TextBox1) Then
        Set c = .Find(CDate(Me.TextBox1), LookIn:=xlValues, LookAt:=xlPart)
      Else
        Set c = .Find(Me.TextBox1, LookIn:=xlValues, LookAt:=xlPart)
      End If
      If Not c Is Nothing Then
         premier = c.Address
         Do
           temp = [A1]
           Sheets("temp").Hyperlinks.Add Anchor:=Sheets("temp").Cells(ligne, 1), _
           Address:="", SubAddress:="'" & Sheets(i).Name & "'" & "!" & c.Address, TextToDisplay:=temp 'Sheets(i).Name
           Cells(ligne, 2) = Sheets(i).Name
           Cells(ligne, 3) = c.Address
           ligne = ligne + 1
           Set c = .FindNext(c)
         Loop While Not c Is Nothing And c.Address <> premier
      End If
    End With
   Next i
End Sub

JB

 

[stepy73]

Re : recherche de dates dans excel

Bonjour JB, je n'arrive toujours pas faire Fonctionner cette recherche.
ci-joint un bout de mon fichier.

les recherches sont a effectuer sur des feuilles de janvier à decembre.

merci encore pour ton , votre aide.

Stéphane