Problème avec formule SI et ET

[Excel Rookie]

Bonjour à tous,

Je suis pris avec la formule SI et ET depuis quelques heures ... quelqu'un peut m'aider ?

Ma formule de départ est:

Pour femmes ("F")
=IF(C9<80;"Très bien";IF(C9<=87;"Acceptable";"À améliorer"))

Pour hommes ("H")
IF(C9<94;"Très bien";IF(C9<=101;"Acceptable";"À améliorer"))

Je voudrais pouvoir regrouper ces deux formules avec l'équation "ET" ("AND"), afin que le résultat change automatiquement, selon le sexe choisi (F ou M)

Merci

 

[soenda]

Re : Problème avec formule SI et ET

Bonsoir le fil, Excel Rookie

En supposant que le sexe soit indiqué en colonne B

=SI(C9<80+SI(B9="[COLOR=black]H[/COLOR]";14);"Très bien";SI(C9<87+SI(B9="[COLOR=black]H[/COLOR]";14);"Acceptable";"A améliorer"))

A plus

Edit : Salut Excel-lent, désolé pour le télescopage

 

[Excel-lent]

Re : Problème avec formule SI et ET

Bonsoir et bienvenu sur le forum Excel Rookie,

=IF(sexe="F";IF(C9<80;"Très bien";IF(C9<=87;"Acceptable";"À améliorer"));IF(C9<94;"Très bien";IF(C9<=101;"Acceptable";"À améliorer")))

Tout simplement! Pas besoin de la fonction ET/AND

Je suis parti du principe que le sexe ne pouvais être QUE F ou H

Mais sinon tu peux :
-> dans la zone où indiquer le sexe, mettre une liste de validation pour obliger l'utilisateur à mettre que F ou H
-> ou mettre la formule suivante à la place :

=IF(sexe="F";IF(C9<80;"Très bien";IF(C9<=87;"Acceptable";"À améliorer"));IF(sexe="H";IF(C9<94;"Très bien";IF(C9<=101;"Acceptable";"À améliorer"));"sexe saisie erroné"))

Dans tous les cas de figure proposés, tu pourras constater que je n'ai pas touché tes formules, juste rajouté une ou deux fonction SI() (selon la méthode choisie)

Dans les formules, remplacer sexe par la référence de la cellule où tu saisie le sexe (ou nommer le nom de la cellule où se trouve le sexe : "sexe" (*))

(*) Pour cela, sélectionner la(es) cellules contenant le sexe, puis cliquer sur "insertion..." / "Noms" / "Définir..."

Bon WE

Edition : Bonsoir Soenda
Edition 2 : C'est plutôt à moi de m'excuser, j'ai été BEAUCOUP plus long Le côté positif, à nous deux, il a trois solutions différentes!

 

[Excel Rookie]

Re : Problème avec formule SI et ET

MERCI beaucoup !!!!

 

[Excel Rookie]

Re : Problème avec formule SI et ET

Merci Excel-lent,

