Re : Somme si avec un OU + éviter une répétition de code

[pepsi]

Bonjour le forum,

J'essaye d'écrire une formule qui me semble dans la logique correcte, mais qui ne renvoie aucun résultat :

Je voudrais calculer une somme de prix, que le type soit dans mon exemple des pommes ou des oranges.

=SOMME.SI(A2:A6;OU("pomme";"orange");B2:B6)

Qu'est ce qui n'est pas correcte dans ma formule,

Merci pour votre aide

 

[phlaurent55]

Re : Somme si avec un OU

Bonjour pepsi,

avec cette formule:
=SOMMEPROD((A2:A6="pomme")*B2:B6)+SOMMEPROD((A2:A6="orange")*B2:B6)

à+
Philippe

 

[Jocelyn]

Re : Somme si avec un OU

Bonjour le Forum,
Bonjour pepsi,

Tu peux tester une formule de ce genre :

=SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*B2:B6)

Cordialement

EDIT : Bonjour phlaurent55, désolé pour la collision

 

[pepsi]

Re : Somme si avec un OU

Merci , des réponses toujours rapides et fonctionnelles.

bravo

 

[pepsi]

Bonjour le forum,

Je cherche à simplifier maintenant ma formule. Est ce possible d'éviter la répétition : =SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))

=SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*B2:B6)+SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*c2:c26)

merci encore

 

[Jocelyn]

Re Bonjour,

dans la formule que tu voudrait simplifiée je suppose que la partie *c2:c26 est une erreur de frappe et que tu voulais mettre *c2:c6, si oui tu peux simplifier je pense de cette façon :

=SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*B2:C6)

Cordialement

 

[pepsi]

Merci Jocelyn
Effectivement, c'était une erreur de frappe.

Et si maintenant, je souhaite simplifier cette formule

=SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*B2:B6)+SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*E2:E6)

merci

 

[Jocelyn]

re,

vu que cette fois tes colonnes ne sont pas adjacentes tu peux essayer comme ça

=SOMMEPROD(((A2:A6="pomme")+(A2:A6 ="orange"))*(B2:B6+E2:E6))

 

[pepsi]

Excellent, cela fonctionne.
J'avais essayé avec un ; et non un +


Merci encore Jocelyn