Lien hypertexte sur feuille masquée

[oreyi19]

Bonjour,

je vais pour la première fois utiliser VBA mais je ne sais pas comment cela fonctionne.

J'ai créée un fichier excel comportant 12 onglets (mois de l'année).
Dans ces 12 feuilles je fais référence avec des liens hypertexte à 8 autres feuilles (Ville).

Pour plus de visibilité, je souhaiterai que seules les 12 feuilles indiquant l'année soient affichées.

De ce fait, comment dois je faire pour que mes liens hypertextes contenus dans mes 12 feuilles renvoient chacun à une des 8 autres feuilles masquées?

Merci de m'indiquer également la procédure détaillée car je ne sais où cliquer.

 

[mromain]

Re : Lien hypertexte sur feuille masquée

Bonsoir oreyi19

Voici une solution par VBA. Le code est à placer dans le module objet ThisWorkbook.
Il faut bien sur adapter le nom des villes.

'encadrer et séparer les noms de feuilles par des ?
 Private Const ListeFeuillesCachees As String = "?Toulouse?Bayonne?Strasbourg?"


Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
    'si la feuille ne fait pas partie des feuilles à cacher, quitter la macro
     If InStr(ListeFeuillesCachees, "?" & Sh.Name & "?") = 0 Then Exit Sub
    'masquer la feuille
     Sh.Visible = xlSheetHidden
End Sub


Private Sub Workbook_SheetFollowHyperlink(ByVal Sh As Object, ByVal Target As Hyperlink)
Dim nomFeuille As String
    
    'récupérer le nom de la feuille pointée par le lien hipertexe
      nomFeuille = Application.Range(Target.SubAddress).Parent.Name
    
    'si la feuille fait partie des feuilles cachées
     If InStr(ListeFeuillesCachees, "?" & nomFeuille & "?") <> 0 Then
        'afficher la feuille
         On Error Resume Next
         Application.Range(Target.SubAddress).Parent.Visible = xlSheetVisible
        On Error GoTo 0
    End If
    
    'suivre le lien hipertexe
     Application.EnableEvents = False
    Target.Follow
    Application.EnableEvents = True
End Sub

A+

 

[oreyi19]

Re : Lien hypertexte sur feuille masquée

Bonsoir,

Merci pour cette réponse rapide et claire.

J'ai bien indiqué le code mais ça ne fonctionne qu'a moitié.

En effet, quand je clique sur le lien hypertexte, ça m'ouvre la feuille cachée dans un onglet mais ça ne me revoit pas automatiquement vers elle.

Je suis obligée de faire un double clic pour y acceder directement.

Comment procéder dans ce cas afin que j'y accede avec 1 seul clic ?

Merci.

 

[mromain]

Re : Lien hypertexte sur feuille masquée

Bonjour oreyi19,


Bizarre, Est-ce que le fichier que j'ai envoyé précédemment fonctionne bien sur ton Excel ?
Si c'est le cas, ça doit venir de ton fichier - et ce sera difficile de le diagnostiquer sans y jeter un œil...

A+

 

[DoubleZero]

Re : Lien hypertexte sur feuille masquée

Bonjour, oreyi19, mromain, le Forum,

S'il est acceptable que les onglets "mois" soient masqués, tout comme les onglets "villes", une suggestion en pièce jointe (grâce à cette discussion ).

A bientôt.