Problème avec NB.SI

[adrian]

Bonjour tout le monde,

Voici mon soucis, avec un fichier test joint en exemple :

J'ai un listing de personnes avec une colonne pour les codes postaux (colonne C) et une pour les pays (colonne E).

Je souhaiterais compter le nombre de personnes par département, j'ai donc utilisé la fonction NB.SI.ENS avec la formule suivante :
=NB.SI.ENS($C:$C;"67*";$E:$E;"FRA") pour les personnes venant du département 67.

Le problème c'est que les codes postaux dans la colonne C ne sont pas reconnus comme du texte et le compte final est donc nul.
Pour un fichier de quelques lignes, j'ai modifié manuellement les cellules en ajoutant l'apostrophe devant les chiffres ('67000) et ça a marché.

Est-ce que quelqu'un aurait une solution svp? Parce que pour mon fichier de 10 000 lignes ça va pas être possible manuellement

Merci à tous.

 

[Tibo]

Re : Problème avec NB.SI

Bonjour,

Peut-être avec ceci :

=NB.SI.ENS($C:$C&"";"67*";$E:$E;"FRA")

Je n'ai pas Excel 2007 ici, la formule devra peut-être être validée matriciellement (CTRL + MAJ + ENTREE)

le &"" a pour effet de transformer ta liste de codes postaux en alphanumérique.

Je te laisse tester

@+

 

[JNP]

Re : Problème avec NB.SI

Bonjour le fil ,
Euh, j'avais cherché plus compliqué ...

=SOMME(SI(GAUCHE(TEXTE($B$5:$B$10000;"00000");2)&$D$5:$D$10000="67FRA";1))

matricielle à valider par Ctrl+Maj+Enter, mais dis moi si je me trompe, Tibo, ta formule ne tiens pas compte des Ardennes, par exemple, qui vont renvoyer 8000 et non 08000 ...
Bonne journée

 

[JNP]

Re : Problème avec NB.SI

Re ,
En utilisant

=SOMME(SI(GAUCHE(TEXTE($B$5:$B$10000;"00000");2)&$D$5:$D$10000=STXT(G5;TROUVE("(";G5)+1;2)&"FRA";1))

toujours matricielle à valider avec Ctrl+Maj+Enter, elle peux être tirée vers le bas ...
Bonne journée

 

[hbenalia]

Re : Problème avec NB.SI

Bonjour à tous,

Une idée avec la formule suivante:

=SOMMEPROD((GAUCHE($B5:$B5000;2)="67")*($D5:$D5000="FRA"))

Cordialement

 

[Tibo]

Re : Problème avec NB.SI

Bonjour,

à JNP, quand j'ai vu la fonction NB.SI.ENS, je n'ai pas ouvert le fichier, sachant que cette fonction n'est pas reconnue par Excel 2003.

Tu a bien entendu raison pour ce qui concerne les départements jusqu'au 09

Je propose ceci en complément aux différentes réponses :

=SOMMEPROD((ENT($B$5:$B$101/1000)=STXT(G5;TROUVE("(";G5)+1;2)*1)*($D$5:$D$101="FRA"))

La formule serait à développer un peu si on devait traiter les départements d'outre-mer qui ont 3 chiffres.

@+

 

[adrian]

Re : Problème avec NB.SI

Merci beaucoup à tous, je teste ça et je reviens pour confirmer que ça a fonctionné.

 

[adrian]

Re : Problème avec NB.SI

J'ai utilisé la dernière proposition de Tibo et ça a fonctionné impec' comme toujours.

Encore merci et bonne journée à tous.

 

[adrian]

Re : Problème avec NB.SI

Rebonjour tout le monde en fait il me reste un soucis, la formule fonctionne sur le fichier test, mais m'indique #VALEUR quand je transpose sur mon autre fichier.
J'ai bien pris soin de modifier les plages et cellules afin que ça corresponde.

J'ai remarqué que ça fonctionne pour une plage de code postaux (colonne B) qui comprend le même nombre de lignes que le tableau (F4:H101). mais si je veux plus de lignes (en l'occurence près de 3000 lignes) ça ne fonctionne plus.

Vu que je ne connais pas toutes les fonctions utilisées dans la solution apportée par Tibo je n'arrive pas à m'en sortir tout seul, j'ai donc une nouvelle fois besoin de vos lumières.

D'avance merci.

 

[adrian]

Re : Problème avec NB.SI

J'ai trouvé le problème, en fait il arrive que dans certaines cellules les codes postaux n'aient pas le même format et comprennent des lettres... C'est le cas pour certains pays étrangers notamment.

Comment pourrais-je résoudre ce problème svp ? En sachant que de toute façon je ne veux pas comptabiliser ce type de codes postaux avec des lettres.

Je joins un autre fichier test avec l'erreur lié à la présence de lettres.

Merci

 

[Tibo]

Re : Problème avec NB.SI

re,

Une tentative proche de celle de JNP (à 11h31) :

=SOMME(SI($D$5:$D$28="FRA";SI(GAUCHE(TEXTE($B$5:$B$28;"00000");2)=STXT(G5;TROUVE("(";G5)+1;2);1)))

Matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

Si pas ça, reviens avec ton fichier (peut-être plus complet) et en y indiquant les résultats attendus.

Je te laisse tester

@+

 

[adrian]

Re : Problème avec NB.SI

Et voilà, ce coup-ci c'est bon, merci beaucoup.
Qu'est-ce que je deviendrais sans Excel downloads