XL 2016 mise a jour de tableau avec des textbox

[auverland]

Bonjour,
Je ne comprend pas mon ereur de code...
Lorsque j'arrive dans cette boucle il vas bien me completer ma première cellule en colonne 58 mais pas les suivante (59 et 60) .
Si je desactive la ligne "Cells(y, 58) = Me.Txt_Couple... " il complete la cellule en 59 mais pas les suivantes

Je voulais me servir de cette boucle pour mettre a jour un tableau avec des Textbox d'un formulaire

Merci de votre aide

Private Sub Cmd_Modif_Click()
Dim y As Byte
Sheets("Gamme").Activate
For y = 2 To Range("F:F").End(xlDown).Row
If Txt_NumBV.Text = Cells(y, 6) Then
Cells(y, 58) = Me.Txt_Couple_1.Value
Cells(y, 59) = Me.Txt_Reg_1.Value
Cells(y, 60) = Txt_Tps_1.Value
End If
Next y

End Sub

 

[Kael_88]

le forum,@auverland ,

Remplace
For y = 2 To Range("F:F").End(xlDown).Row
par
For y = 2 To Range("F36541").End(xlUp).Row
ou bien
For y = 2 To Range("F2").End(xlDown).Row

et ca devrait etre mieux.

Cordialement

 

[Staple1600]

Bonsoir le fil, le forum, auverland

@auverland
Une autre syntaxe possible

Private Sub Cmd_Modif_Click()
Dim y As Long
For y = 2 To Sheets("Gamme").Cells(Rows.Count, 6).End(xlUp).Row
If Txt_NumBV.Text = Cells(y, 6) Then
Cells(y, 58).Resize(, 3) = Array(Txt_Couple_1, Txt_Reg_1, Txt_Tps_1)
End If
Next y
End Sub

 

[job75]

Bonsoir auverland, Kael_88, JM,

Sans boucle c'est sans doute plus rapide :

Private Sub Cmd_Modif_Click()
Application.ScreenUpdating = False
On Error Resume Next
With Sheets("Gamme")
    If .[A1].Formula = "" Then .[A1] = " "
    With .UsedRange
        .AutoFilter 6, Txt_NumBV 'filtre automatique
        With .Offset(1).Resize(.Rows.Count - 1)
            .Columns(58).SpecialCells(xlCellTypeVisible) = Txt_Couple_1.Value
            .Columns(59).SpecialCells(xlCellTypeVisible) = Txt_Reg_1.Value
            .Columns(60).SpecialCells(xlCellTypeVisible) = Txt_Tps_1.Value
        End With
    End With
    .AutoFilterMode = False
End With
End Sub

Bonne nuit.