XL 2013 Recherche dans plusieurs colonnes

[Garamante]

Salut à tous,

sujet mainte fois abordé mais je n'ai pas trouvé exactement ce que je voulais malgré mes recherches.




Est-il possible de faire une recherche sur ces colonnes (dates). Par exemple, la plus ancienne trouvée est le 01/01/2015, la formule de la cellule suivante cherche la deuxième date la plus ancienne et l'affiche à son tour, ce qui donne un truc du genre:

01/01/2015
03/01/2015
05/01/2015
07/01/2015

Sur une seule colonne pas de soucis, j'utilise la formule (Merci R@chid !):

=SI(C46="";"";SIERREUR(PETITE.VALEUR(J7:J1000;NB.SI(J7:J1000;"<="&C46)+1);""))

Mais comment faire sur plusieurs colonnes ?

 

[ERIC S]

Re : Recherche dans plusieurs colonnes

Bonjour

sans fichier, je n'ai pas testé ta formule en entier mais il me semble que petite.valeur fonctionne aussi si tu mets une plage exemple
petite.valeur(I1:K10;1)

 

[Garamante]

Re : Recherche dans plusieurs colonnes

Salut Eric ;o)

hey non ça ne marche pas (Encore moins avec les colonnes de chiffres entre les dates). J'ai mis un fichier en pièce jointe.

 

[ERIC S]

Re : Recherche dans plusieurs colonnes

Re
tes dates sont toujours en ordre croissant (par colonne) ?

 

[JHA]

Re : Recherche dans plusieurs colonnes

Bonsoir à tous,

A essayer,

JHA

 

[ERIC S]

Re : Recherche dans plusieurs colonnes

Re

cela a l'air bien mais la première formule différente des suivantes reste risquée (>0)
j'ai tenté cela en D5, matriciel (validé par Ctrl shift entrée)

=PETITE.VALEUR(SI(($I$4:$P$160>MAX(40000;SI(ESTNUM($D4);$D4;40000)));$I$4:$P$160);1)

40000 correspond au 6/7/2009 donc hors période et cela élimine les nombres des colonnes Nb

 

[R@chid]

Re : Recherche dans plusieurs colonnes

Bonsoir @ tous,
une autre approche en évitant les doublons.
en D5 :

=SIERREUR(PETITE.VALEUR(SI(ESTNUM(CHERCHE("date";I$3:P$3))*(NB.SI(D$4:D4;I$4:P$160)=0)*(I$4:P$160<>"");I$4:P$160);1);"")

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

[JHA]

Re : Recherche dans plusieurs colonnes

Bonjour à tous,



Comme le fait remarquer Eric s que je salue, pour éviter 2 formules différentes tout en gardant la gestion des colonnes "date", petite modification de la formule proposée en #5

=PETITE.VALEUR(SI((MOD(COLONNE($I$4:$P$160);2)=1)*($I$4:$P$160<>"")*($I$4:$P$160>N($C4));$I$4:$P$160);1)

on peut même raccourcir un peu

=PETITE.VALEUR(SI((MOD(COLONNE($I$4:$P$160);2)=1)*($I$4:$P$160>N($C4));$I$4:$P$160);1)

A valider en matricielle puis tirer vers le bas

Bonjour rachid , sympa ta formule.

JHA

 

[Garamante]

Re : Recherche dans plusieurs colonnes

Salut les gars,

désolé de vous répondre si tard: je suis rentré à une heure pas possible et Excel n'aurait pas été une bonne chose à cette heure avancée de la nuit

En tout cas bravo! ça marche ! Maintenant il ne me reste plus qu'à finir le truc tout seul comme un grand !!!

Merci encore les gars !

 

[Garamante]

Re : Recherche dans plusieurs colonnes

Ben en fait j'ai encore besoin de vous

La formule prend en compte la dernière colonne remplie à droite (ici, P). Comment faire pour quelle prenne plus large (par exemple V:V) mais qu'elle ne tienne compte que des colonnes remplies dans son résultat?

l'idéal serait un truc du genre:

$A$1:&ADRESSE(2000;EQUIV(9^9;6:6))

Qui calculerait dynamiquement la dernière colonne pour donner par exemple $A$1:$Z$2000. Mais, vous le savez déjà... ça ne marche pas Vous connaissez une astuce ?

Voir PJ

 

[Garamante]

Re : Recherche dans plusieurs colonnes

la formule

=ADRESSE(5;EQUIV(9^9;5:5))

marche très bien pour trouver la dernière colonne non vide mais ne marche pas lorsque le contenu est généré avec une formule, il semblerait

 

[JHA]

Re : Recherche dans plusieurs colonnes

Bonjour à tous,

Cette formule calcule le nombre de valeur de la ligne 3 de "I3" à max 99 sur la droite dans la formule.
Pour les lignes j'ai mis 500.

=PETITE.VALEUR(SI((MOD(COLONNE(DECALER(Feuil5!$I$3;;;500;NBVAL(DECALER(Feuil5!$I$3;;;;99))));2)=1)*(DECALER(Feuil5!$I$3;;;500;NBVAL(DECALER(Feuil5!$I$3;;;;99)))>N($C4));DECALER(Feuil5!$I$3;;;500;NBVAL(DECALER(Feuil5!$I$3;;;;99))));1)

Si tu nommes la plage "essai", cela fait:

=PETITE.VALEUR(SI((MOD(COLONNE(essai);2)=1)*(essai>N($C4));essai);1)

plage nommée essai

=DECALER(Feuil5!$I$3;;;500;NBVAL(DECALER(Feuil5!$I$3;;;;99)))

JHA

 

[Garamante]

Re : Recherche dans plusieurs colonnes

Merci JHA

J'ai planqué ta formule dans la colonne C. Elle provoque une erreur #NOMBRE! arrivée à la date la plus récente (Voir PJ). J'ai essayé une condition avec un EST.ERREUR mais il réinitialise tout par la suite.

 

[JHA]

Re : Recherche dans plusieurs colonnes

Bonjour à tous,

La plage "essai" bougera vers la droite quand tu noteras dans la ligne 3, dans l'exemple, la plage s'étend jusque la colonne "P".
J'ai modifié la formule car tu as excel 2013.


JHA

 

[JHA]

Re : Recherche dans plusieurs colonnes

Re,

Les calculs sont trop longs, mets plutôt cette formule en "C5"

=SI($C4="";"";SIERREUR(PETITE.VALEUR(SI((MOD(COLONNE(essai);2)=1)*(essai>N($C4));essai);1);""))

JHA