Format Image>Graphique

[allaryxavier]

Bonjour,

Après avoir créé une macro qui copie-colle un graphique, je m'aperçois que le graphique copié est devenu une image (donc par exemple quand je laisse le curseur sur un point du graphique, rien ne s'affiche).

Y-a-t-il un code pour remettre cette image en format graphique? ou un code pour copier directement le graphique sans passer par le format image?

Voici le code:

Sub Copie1()
Dim S_WK As Workbook, D_WK As Workbook
Dim S_F As Worksheet, D_F As Worksheet
Dim S_Graph As ChartObject, D_Graph As ChartObject
Set S_WK = ThisWorkbook: Set S_F = S_WK.Worksheets("Saisie 2008")
Set D_WK = Workbooks("BILAN ANNUEL 2008.xls"): Set D_F = D_WK.Worksheets("Bilan")
Application.ScreenUpdating = False
Set S_Graph = S_F.ChartObjects(1)
S_Graph.Activate

With ActiveChart
.ChartArea.Select
.CopyPicture Appearance:=xlScreen, Size:=xlScreen, Format:=xlPicture
End With
D_F.Paste D_F.Range("C5"):
Application.CutCopyMode = False
Application.ScreenUpdating = True
D_F.Activate
End Sub


Merci

 

[PMO2]

Re : Format Image>Graphique

Bonjour,

Essayez avec votre code modifié ci-dessous

Sub Copie1_pmo()
Dim S_WK As Workbook, D_WK As Workbook
Dim S_F As Worksheet, D_F As Worksheet
Dim S_Graph As ChartObject, D_Graph As ChartObject
Set S_WK = ThisWorkbook
Set S_F = S_WK.Worksheets("Saisie 2008")
Set D_WK = Workbooks("BILAN ANNUEL 2008.xls")
Set D_F = D_WK.Worksheets("Bilan")
Application.ScreenUpdating = False
Set S_Graph = S_F.ChartObjects(1)
S_Graph.Chart.ChartArea.Copy
D_F.Activate
D_F.Range("C5").Select
D_F.Paste
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub

Cordialement.

PMO
Patrick Morange

 

[allaryxavier]

Re : Format Image>Graphique

Génial!

ça marche.

En effet, même si je n'y connais pas grand chose, je remarque que mon code initial se compliquait la vie.

merci beaucoup, vous m'enlevez une belle épine du pied.

++