formule conditionnelle

[jlzcaps238]

Bonjour à tous,

Dans la feuille ci-jointe, je souhaiterais qu'en colonne G soit affiché selon certaines condition "Gms à relancer"

Exemple en ligne 4

Première condition :

Fx cellule G4 : Si la cellule B4 contient le mot "CAB_DYC" ou "ASCENSEURS_DYC"
ET QUE
la date de déclenchement de la DI en cellule E4 est inférieure ou égale à la date du jour saisie en cellule F1, alors ne rien inscrire en cellule G4, si date, sinon inscrire automatiquement Gms à relancer en cellule G4

Deuxième condition :

Fx cellule G4 Si la cellule B4 contient le mot "PORTES_DYC" ou "AUTRES_DYC"
ALORS
indiquer en cellule G4 "Gms à relancer" 5 jours après la date de déclenchement de la DI

Dernière condition :
Si une date en F4 est entrée , alors indiquer en cellule G4 "GMS à relancer" 5 jours après cette date entrée en F4.

Merci beaucoup pour votre aide

Gil

 

[Dugenou]

Bonjour,
ceci semble fonctionner :

=SI(ET(F4>0;$F$1>F4+4);"gms à relancer";SI(ET(E4>0;E4>$F$1;OU(B4="cab_dyc";B4="ascenseurs_dyc"));"gms à relancer";SI(ET(OU(B4="portes_dyc";B4="autres_dyc");E4>0;$F$1>E4+4);"gms à relancer";"")))

voir pj
Cordialement

 

[CISCO]

Bonjour

Est-ce que tu peux tester la formule suivante

SI((((B4<>"CAB_DYC")+(B4<>"ASCENSEURS_DYC"))*(E4>F$1))
+(((B4="PORTES_DYC")+(B4="AUTRES_DYC"))*(AUJOURDHUI()>=E4+5))+(F4<>"");"Gms à relancer";"")

@ plus

P.S : Bonjour Dugenou

 

[Noel Bedard]

Bonjour à tous,
Je me suis aussi amusé avec cette ligne, si vous permettez je vous présente mon raisonnement:

 =SI(ET($E4<>"";$F4<>"");SI(ET(OU($B4="CAB_DYC";$B4="ASCENSEURS_DYC");$E4<=$F$1);"1";SI(ET(OU($B4="PORTES_DYC";$B4="AUTRES_DYC");$F$1>=$E4+5);"Gms à relancer(1)";SI($F$1>=$F4+5;"Gms à relancer(2)";"2")));"3")

F1 = Date d' Aujourd'hui, j'ai placé des numéros comme référence pour savoir la sortie que prenait ma formule.

Condition #0:
E4 = "" rien ET F4 = "" rien, ne rien faire "3" numéro comme référence
Condition #1:
B4 = ("CAB_DYC" OU "ASCENSEURS_DYC") ET E4 <= F1 si VRAI rien "1" numéro comme référence, si FAUX passe à la Condition #2
Condition #2:
B4 = ("PORTES_DYC" OU "AUTRES_DYC") ET F1 >= E4+5 si VRAI "Gms à relancer (1)", si faux passe à la Condition #3
Condition #3:
F1 >= F4+5 si VRAI "Gms à relancer (2)", si faux rien "2" numéro comme référence

Condition #1: vous dites
B4 = ("CAB_DYC" OU "ASCENSEURS_DYC") ET E4 <= F1 si VRAI rien ""
si date ,sinon "Gms à relancer"
ET
Condition #2: vous dites
B4 = ("PORTES_DYC" OU "AUTRES_DYC") ET F1 >= E4+5 si VRAI "Gms à relancer"

Donc Condition #1 si E4 > F1 = "Gms à relancer" et Condition #2 si F1 < E4+5 "Gms à relancer"
Quelle condition à la priorité?
Parce que moi je n'ai pas fais condition #1 E4 > F1.....

Bonne Journée
Noël

 

[jlzcaps238]

Bonjour,

Merci. Toutes les formules fonctionnent. Cest la dernière condition qui à la priorité.

Cdt

 

[Noel Bedard]

Bonjour,

J'ai vraiment aimé ce petit défi.
Lorsque je suis revenu pour afficher ma ligne, j'ai remarqué que les membres avaient déjà répond,
Ha, je me suis dit j'affiche quand même, juste pour préciser les conditions.

Merci
Noël