Numero de Ligne d'une plage de donnée

[@ntoine]

Bonjour à tous.

A partir de 2 emplacements de données :

Une ligne test comportant 8 valeurs sans doublons.
Une plage de données dont les 100 lignes ne comportent pas de doublons.

La recherche des numéros de ligne de la plage de donnée, contenant 1 ou 2 valeurs
communes avec la ligne test fonctionne bien.


Cela fait une erreur avec la recherche du numeros de ligne de la plage de donnée ayant 0 valeurs communes avec la ligne test.

=MAX(SI(FREQUENCE(SI(NB.SI(A1:H1;D7:H36)=0;"";LIGNE(D7:H36));LIGNE(D7:H36))=0;LIGNE(D7:H36)))


Merci pour toute astuce.

 

[JCGL]

Re : Numero de Ligne d'une plage de donnée

Bonjour à tous,

Ceci à l'air de fonctionner :



A+ à tous

 

[job75]

Re : Numero de Ligne d'une plage de donnée

Bonjour @ntoine, Jean-Claude,

Attention au post #1 le fichier est en mode de calcul manuel

Les trois formules améliorées/simplifiées dans le fichier joint :

=MAX(SI(FREQUENCE(SI(NB.SI(A1:H1;D7:H36);LIGNE(D7:H36));LIGNE(D7:H36))=1;LIGNE(D7:H36)))

=MAX(SI(FREQUENCE(SI(NB.SI(A1:H1;D7:H36);LIGNE(D7:H36));LIGNE(D7:H36))=2;LIGNE(D7:H36)))

=MAX(SI(FREQUENCE(SI(NON(NB.SI(A1:H1;D7:H36));LIGNE(D7:H36));LIGNE(D7:H36))=5;LIGNE(D7:H36)))

A+

 

[@ntoine]

Re : Numero de Ligne d'une plage de donnée

Grand merci à vous JCGL & job75.

+

 

[job75]

Re : Numero de Ligne d'une plage de donnée

Re,

Un complément au sujet de votre formule en K5 du post #1 qui renvoie #N/A .

Il est possible d'utiliser la valeur zéro renvoyée par le vecteur FREQUENCE.

Ce vecteur a une hauteur égale à celle de LIGNE(D7:H36) + 1.

La dernière valeur vaut justement zéro, il suffit de la zapper en utilisant GRANDE.VALEUR :

=GRANDE.VALEUR(SI(FREQUENCE(SI(NB.SI(A1:H1;D7:H36);LIGNE(D7:H36));LIGNE(D7:H36))=0;LIGNE(D7:H37));2)

Mais ce n'est pas plus simple que la solution précédente.

Fichier (2).

A+

 

[job75]

Re : Numero de Ligne d'une plage de donnée

Bonjour @ntoine, le forum,

Si l'on recherche les plus petites valeurs avec MIN c'est plus simple.

Mais il faut encore LIGNE(D7:H37) à la fin :

=MIN(SI(FREQUENCE(SI(NB.SI(A1:H1;D7:H36);LIGNE(D7:H36));LIGNE(D7:H36))=0;LIGNE(D7:H37)))

Et on risque d'avoir 37 comme résultat...

Fichier (3).

A+

 

[@ntoine]

Re : Numero de Ligne d'une plage de donnée

Bonjour.

Merci job75 pour ce classeur complémentaire et les explications .

@ +