imbriquer plus de 7 fonctions SI

[azimut]

Bonjour,

J'ai besoin d'utiliser 11 fonction "SI" sauf qu'on est limiter à 7 sous excel 2003, j'ai essayer de retravailler ma formule pour contourner cela mais je seche. en faite j'ai un tableau à plusieur colonne, et plusieur ligne et je dois reproduire la fonction recherchev( sur chacune des colonnes

voici ma formule

=SI(B13="";"";SI(C13="3R313";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;2;FAUX);SI(C13="3R314";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;3;FAUX);SI(C13="3R540";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;4;FAUX);SI(C13="3R541";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;5;FAUX);SI(C13="3R120";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;6;FAUX);SI(C13="3R310";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;7;FAUX);"")))))))

pouvez vous améliorer ma formule svp
merci

 

[noviceAG]

Re : imbriquer plus de 7 fonctions SI

Bonjour azimut, le Forum,
Il te suffit tout simplement d'utiliser plusieurs cellules comme "fonction Si."
en l'occurence, une seule pour les 6 premiers SI

 

[Dranreb]

Re : imbriquer plus de 7 fonctions SI

bonjour
Tient on dirait que vous eêtes dans un cas de figure où la fonction RECHERCHEV n'est pas si détestable que d'habitude !
Vous devez bien avoir vos "3R313" etc dans chaque colonne d'une ligne particulière non ?
de la ligne 1 de 'Code FGX' par exemple ?
Alors:

=SI(B13="";"";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;EQUIV(C13;'Code FGX'!$C$1:$M$1;0);FAUX))

À paufiner...

 

[hoerwind]

Re : imbriquer plus de 7 fonctions SI

Bonjour,

Pas facile sans ton fichier en pièce jointe, car pas moyen de tester si ce n'est en reconstruisant ton fichier, alors que tu l'as sous les yeux !

Essaie néanmoins cette formule :

=SI(B13="";"";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;EQUIV(C13;{"3R313";"3R314";"3R540";"3R541";"3R120";"3R310"};0)+1;0)

Si cela ne fonctionne pas, tu sais ce qu'il te reste à faire.

 

[Dranreb]

Re : imbriquer plus de 7 fonctions SI

À la réflexion, le RECHERCHEV me paraît aussi haïssable qu'ailleurs: J'aurai plutôt utilisé un INDEX dans tout le tableau, avec un EQUIV pour trouver et spécifier la ligne, et un autre pour la colonne.
Cordialement.

 

[ROGER2327]

Re : imbriquer plus de 7 fonctions SI

Bonjour à tous

Un truc du genre

=INDEX(Feuil2!C6:M29;B13;EQUIV(C13;{"3R313";"3R314";"3R540";"3R541";"3R120";"3R310"};0))

devrait faire l'affaire. Mais sans support, ce n'est pas testé…

J'ai la même opinion que Dranreb sur RECHERCHEV() et consorts. Ce sont des fonctions d'un autre siècle, utiles quelquefois pour des raisons de compatibilité avec de vieux tableurs. Je suppose que la routine est la cause de leur survivance chez les utilisateurs de versions modernes d'Excel, car la compatibilité avec les vieux_machins.xls n'est certainement pas une bonne raison quand on écrit des super_modernes.xlsx…
​

ROGER2327
#5353

Lundi 2 Gidouille 138 (Saint Lucullus, amateur(Bloosday) - fête Suprême Quarte)
28 Prairial An CCXIX, 5,7752h - thym
2011-W24-4T13:51:38Z

 

[Nabran]

Re : imbriquer plus de 7 fonctions SI

Bonjour ,
Oui les index equiv sont puissants, n'oubliez pas l'outil "lookup" dans les macros complémentaires (xl 2003) qui génère les index equiv à personnaliser apres .

Un exemple de fichier serait un plus en effet une aide

 

[azimut]

Re : imbriquer plus de 7 fonctions SI

Bonjour,

Pas facile sans ton fichier en pièce jointe, car pas moyen de tester si ce n'est en reconstruisant ton fichier, alors que tu l'as sous les yeux !

Essaie néanmoins cette formule :

=SI(B13="";"";RECHERCHEV(B13;'code FGX'!$C$6:$M$29;EQUIV(C13;{"3R313";"3R314";"3R540";"3R541";"3R120";"3R310"};0)+1;0)

Si cela ne fonctionne pas, tu sais ce qu'il te reste à faire.

Merci, voila qui marche impec je ne connaissais cette fonction index, j'aurais appris un truc