Y a t-il moyen de faire ou ce genre de formule malgré un bon nombre de condition (trop de "SI" n'affiche pas la formule...)????

ex:
IF(C5="F";IF(C14<=8%;"A";IF(C14<=22%;"B";IF(C14<23,9%;"C";IF(C14<=31%;"D";"E"))));IF(C5="M";IF(C14<=5%;"A";IF(C14<=14%;"B";IF(C14<15,9%;"C";IF(C14<=24%;"D";"E"));"sexe saisie erroné")))

Excel refuse la formule dans ce cas-ci...

 

[soenda]

Re : Problème avec formule SI et ET

Re,

Remplaces les SI par des IF, si nécessaire (et le OU par un OR)

=SI(OU(C1="F";C1="M");SI(C14<=5%+(C1="F")*3%;"A";SI(C14<=14%+(C1="F")*8%;"B";SI(C14<15,9%+(C1="F")*8%;"C";SI(C14<=24%+(C1="F")*7%;"D";"E"))));"sexe saisie erroné")

A plus

 

[Excel Rookie]

Re : Problème avec formule SI et ET

Re,

Remplaces les SI par des IF, si nécessaire (et le OU par un OR)

=SI(OU(C1="F";C1="M");SI(C14<=5%+(C1="F")*3%;"A";SI(C14<=14%+(C1="F")*8%;"B";SI(C14<15,9%+(C1="F")*8%;"C";SI(C14<=24%+(C1="F")*7%;"D";"E"))));"sexe saisie erroné")

A plus

Merci, cependant la formule ne semble que détecter une seule variable (donne la même réponse peu importe le chiffre entré)

Pour être honnête, je saisis pas grand chose à la formule mais je travaille là-dessus.
Faites-moi signe si vous trouvez le pépin

 

[hoerwind]

Re : Problème avec formule SI et ET

Bonjour,

B9 : H ou F
C9 :=CHOISIR(EQUIV(C9+(B9="F")*14;{0;94;102});"Très bien";"Acceptable";"À améliorer")
Version US :=CHOOSE(MATCH(C9+(B9="F")*14;{0;94;102});"Très bien";"Acceptable";"À améliorer")

Éventuellement mettre une condition préliminaire si B9 ou C9 sont vides

 

[hoerwind]

Re : Problème avec formule SI et ET

Variante :
=RECHERCHEV(C9+(B9="F")*14;{0\"Très bien";94\"Acceptable";102\"À améliorer"};2)

Version US :
=VLOOKUP(C9+(B9="F")*14;{0\"Très bien";94\"Acceptable";102\"À améliorer"};2)

 

[Excel-lent]

Re : Problème avec formule SI et ET

Bonsoir Excel Rookie

Merci Excel-lent,

Y a t-il moyen de faire ou ce genre de formule malgré un bon nombre de condition (trop de "SI" n'affiche pas la formule...)????
(...)

Excel refuse la formule dans ce cas-ci...

En effet, Excel n'autorise l'imbrication de seulement sept fonction SI()

Etant donné que pour répondre à ta question (voir ma solution la plus complexe : réponse 2) j'avais besoin de seulement six fonction SI(), je n'ai pas pris la peine de raccourcir ta formule, car la réponse aurait été plus complexe, donc plus difficile à comprendre.

Mais si ma réponse ne convient pas, que tu doivent la compléter et qu'au final tu as plus de 7 fonction SI() alors tu devras retrousser les manches et apprendre de nouvelles fonctions (celles proposés par Hoerwind)

Mais sinon, tu as la solution de SOENDA d'hier soir, qui est intermédiaire! Que des fonctions que tu connais déjà, avec en plus une pointe de génie : elle/il a trouvé le point commun entre tes deux conditions, permettant ainsi de simplifier ta fonction (et réduire le nombre de fonction SI()), sans pour autant utiliser des fonctions complexes.

Bon Samedi

PS : dans tes conditions, un coup tu met strictement inférieur, un autre coup tu met inférieur ou égale. Il est plus cohérent, mais surtout plus simple à mettre en formule si tu utilise toujours la même expression

 

[hoerwind]

Re : Problème avec formule SI et ET

Rebonjour,

Sous ma précédente réponse, je m'étais arrêté à la première question.

En pièce jointe, réponse à la deuxième question avec une proposition de réduction à deux SI (M et F), les autres conditions pouvant être augmentées (toutefois limitées à trente arguments).

 

[soenda]

Re : Problème avec formule SI et ET

Bonjour

Merci, cependant la formule ne semble que détecter une seule variable (donne la même réponse peu importe le chiffre entré) ...

... Et c'est la variable F !
En fait il faudrait savoir si tu utilises H ou M.

Remplaces les "M" (masculin) par des "H" (homme)

A plus

 

[Excel Rookie]

Re : Problème avec formule SI et ET

Merci beaucoup tout le monde.

Votre aide est grandement appréciée

 

[Excel Rookie]

Re : Problème avec formule SI et ET

Au fait, question de vous mettre au défi,
Il y avait déjà:

- SEXE (M ou F)
- CATÉGORIE (<80,<92, etc)

Si je décide d'ajouter une condition selon les tranches d'âge (14-19ans,20-29ans,...)
La formule sera à mes yeux beaucoup trop longue. Est-il préférable de faire un tableau et de rechercher les valeurs dans le tableau ou bien il est possible de s'en sortir avec une formule qui ne fait pas 100 pieds de long ?

 

[hoerwind]

Re : Problème avec formule SI et ET

Bonjour,

Si il y a une relation mathématique entre les différents âges, c'est faisable sans trop allonger la formule.
Au cas contraire, un ou plusieurs tableaux reprenant toutes les données semble être une bonne solution.

Avec un exemple en pièce jointe ce serait plus facile pour te conseiller.