XL 2013 Importer une image d'un site Web

[maval]

Bonjour,

J'ai une question, est-il possible d'importer une image d'un site Web dans contrôle image se trouvant sur un Usf.

Je vous remercie d'avance

 

[Lone-wolf]

Re : Importer une image d'un site Web

Bonjour Max,

oui c'est possible.

'Dans un module standard
Public Const url As String = "http://www.monblogamoi.com/"     'url de l'image
Public chemin, Fichier, img As String


'À placer dans le module du formulaire

Private Declare Function URLDownloadToFile Lib "urlmon" Alias _
        "URLDownloadToFileA" (ByVal pCaller As Long, ByVal szURL As String, _
        ByVal szFileName As String, ByVal dwReserved As Long, _
        ByVal lpfnCB As Long) As Long

       img =  "tarzan.jpg"
       Fichier = url &  "/" & img
      chemin = ThisWorkbook.Path & "\fichier"
      URLDownloadToFile 0, Fichier, chemin, 0, 0
 With Me
    .Image1.Picture = LoadPicture(chemin)
  End With

A+

 

[maval]

Re : Importer une image d'un site Web

Bonjour Lone-Wolf,

Je te remercie beaucoup mais je n'arrive pas a ajouter ton code à mon Usf
Je joint mon fichier avec lequel le recherche l'acteur sur Google.

Je te souhaite une bonne journée

 

[Lone-wolf]

Re : Importer une image d'un site Web

Re Max,

c'est impossible. Dans google images tu as des 10aine de liens, lequel de ces liens tu veux avoir???
Si tu as un blog, où tu as un dossier images, là tu peux les lister.


EDIT: j'ai retrouver un de tes anciens SOUVENIRS




A+

 

[maval]

Re : Importer une image d'un site Web

Re,

Non j'ai du mal m'expliquer en faite avec le code que j'ai envoyé je trouve l'image de la je fait un copier et je voulais avec l'Usf pouvoir coller dans le contrôle image.

@+

 

[Lone-wolf]

Re : Importer une image d'un site Web

Re,

alors là, j'aimerais bien que tu m'explique.

Je cherche A lin de long sur google(images)- dans la barre de recherche j'ai ceci:

Avertissement de redirection

Ce n'est pas celle de google qui faut copier mais le lien du site d'où elle provient, c'est à dire:
Krealinks[1].jpg

Pour connaître ce lien, moi je le fait avec Firefox, clique droit sur l'image >Informations sur l'image et là tu trouve cette adresse.

Et là je te souhaite mes meilleurs voeux.



A+

 

[maval]

Re : Importer une image d'un site Web

Re,

Mais je croyais qu'il était possible de copier la photo dans le presse papier et avec l'Usf coller dans le contrôle image.

@+

 

[job75]

Re : Importer une image d'un site Web

Bonjour maval, Lone-wolf,

Mais je croyais qu'il était possible de copier la photo dans le presse papier et avec l'Usf coller dans le contrôle image.

Oui par exemple en exécutant cette macro dans l'USF :

Sub AfficheImage()
Dim chemin$, w, h
chemin = ThisWorkbook.Path
Application.DisplayAlerts = False 'si le fichier existe déjà
On Error Resume Next 's'il n'y a rien dans le presse-papiers
With ActiveSheet
  .Paste
  If Err Or TypeName(Selection) <> "Picture" Then Exit Sub
  w = Selection.Width: h = Selection.Height: Selection.Delete
  With .ChartObjects.Add(0, 0, w, h).Chart
    .Paste
    .Export chemin & "\MonImage.jpg", "JPG"
    .Parent.Delete
  End With
  .[A1].Copy [A1] 'facultatif, vide le presse-papiers
End With
Image1.Picture = LoadPicture(chemin & "\MonImage.jpg")
Kill chemin & "\MonImage.jpg"
End Sub

A+

 

[maval]

Re : Importer une image d'un site Web

Bonjour Job

Je vous remercie beaucoup mais j'ai juste une question pourquoi l'image que je copie dans le presse papier ne s'affiche pas dans le contrôle image de l'Usf mais sur la feuille?

Mercie et bonne soirée

 

[job75]

Re : Importer une image d'un site Web

Re,

Parce que l'image n'est pas une "Picture", alors peut-être, sans aucune certitude :

Sub AfficheImage()
Dim chemin$, w, h
chemin = ThisWorkbook.Path
Application.DisplayAlerts = False 'si le fichier existe déjà
On Error Resume Next 's'il n'y a rien dans le presse-papiers
With ActiveSheet
  .Paste
  If Err Or TypeName(Selection) = "Range" Then Exit Sub
  w = Selection.Width: h = Selection.Height: Selection.Delete
  With .ChartObjects.Add(0, 0, w, h).Chart
    .Paste
    .Export chemin & "\MonImage.jpg", "JPG"
    .Parent.Delete
  End With
  .[A1].Copy [A1] 'facultatif, vide le presse-papiers
End With
Image1.Picture = LoadPicture(chemin & "\MonImage.jpg")
Kill chemin & "\MonImage.jpg"
End Sub

A+

 

[maval]

Re : Importer une image d'un site Web

Re,

oui nickel merci beaucoup et bonne soirée

 

[maval]

Re : Importer une image d'un site Web

Bonjour Job

J'ai parler un peut trop vite sa fonctionne une fois sur cinq je ne comprend pas pourquoi avec la même image. Par contre si je copie une image de ma feuille excel aucun problème?

Je joint mon fichier

Bonne journée

 

[Lone-wolf]

Re : Importer une image d'un site Web

Bonjour maval, job

est-ce que l'image est enregistrée dans un dossier?

chemin = ThisWorkbook.Path & "\Mes Artsistes\" par exemple.


A+

 

[maval]

Re : Importer une image d'un site Web

Bonjour Lone-Wolf

Non l'image est copier dans le presse papier a partir d'internet et après coller dans un contrôle image sur un Usf

@+

 

[job75]

Re : Importer une image d'un site Web

Bonjour maval, Lone-wolf, le forum,

Pour éviter de coller dans la feuille la copie d'une plage de cellules utiliser une feuille auxiliaire :

Private Sub CommandButton3_Click()
Dim chemin$, w, h
chemin = ThisWorkbook.Path
Application.ScreenUpdating = False
Application.DisplayAlerts = False
On Error Resume Next 's'il n'y a rien dans le presse-papiers
Image1.Picture = LoadPicture("") 'RAZ
With Sheets.Add 'nouvelle feuille
  .Paste
  DoEvents
  If TypeName(Selection) <> "Range" Then
    w = Selection.Width: h = Selection.Height: Selection.Delete
    With .ChartObjects.Add(0, 0, w, h).Chart
      .Paste
      .Export chemin & "\MonImage.jpg", "JPG"
    End With
    Image1.Picture = LoadPicture(chemin & "\MonImage.jpg")
    Kill chemin & "\MonImage.jpg"
  End If
  .Delete 'suppression de la nouvelle feuille
End With
[A1].Copy [A1] 'facultatif, vide le presse-papiers
Application.ScreenUpdating = True
End Sub

Bonne journée.

Edit : je n'avais pas vu le post #12, j'ai ajouté DoEvents.