faire une copie PDF de la feuille active

[pascal21]

bonsoir le forum
j'ai une macro qui me permet de faire une copie de la zone ("A1:Y58") puis d'effacer le contenu de certaines cellules de cette même zone
j'aimerais faire une copie PDF de cette zone avec pour nommant cette copie avec le contenu de la cellule S5
comment réaliser cela si c'est possible?
je n'ai pas trouver comment faire avec l'enregistreur de macro
merci à vous
ps je ne pense pas que vous ayez besoin de fichier pour illustrer cette demande
au cas où, faites le savoir
merci

 

[pascal21]

Re : faire une copie PDF de la feuille active

re
cette fois j'ai sur 2007 sp2
document non enregistré. le document est peut-etre ouvert ou une erreur s'est produite lors de l'enregistrement
commence à etre fatigué par ce truc

 

[MJ13]

Re : faire une copie PDF de la feuille active

Re

Pascal: je ne sais pas si tu le sais, mais tu peux fournir un fichier, sinon, notre pauvre kiki ne va pas s'en sortir .

 

[pascal21]

Re : faire une copie PDF de la feuille active

si je le sais bien
mais le problème n'a pas l'air dans la compréhension de la demande,mais dans l'exécution de la macro, qui chez moi n'a pas l'air de fonctionner
quoi qu'il en soit je repasserai ce soir pour proposer un bout de fichier et on verra bien ce que ça donnera
bon après-midi

 

[kiki29]

Re : faire une copie PDF de la feuille active

Salut, S5 vide ou avec un caractère interdit "*/:<>?[\]|

Option Explicit

Sub Tst_2007()
Dim sNomDossier As String
Dim sNomFichierPDF As String

    sNomDossier = ThisWorkbook.Path
    sNomFichierPDF = Trim$(Feuil1.Range("S5"))

    If Len(sNomFichierPDF) > 0 Then
        If NomFichierValide(sNomFichierPDF) Then
            ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
                                            Filename:=sNomDossier & "\" & _
                                                      sNomFichierPDF & ".pdf", _
                                            Quality:=xlQualityStandard, _
                                            IncludeDocProperties:=True, _
                                            IgnorePrintAreas:=False, _
                                            OpenAfterPublish:=False
        Else
            Feuil1.Range("S5").Select
            MsgBox "Nom de fichier invalide", vbOKOnly + vbInformation, "Nom de Fichier"
        End If
    End If
End Sub

Private Function NomFichierValide(sChaine As String) As Boolean
Dim i As Long
Const CaracInterdits As String = """*/:<>?[\]|"

    NomFichierValide = True
    For i = 1 To Len(CaracInterdits)
        If InStr(sChaine, Mid$(CaracInterdits, i, 1)) > 0 Then
            NomFichierValide = False
            Exit Function
        End If
    Next i
End Function

Pour info il existe un SP3 pour Office 2007 : Détails du téléchargement : Suite Microsoft Office*2007 Service Pack*3 (SP3)

 

[pascal21]

Re : faire une copie PDF de la feuille active

bravo kiki, cette fois ça fonctionne très bien, si ce n'est que le contenu de la cellule s5 est une date au format 'samedi 26 novembre 2011 que j'écris comme ceci 26/11/2011 ou 26-11-2011
et ça me mets "nom non valide"

 

[pascal21]

Re : faire une copie PDF de la feuille active

non c'est bon j'écris la date comme ceci et ça fonctionne
26 11 2011 c'est du format texte mais pas grave
merci pour tout bon week end

 

[MJ13]

Re : faire une copie PDF de la feuille active

Re

bravo kiki, cette fois ça fonctionne très bien, si ce n'est que le contenu de la cellule s5 est une date au format 'samedi 26 novembre 2011 que j'écris comme ceci 26/11/2011 ou 26-11-2011

Et oui, Pascal, c'est pour cela qu'on demande souvent un fichier .

 

[kiki29]

Re : faire une copie PDF de la feuille active

Re,et voilà

Rajouter

        If IsDate(sNomFichierPDF) Then sNomFichierPDF = Replace(sNomFichierPDF, "/", " ")

    .....
    If Len(sNomFichierPDF) > 0 Then
        If IsDate(sNomFichierPDF) Then sNomFichierPDF = Replace(sNomFichierPDF, "/", " ")
        If NomFichierValide(sNomFichierPDF) Then ....