Moyenne conditionnée

[Julien]

J'ai un tableau de notes avec une colonne par matière et un élève par ligne.
Avant ces notes j'ai en colonne le nom de l'élève puis une autre colonne avec son sexe (M ou F)...
____________
nom 1 | M | 12
nom 2 | F | 14 Quelque chose dans ce goût là....
nom 3 | F | 11
nom 4 | M | 13

J'aimerais faire la moyenne d'une certaine matière pour les hommes seulement par exemple.
C'est à dire calculer la moyenne des valeurs d'une colonne mais seulement pour les hommes.. Donc je ne sais pas comment faire ça.
Si il faut utiliser une combinaison de SI et de RECHERCHE ou quelque chose d'autre....
Merci d'avance ! ;-)

 

[Monique]

Bonjour,

Sexe en colonne B, note en colonne C

Si tous les noms ont une note :
=SOMMEPROD((B2:B10="F")*C2:C10)/NB.SI(B2:B10;"F")
fait la somme des notes, à condition que la lettre située sur la même ligne soit un F
puis divise cette somme par le nb de F

Si certaines cellules de notes sont vides ou contiennent du texte :
=SOMMEPROD((B2:B10="F")*C2:C10)/SOMMEPROD((B2:B10="F")*(ESTNUM(C2:C10)))
fait la somme des notes, à condition que la lettre située sur la même ligne soit un F
puis divise cette somme par le nb de F, à condition que le F ait une note sur la même ligne.

 

[Bernard]

Bonjour Julien et Monique

Tu peux aussi utiliser le filtre automatique :

1- Tu sélectionnes la lignes des étiquettes des colonnes concernées, toutes devant être remplies;

2- Tu places au-dessus des colonnes à calculer la formule : =SOUS.TOTAL(1;A$11:A$200) ; 1 représente le sous-total moyenne, le reste la colonne prise en compte.

3- Activer le filtre automatique par le menu Données/Filtrer/Filtre automatique et choisir dans les listes déroulantes mises en place choisir le critère "Masculin".


Si tout va bien, le sous total de la matière te donne la moyenne souhaitée.

Pour revenir à zéro, désactiver le filtre automatique.

Cordialement

Bernard

 

[Julien]

Je vous remercie, ça marche très bien ! ;-)
Et maintenant une p'tite question bonus :
Comment est-ce que je fais, toujours avec le même tableau, pour connaitre le nombre de femmes dont la note est inférieure à 10 par exemple ?

 

[Monique]

Re,

Nb de femmes dont la note est inférieure à 10 :
=SOMMEPROD((B2:B10="F")*(C2:C10<10)*(ESTNUM(C2:C10)))

Nb de femmes dont la note est supérieure à 5 et inférieure à 15 :
=SOMMEPROD((B2:B10="F")*(C2:C10>5)*(C2:C10<15)*(ESTNUM(C2:C10)))

Nb de femmes dont la note est soit inférieure ou = à 5, soit supérieure ou = à 15 :
=SOMMEPROD((B2:B10="F")*((C2:C10<=5)+(C2:C10>=15))*(ESTNUM(C2:C10)))

Nb de femmes dont la note est inférieure à 10 et dont le nom commence par un A :
=SOMMEPROD((B2:B10="F")*(C2:C10<10)*(ESTNUM(C2:C10))*(GAUCHE(A2:A10)="A"))
(les noms sont en A2:A10)
On peut continuer comme ça jusqu'à 30 arguments.

Le signe * équivaut au ET des formules conditionnelles,
le + équivaut au OU et le - équivaut à SAUF

 

[Bernard]

Rebonjour Julien

Tu peux aussi utiliser le filtre automatique :

1- Toujours sélectionner la ligne des étiquettes ;

2- Toujours activer le filtre automatique par le menu Données/Filtrer/Filtre automatique et choisir dans les listes déroulantes "Sexe" et dans la matière tu choisis "Personnalisé" et tu configures ton choix, dans ton exemple <10. OK et Le filtrage est là !

Pour revenir à zéro, désactiver le filtre automatique.

Cordialement

Bernard