Problème Combobox

[freefer]

Bonjour,

Avec le code suivant, rien ne s'affiche dans les deux combo. Pourquoi ?

Private Sub UserForm_Initialise()
Dim Cel As Range
Sheets("Saisie_Notes").Activate
Range("e3,ai3").Select
For Each Cel In Selection
Test.AddItem Cel.Value
Next Cel
Range("d4").Select
Range(Selection, Selection.End(xlDown)).Select
For Each Cel In Selection
If Left(Cel.Value, 5) <> "Annul" Then Nom.AddItem Cel.Value
Next Cel

End Sub
Si vous avez la réponse, merci d'avance.

Cordialement,

Freefer

 

[skoobi]

Re : Problème Combobox

Bonsoir,

Pourrais-tu envoyer le fichier ou un extrait s'il est trop lourd?

 

[Robert]

Re : Problème Combobox

Bonsoir Freefer, Skoobi, bonsoir le forum,

J'ai un peu raccourci le code et surtout corrigé deux erreurs :

[COLOR=navy]Private Sub UserForm_Initiali[B][COLOR=red]s[/COLOR][/B]e()[/COLOR]

je te conseille d'utiliser la liste des procédures plutôt que de la taper toi même, ça t'évitera ce genre de déconvenue. Avec un s la procédure n'existe pas...

[COLOR=navy]Range("e3[COLOR=red][B],[/B][/COLOR][COLOR=navy]ai[/COLOR]3")[/COLOR]

deux points à la place de la virgule...

ton code corrigé et testé :

Private Sub UserForm_Initialize()
Dim cel1 As Range, cel2 As Range
With Sheets("Saisie_Notes")
    For Each cel1 In .Range("E3:AI3")
        test.AddItem cel1.Value
    Next cel1
    For Each cel2 In .Range("D4:D" & .Range("D4").End(xlDown).Row)
        If Left(cel2.Value, 5) <> "Annul" Then nom.AddItem cel2.Value
    Next cel2
End With
End Sub

 

[kjin]

Re : Problème Combobox

Bonsoir,
Peut-être comme ceci :

Private Sub UserForm_Initialize()
Dim Cel1 As Range, Cel2 as range, plage1 as Range, plage2 as Range
With Sheets("Saisie_Notes")
Set plage1 = .Range("E3:AI3")
For Each Cel1 In plage1
Test.AddItem Cel1.Value
Next Cel1
Set plage2 = .Range("D4" & .Range("D4").End(xlDown).Row)
For Each Cel2 In plage2
If Left(Cel2.Value, 5) <> "Annul" Then
Nom.AddItem Cel2.Value
End If
Next Cel2
End With
End Sub

A+
kjin
Edit : Bonsoir Robert, pas rafraichi à temps

 

[freefer]

Re : Problème Combobox

Bonjour,

Merci à vous tous, mais effectivement pour que cela fonctionne, comme Robert me le conseille, l'utilisation de la liste des procédures évite les fautes de frappe qui bloquent le programme. Mon code fonctionne bien sauf pour la seconde combo, pour laquelle il faut que je "Transpose" de ligne en colonne pour pouvoir lui faire afficher les valeurs.

Merci encore pour votre aide,

Cordialement,

Freefer