macro sur certaines feuiles

[jeromear]

Bonjour
J'ai fait cette macro qui doit s'adapter à certaines feuilles du classeur mais elle ne marche que feuille par feuille.
Il doit y avoir une erreur. Mais ou ?
Merci pour vos reponses.

Sub EFFACER()
'
' EFFACER Macro
' Macro enregistrée le 14/01/2010 par JEROME
'


Dim cel As Range
Dim tablo, i As Byte
Application.ScreenUpdating = False
tablo = Array("COM1", "COM2", "COM3", "COM4", "COM5", "COM6", "COM7", "COM8", "COM9", "COM10") 'nombre de feuilles étudiées limité à 255, sinon => i As Integer
For i = 0 To UBound(tablo)
With Sheets(tablo(i))
     ActiveSheet.Unprotect
    Range("A10:AI24").Select
    Selection.ClearContents
    Range("A10").Select
    ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
    Range("A10").Select

End With
Next i
End Sub

 

[Dull]

Re : macro sur certaines feuiles

Salut jeromear, le Forum

Essaye ce code si j'ai bien compris

Sub EFFACER()
'
' EFFACER Macro
' Macro enregistrée le 14/01/2010 par JEROME
'


Dim cel As Range
Dim tablo, i As Byte
Application.ScreenUpdating = False
tablo = Array("COM1", "COM2", "COM3", "COM4", "COM5", "COM6", "COM7", "COM8", "COM9", "COM10") 'nombre de feuilles étudiées limité à 255, sinon => i As Integer
For i = 0 To UBound(tablo)
With Sheets(tablo(i))
    .Unprotect
    .Range("A10:AI24").ClearContents
    .Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
End With
Next i
End Sub

Bonne Journée

 

[jeromear]

Re : macro sur certaines feuiles

Bonjour Dull
effecetivement cela marche comme cela.
Mais je ne comprends tjrs pas ce qui bloquait la boucle sur le tablo
Bonne journée a toi

 

[Dull]

Re : macro sur certaines feuiles

Re jeromear

Pas très pédagogue que je suis... néanmoins je vais essayer de t'expliquer

Dans ton code il y a:

With Sheets(tablo(i)) qui passe en revue les feuilles de ton array donc les
ActiveSheet.Unprotect ainsi que le ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True deviennent inutile

avec ton code ça protège la Feuille Active et déprotège les autres

Bonne Journée

 

[jeromear]

Re : macro sur certaines feuiles

Compris! merci pour cette explication ca m'aide à progresser
Bonne journée a toi