Problème Formule matricielle

[olivm]

Bonjour,

Pouvez-vous me dire ce que donne cette formule classique en formule matricielle (ma formule possédant des "=" et étant assez compliquée, je n'arrive pas à faire ma formule matricielle):
=SI(B1=B2;"";
SI(ET(B2=B6;B2=B5;B2=B4;B2=B3);1/((1/A6)+(1/A5)+(1/A4)+(1/A3)+(1/A2));
SI(ET(B2=B5;B2=B4;B2=B3);1/((1/A5)+(1/A4)+(1/A3)+(1/A2));
SI(ET(B2=B4;B2=B3); 1/((1/A4)+(1/A3)+(1/A2));
SI(B2=B3; 1/((1/A3)+(1/A2));
A2)))))


J'ai le même problème pour une formule de cette forme-ci:
=SI(P7=P6;"";
SI(ET(P7=P12;P7=P11;P7=P10;P7=P9;P7=P8);(J7+J8+J9+J10+J11+J12)/(J12/H12+J11/H11+J10/H10+J9/H9+J8/H8+J7/H7);
SI(ET(P7=P11;P7=P10;P7=P9;P7=P8);(J7+J8+J9+J10+J11)/(J11/H11+J10/H10+J9/H9+J8/H8+J7/H7);
SI(ET(P10=P7;P7=P9;P7=P8);(J7+J8+J9+J10)/(J10/H10+J9/H9+J8/H8+J7/H7);
SI(ET(P7=P9;P7=P8); (J7+J8+J9)/(J7/H7+J8/H8+J9/H9);
SI(P7=P8; ( J7+J8)/(J7/H7+J8/H8);
H7))))))

Je vous joins un fichier exemple ;-)

J'ai vraiment besoin de votre aide car sinon je dois continuer en formule classique et je dois aller jusqu'à "si 10 articles sont identiques"...donc j'aimerais vraiment passer par le fameux CTRL+MAJ+ENTREE


Je suis aussi preneur des formules équivalentes

Merci par avance pour votre aide

 

[Dranreb]

Re : Problème Formule matricielle

Bonjour
Ça donne ça:

=SI(B2<>B1;1/SOMME(SI(B2:B28=B2;1/A2:A28;0));"")

validé Ctrl+Maj+Entrée puis recopié vers le bas.
Devrait marcher jusqu'à 27 articles identiques (c'est un peu par hasard) diminuer étendue si vraiment jamais besoin de plus de 10.
À+

 

[olivm]

Re : Problème Formule matricielle

Merci beaucoup, je vais étudier ça pour le comprendre, l'appliquer à mon réel fichier et essayer de faire ma formule matricielle pour ma deuxième formule classique.

 

[olivm]

Re : Problème Formule matricielle

arf, je n'arrive pas au résultat attendu, je fais un edit dans 5 min avec mon fichier mais ma deuxième formule classique à transformer en formule matricielle



Voila, j'ai joins un fichier exemple avec la deuxième formule que je veux passer sous forme matricielle...je débute en fct matricielle donc c'est pas mon fort :-s

 

[Dranreb]

Re : Problème Formule matricielle

Plus le temps.
Essayer:

=SI(P7<>P6;SOMME(SI(P7:P28=P7;P7:P28;0))/SOMME(1/P7:P28);"")

Bonsoir.
Bon week end
Joyeuses pâques à vous ainsi qu'à tout le forum.

 

[olivm]

Re : Problème Formule matricielle

Merci, bonne vacances à toi aussi et bonne fête de pâques !

Ah ça ne marche pas non plus, j'ai joins un nouveau fichier au cas où d'autres souhaiterais m'aider

 

[tdenfert]

Re : Problème Formule matricielle

Bonjour,
Avec ça peut être =Si(B1=b2;"";1/SOMMEPROD(($B$2:$B$6=B2)*(1/($A$2:$A$6)))) à tirer

 

[olivm]

Re : Problème Formule matricielle

Bonjour Tdenfert, merci pour ton aide.
en fait, pour cette formule, dranreb a déjà trouvé la solution.
=SI(B1=B2;"";
SI(ET(B2=B6;B2=B5;B2=B4;B2=B3);1/((1/A6)+(1/A5)+(1/A4)+(1/A3)+(1/A2));
SI(ET(B2=B5;B2=B4;B2=B3);1/((1/A5)+(1/A4)+(1/A3)+(1/A2));
SI(ET(B2=B4;B2=B3); 1/((1/A4)+(1/A3)+(1/A2));
SI(B2=B3; 1/((1/A3)+(1/A2));
A2)))))

solution => =SI(B2<>B1;1/SOMME(SI(B2:B28=B2;1/A2:A28;0));"") CTRL + MAJ + ENTREE
ou => =Si(B1=b2;"";1/SOMMEPROD(($B$2:$B$6=B2)*(1/($A$2:$A$6)))) à tirer


Mais je n'ai pas trouvé la solution pour cette formule:
=SI(C2<>C1;
SI(ET(C2=C3;C2=C4); ( B2+B3+B4)/(B2/A2+B3/A3+B4/A4);
SI(C2=C3;(B2+A2)/(B2/A2+B3/A3);
A2));"")

solution????

Pour être plus explicite, je propose à nouveau mon fichier exemple avec cette nouvelle formule.

edit :edit: j'ai peut-être une piste en ajoutant un somme.si à la place du numérateur...

 

[olivm]

Re : Problème Formule matricielle

J'ai trouvé cette formule !
=SI(C1=C2;"";SOMME.SI(C2:C6;C2;B2:B6)/SOMMEPROD(($C$2:$C$6=C2)*((B$2:$B$6)/($A$2:$A$6))))




mince, j'ai un autre souci maintenant, cest que ma plage, si elle est trop grande (elle peur varier comme c'est sur un TCD), et bien ça me met un #div/0

en gros, si j'élargis les plages d'une ligne, on arrive à ça (cf fichier exemple).

avez-vous une solution?


Trouvé tout seul comme un grand !

=SI(C1=C2;"";SOMME.SI(C2:C7;C2;B2:B7)/SOMME(SI($C$2:$C$7=C2;B$2:$B$7/$A$2:$A$7;0)))
à valider par ctrl + maj + entrée.

Sujet résolu