mail lotus avec piece jointe

[yoda60]

bonjour

je n'ai pas trouver de solution sur le forum (je ne suis pas fort en vba).

comment peut on modifier ce code pour y joindre une piece jointe situé sur le bureau ?

merci de votre aide !

cordialement


Sub SendNotesMail()
On Error Resume Next

Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim EmbedObj As Object 'The embedded object (Attachment)

Set Session = CreateObject("Notes.NotesSession")
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
'Open the mail database in notes
Set Maildb = Session.GetDatabase("", MailDbName)
If Maildb.IsOpen = True Then
'Already open for mail
Else

Maildb.OPENMAIL

End If
'Set up the new mail document
Set MailDoc = Maildb.CreateDocument
MailDoc.Form = "Memo"
MailDoc.Subject = "ssdfsf ......"
MailDoc.body = "message....."
MailDoc.SAVEMESSAGEONSEND = saveit


'Send the document
MailDoc.PostedDate = Now()
MailDoc.Send 0, "toto@gdfg.com"
'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set Session = Nothing
Set EmbedObj = Nothing
End Sub

 

[Roland_M]

Re : mail lotus avec piece jointe

bonsoir,

voir classeur ci-joint si ça peut aider !?

 

[yoda60]

Re : mail lotus avec piece jointe

merci
ce fichier c'est impréssionant !!

mais ce n'est pas ce qu'il me faut et j'avoue avoir du mal a comprendre le code.

j'aimerais vraiment juste avoir le morceau de code pour envoyer une pièce jointe situé sur mon bureau.

en tous cas merci de ton aide
cordialement

 

[Roland_M]

Re : mail lotus avec piece jointe

re,

ci-joint ton code modifié !
pour la saisie du chemin et du fichier voir les rems ci-dessous !?
tu as le choix en enlevant et en mettant les rem(') sur l'une des deux méthodes

Sub SendNotesMail()
'----------------------
On Error GoTo ErreurNET: Err.Clear
Dim CheminEtFichier As String, NomDuFichier As String

'---------------------- SOIT SAISIR LE FICHIER AVEC SON CHEMIN AVEC BOITE DE DIALOGUE
CheminEtFichier = Application.GetOpenFilename("(*.*), *.*")
If CheminEtFichier = "Faux" Then Exit Sub

'---------------------- SOIT SAISIR LE FICHIER EN DUR ICI ET LE CHEMIN SERA MIS AUTO
'NomDuFichier = ""
'CheminEtFichier = "C:\Documents and Settings\" & Environ("username") & "\Bureau\" & NomDuFichier
'----------------------------------------------------------------------------------------

Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim Session As Object 'The notes session
'---------------------
Dim AttachME As Object 'Fich joint en RTF
Dim AttachF1 As Object '1' pièce attachée
'---------------------

Set Session = CreateObject("Notes.NotesSession")
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
'Open the mail database in notes
Set Maildb = Session.GetDatabase("", MailDbName)
If Maildb.IsOpen = True Then
  'Already open for mail
Else
  Maildb.OPENMAIL
End If
'Set up the new mail document
Set MailDoc = Maildb.CreateDocument
MailDoc.Form = "Memo"
MailDoc.Subject = "ssdfsf ......"
MailDoc.body = "message....."

'---------------------- pièce jointe
Set AttachME = MailDoc.CreateRichTextItem("Attachment")
Set AttachF1 = AttachME.EmbedObject(1454, "", CheminEtFichier, "Attachment")
'----------------------

MailDoc.SAVEMESSAGEONSEND = True

'Send the document
MailDoc.PostedDate = Now()
MailDoc.Send 0, "toto@gdfg.com"
'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set AttachF1 = Nothing
Set Session = Nothing

'-------------------------
On Error GoTo 0: Err.Clear
Application.ScreenUpdating = True
Exit Sub

ErreurNET: 'trit erreur
Msg$ = "Erreur " & Err.Source & "  No " & Err.Number & vbLf & vbLf & Err.Description
T$ = "Envoi Mail: Erreur !?"
MsgBox Msg$, vbCritical, T$, Err.HelpFile, Err.HelpContext
On Error GoTo 0: Err.Clear
Application.ScreenUpdating = True
'-------------------------
End Sub

 

[yoda60]

Re : mail lotus avec piece jointe

SUPER !!!!!!!

merci de ton aide c'est parfait

cordialement

 

[Roland_M]

Re : mail lotus avec piece jointe

re

j'espère que tu l'as pris après la modif faite de 8h34 !

 

[yoda60]

Re : mail lotus avec piece jointe

oui nickel

mais juste un complèment d'info comment ajouté une ou 2 adresse en copie du mail ?

aurait tu une idée ?

cordialement

 

[Roland_M]

Re : mail lotus avec piece jointe

re

Pour envoi à plusieurs destinataires,
les séparer par le ( ; ) voir par la ( , ) à vérifier car perso je n'ai pas lotus et ne peut pas essayer !?
Exemple: nom1@site.fr;nom2@site.com; ...
ici:
MailDoc.Send 0, "toto@gdfg.com;nom1@site.fr;nom2@site.com"

 

[yoda60]

Re : mail lotus avec piece jointe

encore merci pour ton aide

j'essai demain

 

[yoda60]

Re : mail lotus avec piece jointe

ca ne marche pas , c'est curieux !?

as tu une solution pour contourner le problème en mettant quelqu'un en copy , plutot que 2 destinataire principaux ?

cdt