macro : archiver les données dans une autre feuille

[kakachi]

Bonjour,

je cherche a écrire une macro qui archive mes données dans une autre feuille excel,cependant je ne sais pas comment procéder et je n'arrive pas a écrire la macro " archivage ".C'est pour cela que je sollicite votre aide

je vous envoie en pièce jointe mon fichier excel, qui ne contient pas de macro" archivage", afin que vous puissiez visualiser mon problème

@+!!! et bonne continuation

 

[PMO2]

Re : macro : archiver les données dans une autre feuille

Bonjour,

Copiez le code suivant dans un module standard

Const SOURCE As String = "Pronos"
Const ARCHIVES As String = "Archivage_résultats"

Sub Archivage()
Dim S1 As Worksheet
Dim S2 As Worksheet
Dim R As Range
Dim var1
Dim var2
Dim i&
Dim j&
Dim T(1 To 1, 1 To 5)
Set S1 = Sheets(SOURCE)
Set R = S1.[b1].CurrentRegion
var1 = R
Set S2 = Sheets(ARCHIVES)
Set R = S2.[a1].CurrentRegion
var2 = R
For i& = 2 To UBound(var2, 1)
  If CDate(var1(1, 2)) = CDate(var2(i&, 1)) Then
    MsgBox "La date du " & CDate(var1(1, 2)) & " est déjà renseignée."
    Exit Sub
  End If
Next i&
T(1, 1) = CDate(var1(1, 2))
j& = 3
For i& = 3 To UBound(var1, 1)
  If var1(i&, 1) <> "" Then
    T(1, j&) = var1(i&, 1)
    j& = j& + 1
  End If
Next i&
Set R = S2.Range("a" & UBound(var2, 1) + 1 & ":e" & UBound(var2, 1) + 1 & "")
R = T
End Sub

Cordialement.

PMO
Patrick Morange

 

[kakachi]

Re : macro : archiver les données dans une autre feuille

bonjour PMO,

Merci pour ton programme !!!
c'est exactement ce que je voulais comme macro !!!!
Bonne continuation !!!!

@+ !!!!!!