NB.SI par attribut

[Juju29]

Bonjour à tous,

Je cherche une formule qui intègre un NB.SI et une recherche par attribut.
Le fichier joint donne un exemple de ce que je veux faire:

Le tableau des lignes 1 à 13 est un tableau de données duquel je veux extraire les statistiques que j'ai inscrites dans le tableau en lignes 16 à 20.

Je veux obtenir le nombre de chiffres 1, 3, 5, 8 ou 10 par région.
J'ai testé une formule intégrant le NB.SI et l'INDEX ou le SI mais ne trouve pas comment les agencer correctement.

Quelqu'un aurait-il une solution (sans macro svp).

Merci beaucoup!
Ju

 

[Jocelyn]

Re : NB.SI par attribut

Bonjour le Forum,
BonjourJuju29,

une formule a mettre en B18 et a étirer vers la droite et vers le bas :

=SOMMEPROD(($A$2:$A$13=$A18)*($B$2:$C$13=B$17))

Cordialement

 

[Juju29]

Re : NB.SI par attribut

Bonjour Jocelyn,

Merci de m'avoir répondu.
J'ai testé ta formule dans le fichier sur lequel je travaille et n'obtiens pas les résultats que je cherche.

Ce qu'il faudrait c'est que la formule balaye la colonne A pour trouver toutes les entrées de la région concernée puis me dise combien de 1, 3, 5, 8 ou 10 elle trouve dans les colonnes A et B en les sommant.

Aurais-tu une autre formule à me proposer sachant que je ne peux pas retravailler le 1er tableau?

Merci beaucoup,
Ju

 

[CISCO]

Re : NB.SI par attribut

Bonjour à tous

La formule proposée par Jocelyn est bonne, si tu l'appliques à la bonne plage

SOMMEPROD(($A$2:$A$13=$A18)*($B$2:$D$13=B$17))

(sauf si nous n'avons pas compris ta demande)

@ plus

 

[Jocelyn]

Re : NB.SI par attribut

re,
Bonjour Cisco ,

merci d'avoir modifié Cisco , mais la plage que j'avais donnée découlait de l'intitulé du tableau

hum hum je ne l'avais etendue que sur la plage $B$2:$C$13 car l'intitulé de ton tableau donnait "Stats A+b"
et que la colonne D représente les stats C

 

[Juju29]

Re : NB.SI par attribut

Rebonjour Jocelyn, bonjour Cisco,

Merci de m'aider tous les 2,

C'est peut-être ma demande qui n'était pas très claire?
J'ai remis un tableau en pj: "tableau 2", c'est ce que j'obtiens avec la formule, "Tableau 3", c'est ce que je veux obtenir.

J'ai remplacé les 1, 3, 5, 8, 10 par des lettres pour montrer que je ne veux pas une somme mais bien un décompte des infos du tableau 1 (ex: je veux savoir combien il y a de "a" dans la région Centre, en ne regardant que les infos des colonnes A et B). Je ne peux ni faire 3 tableaux (1 par région), ni trier mon tableau 1 par région.

Dans mon tableau de donnée réel, j'ai beaucoup de colonnes sur lesquelles je dois faire le travail, séparées par d'autres colonnes, c'est pourquoi j'ai intercalé la colonne "C" pour montrer que je dois sélectionner des données de différentes colonnes disjointes.

Est-ce que c'est plus clair?
Auriez-vous une nouvelle proposition?

Merci!
Ju

 

[hoerwind]

Re : NB.SI par attribut

Bonjour, salut les autres,

La formule était presque bonne, il ne manquait qu'une paire de parenthèses.

En I19 :

=SOMMEPROD(($A$3:$A$14=$H19)*(($B$3:$B$14=I$18)+($D$3:$D$14=I$18)))

 

[CISCO]

Re : NB.SI par attribut

Bonjour

Et oui, c'est la colonne à ne pas prendre en compte qui change tout. Dans ce cas, tu peux faire avec
SOMMEPROD(($A$3:$A$14=$A19)*($B$3:$D$14=B$18))-SOMMEPROD(($A$3:$A$14=$A19)*($C$3:$C$14=B$18))

le premier SOMMEPROD faisant le total de tout les termes intéressants, le deuxième permettant de soustraire ceux de la colonne à ne pas prendre en compte. Si il y a plusieurs colonnes à éliminer, non contigues, il suffit de faire avec plusieurs -SOMMEPROD.

@ plus

P.S : Bonjour Hoerwind. Ta proposition est intéressante si il ni a pas trop de colonnes à prendre en compte, la mienne si il ni en a pas beaucoup à éliminer. Comme ça, notre ami a le choix.

 

[Jocelyn]

Re : NB.SI par attribut

re,,

une petite explication :

contrairement à la première version ta plage de comptage est discontinue puisque tes stats a sont en colonne b et les stats b en colonne d donc il faut changer la façon d'écrire, lorsque que l'on écris cette formule de cette façon :

=SOMMEPROD(($A$3:$A$14=$A19)*($B$3:$B$14=B$18)*($D$3:$D$14=B$18))

on demande a excel de compter le nombre de ligne pour lesquelles dans la colonne A on a la valeur de A19 et que sur la même ligne et colonne B on a la valeur de B18 et que toujours sur la même ligne on a en colonne D la valeur de B18 ce qui ne se produit pas une fois.

il faut donc ecrire :

=SOMMEPROD(($A$3:$A$14=$A19)*(($B$3:$B$14=B$18)+($D$3:$D$14=B$18)))

dans cette formulation on demande de compter pour chaque ligne qui on colonne A la valeur A19 et en colonne B la valeur B18 ou alors chaque ligne qui on colonne A la valeur A19 et en colonne D la valeur B18, c'est pour cela que cette partie de la formule ($B$3:$B$14=B$18)+($D$3:$D$14=B$18) et regroupée a l'intérieur d'une même paranthèse (($B$3:$B$14=B$18)+($D$3:$D$14=B$18)) située aprés le et (*) concernant la colonne A

dans la formule sommeprod le signe * veut dire et alors que le signe + veut dire ou

voila j'espère que ces explication sont claires dans le cas contraire n'hésite pas

je te reposte le fichier

EDIT : Bonjour hoerwind , re CISCO , bon et bien la j'ai un train de retard je ne tape pas assez vite