Pb excel à word.

[bradpit34]

Bonjour à tous je vous expose mon cas.
J'ai un classeur excel qui contient un certain nombre de feuille.
dans chaque feuille j'ai des données dans des tableau.
A l'aide de diférent bouton j'enregistre par exemple les feuille 1-2-4-5 ou bien 7-5-6-9 dans un nouveau classeur excel qui est sauvegarder dans un dossier sur mon bureau.
J'ai donc plusieurs Macro affecter à mes bouton qui leur font faire tel ou tel enregistrement.
Ce que je veut faire c'est au lieu d'enregistrer 4 feuille de mon classeur dans un autre classeur c'est d'enregistrer uniquement les donnée de mes 4 feuille dans un document word.
Je veux visualisé les tableau les uns à la suite des autres.

Merci à ceux qui pourron m'apporter leur aide.
Pierre.

 

[PMO2]

Re : Pb excel à word.

Bonjour,

Une piste avec le code suivant à copier dans un module standard

'''Library Word
'''C:\Program Files\Microsoft Office\OFFICE11\MSWORD.OLB
'''Microsoft Word 11.0 Object Library

'### Constantes à adapter ###
Const CHEMIN As String = "C:\"
Const AVEC_LIAISON As Boolean = False   'True pour activer la liaison
'############################

Sub Excel2Word()
Dim DOC As Object   'Word.Document
Dim SEL As Object   'Word.Selection
Dim R As Range
Dim S As Worksheet
Dim NomFichier$
Dim A$
Dim i&
Set DOC = CreateObject("Word.document")
For Each S In ActiveWindow.SelectedSheets
  Set R = S.UsedRange
  R.Copy
  Set SEL = DOC.Parent.Selection
  SEL.PasteExcelTable LinkedToExcel:=AVEC_LIAISON, _
      WordFormatting:=False, RTF:=True
  SEL.TypeParagraph
  SEL.TypeParagraph
Next S
ActiveWindow.SelectedSheets(1).Select
Application.CutCopyMode = False
NomFichier$ = ActiveWindow.Caption
A$ = CHEMIN & NomFichier$ & ".doc"
Do Until Dir(A$) = ""
  i& = i& + 1
  A$ = CHEMIN & NomFichier$ & "_" & i& & ".doc"
Loop
DOC.SaveAs Filename:=A$
DOC.Windows(1).Visible = True
End Sub

Sélectionnez une ou plusieurs feuilles (touche Ctrl maintenue) et lancez la macro Excel2Word.
Les données des feuilles sont copiées dans un document Word et celui-ci est enregistré automatiquement (dans C pour l'exemple en pièce jointe)
Adaptez à votre usage les constantes cernées par des ###.

Cordialement.

PMO
Patrick Morange