Nom Prénoms à extraires via minuscules et majuscules

[Fonmaz]

Bonjour le forum.
Avant tout merci à tous les contributeurs qui permettent au néophyte que je suis d'avancer dans excel. J'ai trouvé une formule sur le forum pour extraire des noms et prénoms. Problème je vois que par trois fois sur le mini tableau joint, qu'il y a des erreurs. Je n'arrive pas à voir d'où vient le problème. Merci de regarder le tableau. les resultats des formules sont dans les colonnes C et D. Les erreurs en rouge.
Qu'est ce qui peut donc faire que la formule ne marche pas sur certaines lignes ?
Tout ca sachant que je traite des fichiers de 150 000 lignes !
Merci à tous et à ceux qui ont donné la formule que j'ai utilisé.

 

[mromain]

Re : Nom Prénoms à extraires via minuscules et majuscules

bonjour Fonmaz,

voici une autre solution avec des fonctions VBA.

a+

 

[BOISGONTIER]

Re : Nom Prénoms à extraires via minuscules et majuscules

Bonjour,

=GAUCHE(B3;EQUIV(VRAI;EXACT(STXT(B3;LIGNE($1:$255);3);MAJUSCULE(STXT(B3;LIGNE($1:$255);3)));0))
Valider avec Maj+ctrl+entrée

=STXT(B3;EQUIV(VRAI;EXACT(STXT(B3;LIGNE($1:$255);3);MAJUSCULE(STXT(B3;LIGNE($1:$255);3)));0)+1;999)

JB

 

[Tibo]

Re : Nom Prénoms à extraires via minuscules et majuscules

Bonjour,

Une solution avec formules matricielles :

en C3 :

=GAUCHE(B3;EQUIV(FAUX;EXACT((STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1));
MAJUSCULE((STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1))))))

Formule matricielle à valider par CTRL + MAJ + ENTREE

EN D3 :

=STXT(B3;EQUIV(FAUX;EXACT((STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1));
MAJUSCULE((STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)))))+2;999)

Formule matricielle à valider également par CTRL + MAJ + ENTREE

à recopier ensuite vers le bas

@+

Edit : Bing ! salut Jacques, et merci pour ta solution

@+

 

[hoerwind]

Re : Nom Prénoms à extraires via minuscules et majuscules

Bonjour, salut les autres,

Si je puis me permettre ...

En ajoutant un -1 à la fin de l'excellente formule de JB, comme ceci :
... 3)));0)-1)
l'espace derrière le prénom est supprimé.

Dès que le prénom est extrait, par exemple en C3, il est plus facile d'extraire le nom de famille par la formule :
=SUBSTITUE(B3;C3&" ";"")

 

[Fonmaz]

Re : Nom Prénoms à extraires via minuscules et majuscules

Vous êtes tous merveilleux !!!!!!!!!!!!!!!!!!!!!!
Je ne sais pas quoi dire ; toutes LES propositions fonctionnent parfaitement. Un grand merci, à HOERWIND, TIBO, BOISGONTIER ET MROMAIN.