lancer une macro par activation de cellule

[PHILIP]

Bonjour à tous

Est-il-possible d'activer une macro en activant une cellulle de la colonne A , cellule qui selectionnera les données de sa ligne et les collera dans des cellulles designées dans feuill 2 J'ai écris un code qui ne marche pas trop

Sub Macro15()

    Sheets("recap sinistres").Select
    For i = 2 To 100
    If Cells(i, 1).Activate Then
    Range("A" & i).Select
    Selection.Copy
    Sheets("document").Select
    Range("D1,c10").Select
    ActiveSheet.Paste
    Sheets("recap sinistres").Select
    Range("B" & i).Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("document").Select
    Range("B13").Select
    ActiveSheet.Paste
    Sheets("recap sinistres").Select
    Range("C" & i).Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("document").Select
    Range("B15").Select
    ActiveSheet.Paste
    Exit For
    End If
    Next i
    End Sub

 

[Softmama]

Re : lancer une macro par activation de cellule

Bonjour,

essaie ceci (à coller dans le module de ta feuille de calcul Recap Sinistres : clic droit sur l'onglet de la feuille et choisir Visualiser le code) :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Count = 1 Then
  If Target.Column = 1 Then
    With Sheets("document")
      Union(.Range("D1"), .Range("C10")) = Target
      .Range("B13") = Target.Offset(0, 1)
      .Range("B15") = Target.Offset(0, 2)
    End With
  End If
End If
End Sub