Bonsoir José, Prométhée, le Forum
José m'a demandé à la rescousse, mais moi mon truc c'est les UserForms, mais j'ai quand même regardé...
A mon avis au regard de ce qu'à écrit Laurent Longre Lui-même sur le MPFE ce n'est pas coton !!!
From: Laurent Longre
Subject: Re: Info bulle et nuage de points
View: Complete Thread (9 articles)
Original Format
Newsgroups: microsoft.public.fr.excel
Date: 2002-10-12 20:10:03 PST
Je ne sais pas trop comment modifier le contenu par défaut de ces
infos-bulles affiché par Excel, mais sinon tu peux toujours afficher les
informations que tu veux dans la barre d'état.
Cet exemple suppose que les séries de ton graphique sont contenues dans
des plages verticales et que ce graphique est incorporé dans la feuille
"Feuil1" (nom du module attaché à la feuille). Il affiche dans la barre
d'état les adresses de cellules et les valeurs de l'abscisse et de
l'ordonnée du point sur lequel se trouve la souris, libre à toi
d'afficher d'autres infos à partir de là.
'===== Dans le module ThisWorkbook =====
Dim Graph As Classe1
Private Sub Workbook_Open()
Set Graph = New Classe1
Set Graph.Graph = Feuil1.ChartObjects(1).Chart
End Sub
'===== Dans le module de classe "Classe1" =====
Public WithEvents Graph As Chart
Private Sub Graph_MouseMove(ByVal Button As Long, _
ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
Dim ElementID As Long, SeriesIndex As Long, PointIndex As Long
Dim S As Series, I As Integer, J As Integer, Form As String
Dim CellX As Range, CellY As Range
Graph.GetChartElement x, y, ElementID, SeriesIndex, PointIndex
If ElementID = xlSeries Then
Form = Graph.SeriesCollection(SeriesIndex).Formula
I = InStr(1, Form, ",") + 1
J = InStr(I, Form, ",") + 1
Set CellX = Range(Mid$(Form, I, J - I - 1))(PointIndex)
Set CellY = Range(Mid$(Form, J, InStr(J, Form, ",") -
J))(PointIndex)
Application.StatusBar = "Cellules= " & CellX.Address & ", " _
& CellY.Address & " | valeurs = " & CellX & ", " & CellY
Else: Application.StatusBar = False
End If
End Sub
Pour que ça marche, il faut exécuter d'abord Workbook_Open. La procédure
MouseMove est appelée dès que tu déplaces la souris dans le graphique
(celui-ci doit être activé) et permet d'obtenir les coordonnées du
pointeur. La méthode GetChartElement donne des informations sur
l'élément du graphique pointé par ces coordonnées.
Bonne chance,
Laurent
Je te renouvelle les souhaits de Laurent.... Bonne Chance
@+Thierry