XL 2016 procédure qui ne fait rien

[Bill73]

bonjour,

je me casse les dents depuis quelques heures avec :

Public Sub Format_Ligne(feuille As String, ByVal lig As Integer, dbcol As Integer, fncol As Integer)
        
        Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Borders.LineStyle = 1
        Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Borders.Weight = xlMedium
        Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Borders.Color = RGB(230, 230, 230)
        Worksheets(feuille).Cells(lig, fncol).Borders(xlEdgeRight).Color = RGB(89, 89, 89)
        Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Borders(xlEdgeTop).Color = RGB(230, 230, 230)
        Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Borders(xlEdgeBottom).Color = RGB(89, 89, 89)
        If lig Mod 2 = 0 Then
            Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Interior.Color = RGB(232, 232, 232)
        Else
            Worksheets(feuille).Range(dbcol & lig & ":" & fncol & lig).Interior.Color = RGB(209, 209, 209)
        End If
End Sub

je voudrais avoir ce code en général avec appel type " Format_Ligne "Entrée", ligent, 2, 15 " , ligent étant une variable contenant un numéro de ligne, depuis plusieures feuilles.

si je mets ce code à chaque fois dans les différentes feuilles, ça marche, si je fais une procédure globale, rien ne se passe.

Si quelqu'un a une idée ?

 

[sylvanu]

Bonsoir Bill,
Juste par curiosité, si lig, dbcol, fncol sont des nombres comme déclarés, comment :
Range(dbcol & lig & ":" & fncol & lig) peut fonctionner ?

 

[Bill73]

j'avais testé :

Worksheets(feuille).Range(Cells(lig, dbcol), Cells(lig, fncol)).Borders.LineStyle = 1

mais "erreur d'exe 1004 : Erreur définie par l'application ou l'objet"

 

[sylvanu]

si je mets ce code à chaque fois dans les différentes feuilles, ça marche

C'est ça qui m'étonnes. Votre code marche comme écrit au post #1 ?

 

[Bill73]

oui, en entrant par exemple dbcol = 12 etc avant la proc

 

[MFoxy]

Bonsoir,

Utilisant une version 2016 d'excel, ne serait-il pas plus efficace d'utiliser un tableau structuré plutôt qu'une plage classique.

Vous pourriez même, si les visuelles de bases ne vous conviennent pas, créé votre propre format visu.

Bav

 

[Bill73]

la, je ne sais pas, quid d'un tableau structuré ?

 

[MFoxy]

Re,

Quelques explications sur les tableaux structurés / listObject sur le site MS.

Créer et mettre en forme des tableaux - Support Microsoft

Découvrez toutes les manières qui s’offrent à vous pour créer un tableau dans une feuille de calcul Excel, et comment effacer des données, une mise en forme ou une fonctionnalité de tableau dans Excel. Découvrez-en plus dans cette vidéo.

support.microsoft.com

Bav,

 

[Bill73]

ok, je n'avais pas saisi.
non, je cherche à le structurer par code directement dans la macro du fichier.
mais merci quand même.

 

[Bill73]

j'avance :
-le code marche pour la feuille activée
-le code ne marche pas pour une feuille non activée

je m'explique, lorsque je rentre une ligne de données depuis un form, cette ligne se rajoute à un tableau dans une feuille non activée, puis et copiée dans la feuille active.

 

[Dranreb]

Bonsoir.

Worksheets(feuille).Range(Cells(lig, dbcol), Cells(lig, fncol)).Borders.LineStyle = 1

mais "erreur d'exe 1004 : Erreur définie par l'application ou l'objet"

Normal: vous ne pouvez pas définir une plage d'une feuille composée de cellules d'une autre feuille, à savoir celles de la feuille active assumée puisque non précisée.
Worksheets(feuille).Range(ActiveSheet.Cells(lig, dbcol), ActiveSheet.Cells(lig, fncol))
Le paramètrage de votre Sub n'est pas pertinent. Je ferais :
Public Sub Format_Ligne(ByVal Cel As Range, ByVal NbCol As Long)
Ce serait bien plus pratique à utiliser.
Et tout tiendrait dans un :
With Cel.Resize(, NbCol)
> .Borders( … etc.
> .Interior.Color = etc.
> End With
Mais c'est vrai aussi que je ne m'embêterais pas à reconduire un format alors que ça se fait tout seul si c'est un tableau Excel

 

[Bill73]

Normal: vous ne pouvez pas définir une plage d'une feuille composée de cellules d'une autre feuille, à savoir celles de la feuille active assumée puisque non précisée.

surprenant, j'ai tout une série de fonctions ou procédures montées sur le même type d'appel et qui marchent sans problèmes.
- fonctions de tri, recherches, écritures... sur des feuilles autres que l'active

 

[patricktoulon]

bonjour
non ce qui est surprenant c'est que tu dise que d'autre macro montées de la même façon fonctionnent sur des feuilles non activées
Worksheets(feuille).Range(parent.Cells(lig, dbcol),parent. Cells(lig, fncol)).Borders.LineStyle = 1

une écriture simple comme te l'a dit Dranreb que je salut
with Worksheets(feuille):.Range(.Cells(lig, dbcol), .Cells(lig, fncol)).Borders.LineStyle = 1:end with

 

[Bill73]

comme quoi, une nuit de sommeil arrange tout :

Public Sub Format_Ligne(feuille As String, ByVal lig As Integer, dbcol As Integer, fncol As Integer)
    Dim ligne, fligne As Range
    
    With Worksheets(feuille)
        Set ligne = .Range(.Cells(lig, dbcol), .Cells(lig, fncol))
        Set fligne = .Cells(lig, fncol)
    End With
    ligne.Borders.LineStyle = 1
    ligne.Borders.Weight = xlMedium
    ligne.Borders.Color = RGB(230, 230, 230)
    fligne.Borders(xlEdgeRight).Color = RGB(89, 89, 89)
    ligne.Borders(xlEdgeTop).Color = RGB(230, 230, 230)
    ligne.Borders(xlEdgeBottom).Color = RGB(89, 89, 89)
    If lig Mod 2 = 0 Then
        ligne.Interior.Color = RGB(232, 232, 232)
    Else
        ligne.Interior.Color = RGB(209, 209, 209)
    End If
End Sub

la, ça marche que se soit dans la feuille active ou une autre feuille.

 

[patricktoulon]

re
bonjour
ouais ben..il te manque encore quelques heures de sommeil
ligne.Borders.LineStyle = 1
ligne.Borders.Weight = xlMedium
ligne.Borders.Color = RGB(230, 230, 230)
fligne.Borders(xlEdgeRight).Color = RGB(89, 89, 89)
ligne.Borders(xlEdgeTop).Color = RGB(230, 230, 230)
ligne.Borders(xlEdgeBottom).Color = RGB(89, 89, 89)