formule multi-critères

[braque]

Bonjour,

Je ne suis pas un pro d'excel, mais je me lance ...
j'essaye de trouver une formule qui me permette d'additionner par exemple les sommes de la colonne H, chaque fois que je trouve '6510' en colonne A et '4' en colonne C; ou '6511' en colonne a et 25 en colonne C.
Cela sur un fichier comprenant plus de 3500 lignes.
Quelqu'un aurait il une idée à me proposer ?
d'avance un grand merci.
Je joint un extrait de mon fichier si sa peu aider.

 

[Gérard DEZAMIS]

Bonjour Braque

=SOMMEPROD((A1:A3500=6510)*(C1:C3500=4)*(H1:H3500))+SOMMEPROD((A1:A3500=6511)*(C1:C3500=25)*(H1:H3500))

si j'ai bien compris

@+ GD

 

[Jocelyn]

Bonjour le Forum,
Bonjour Braque, Gérard DEZAMIS,

j'ai compris la même chose que toi Gérard alors juste un élément pour raccourcir la formule.

on peut ecrire :

=SOMMEPROD(((A1:A3500=6510)+(A1:A3500=6511))*((C1:C3500=4)+(C1:C3500=25))*H1:H3500)

Jocelyn

 

[Gérard DEZAMIS]

Salut à tous
Bonjour Jocelyn
ton 'raccourci' me semble poser un probleme
en effet la demande de Braque indiquait des critères couplés

(6510 en A et 4 en C) ou (6511 en A et 25 en C)

Ta formule 'mélange les critère et ainsi par exemple un 6510 avec 25 va fonctionner ce qui n'est pas juste

Sauf erreur de ma part ....

@+ GD.

 

[Jocelyn]

re bonjour,

Exact Gérard tu as entierement raison la prochaine fois j'attendrais d'etre totalement réveillé avant de poster. :whistle: :whistle:

Jocelyn

 

[Monique]

Bonjour,

On peut la raccourcir, sauf erreur :
=SOMMEPROD(((A1:A3500=6510)*(C1:C3500=4)+(A1:A3500=6511)*(C1:C3500=25))*H1:H3500)
ou bien :
=SOMMEPROD(((A1:A3500&C1:C3500=6510&4)+(A1:A3500&C1:C3500=6511&25))*H1:H3500)

 

[BRAQUE]

Bonjour le Forum, Bonjour Gérard Dezamis, Jocelyn et monique.

Un grand MERCI avous tous, c'est vraiment génial.
Ca marche impec
Braque