fonction recherche avance

[cdp095]

Bonjour,n’ayant aucune connaissance sur excel je me suis lancé un défi perso.
Je souhaite intégrer dans dans fichier excel une fonction de recherche multi paramètres sur un fichier qui contient 2 colonnes et 1636 lignes, a travers une interface graphique sobre avec un champ d'affichage des résultats trouvé. fichier joint
Merci pour votre aide.

 

[Paritec]

Re : fonction recherche avance

Bonjour Cdp095 le forum
voilà ton fichier en retour les macros doivent être activées
a+
Papou

 

[job75]

Re : fonction recherche avance

Bonjour cdp095, Papou,

"Interface graphique" hypersimple dans le fichier joint.

Simple aussi la macro :

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$D$1" Then Exit Sub
[C2] = "=ISNUMBER(SEARCH(D$1,A2))+ISNUMBER(SEARCH(D$1,B2))"
[A:B].AdvancedFilter xlFilterInPlace, [C1:C2]
[C2] = ""
End Sub

A+

 

[cdp095]

Re : fonction recherche avance

M-E-R-C-I maintenant le but c'est de reproduire tout seul ce que vous avez fait mais alors là pfeuuuuu....

 

[job75]

Re : fonction recherche avance

Re,

On peut même mettre une formule plus simple pour le critère en C2 :

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$D$1" Then Exit Sub
[C2] = "=SEARCH(D$1,A2&CHAR(1)&B2)"
[A:B].AdvancedFilter xlFilterInPlace, [C1:C2]
[C2] = ""
End Sub

Fichier (2).

A+

 

[job75]

Re : fonction recherche avance

M-E-R-C-I maintenant le but c'est de reproduire tout seul ce que vous avez fait mais alors là pfeuuuuu....

Ma solution ne nécessite pas un QI supérieur à la moyenne

A+

 

[cdp095]

Re : fonction recherche avance

Merci papou, pour votre performance,y'aurait une possibilité pour vous m’expliquiez en faite au lieu de voir apparaitre les codes de pièces d'avoir une page graphique qui les caches avec juste le bouton de recherche encore Merci ...

 

[cdp095]

Re : fonction recherche avance

Ma solution ne nécessite pas un QI supérieur à la moyenne

A+

oui mais j'ai le QI d'un bulot ....

 

[job75]

Re : fonction recherche avance

Re,

(...) en faite au lieu de voir apparaitre les codes de pièces d'avoir une page graphique qui les caches avec juste le bouton de recherche encore Merci ...

Si les "codes" ne vous intéressent pas :

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address <> "$D$1" Then Exit Sub
[C2] = "=SEARCH(D$1,B2)"
[B:B].AdvancedFilter xlFilterInPlace, [C1:C2]
[C2] = ""
Columns(1).Hidden = Target <> ""
End Sub

Fichier (3).

Mais puisque vous ne jurez que par un UserForm je vous laisse avec Papou

A+

 

[Paritec]

Re : fonction recherche avance

Bonjour Cdp095 Job le forum
est-ce que tu peux me traduire en français:

apparaitre les codes de pièces d'avoir une page graphique qui les caches avec juste le bouton de recherche

une explication dans le fichier avec si possible un résultat même obtenu manuellement
Pour la recherche elle ne se fait pas sur les noms de pièces mais sur n'importe quelle partie de le référence ou de la désignation si tu as une reférence autrefois et que tu tapes "fois" la ligne sera dans la listbox
Plus tu tapes de lettre plus la recherche s'affine mais tu verras vite que même 4 lettres suffisent a trouver ce que tu cherches
dans l'attente de ta traduction et des explications dans le fichier
a+
Papou

 

[Paritec]

Re : fonction recherche avance

Re cdp095 le forum
ou alors tu veux un truc du genre
la version 2
a+
Papou

 

[job75]

Re : fonction recherche avance

Re,

Je ne peux quitter ce fil sans cette solution avec liste déroulante (ComboBox) :

Option Compare Text 'pour ignorer la casse

Private Sub ComboBox1_Change()
Dim x$, t, e, n&, a$()
x = ComboBox1
t = Range("B2", Range("B" & Rows.Count).End(xlUp)(3)) 'au moins 2 éléments
For Each e In t
  If e <> "" And InStr(e, x) Then
    n = n + 1
    ReDim Preserve a(1 To n)
    a(n) = e
  End If
Next
If n = 0 Then ReDim a(1 To 1)
ComboBox1.List = a
ComboBox1.DropDown 'déroule la liste
End Sub

Fichier joint.

A+

 

[job75]

Re : fonction recherche avance

Re,

Je viens de remarquer qu'en colonne B il y a 52 doublons...

Pour les éliminer, utiliser l'objet Dictionary :

Option Compare Text 'pour ignorer la casse

Private Sub ComboBox1_Change()
Dim x$, t, d As Object, e
x = ComboBox1
t = Range("B2", Range("B" & Rows.Count).End(xlUp)(3)) 'au moins 2 éléments
Set d = CreateObject("Scripting.Dictionary")
For Each e In t
  If e <> "" And InStr(e, x) Then d(e) = ""
Next
If d.Count = 0 Then d("") = "" 'au moins 1 élément (vide)
ComboBox1.List = d.keys
ComboBox1.DropDown 'déroule la liste
End Sub

Fichier (2).

Edit : tiens je découvre, la ligne If d.Count = 0 Then... n'est pas indispensable.

Elle permet cependant d'effacer la ComboBox quand on clique dans la liste (vide).

A+

 

[cdp095]

Re : fonction recherche avance

Bonsoir je tiens a remercier papou et les autres pour leurs aide , je vais maintenant essayer de comprendre ce que vous avez fait merci à Tous

 

[cdp095]

Re : fonction recherche avance

Merci papou pour votre aide, mais des que je veux modifier la place du bouton recherche, ainsi que la couleur de fond de la feuille menu cela me dit que c'est protégé par un mdp et j'échoue, précision je suis sous Excel 2013
cordialement manu le bulot !