Microsoft 365 Extraire tous les caractères après des chiffres

[boza]

Bonjour,

Je n'arrive pas à extraire l'ensemble des caractères d'une cellule qui se trouve après des chiffres !

Par exemple en A1 :

Rue du Savoureulx 37350 Le Petit-Pressigny

Je voudrais que en A2 soit extrait : Le Petit-Pressigny

J'ai essayé avec droite et trouve mais impossible.

Pouvez vous m'aider pour me faire gagner plusieurs heures de travail? !

Merci d'avance

 

[D.D.]

Bonjour;

Vite fait:

=DROITE(A1;NBCAR(A1)-MAX(SIERREUR(TROUVE({0.1.2.3.4.5.6.7.8.9};A1);""))-1)

 

[boza]

Bonjour;

Vite fait:

=DROITE(A1;NBCAR(A1)-MAX(SIERREUR(TROUVE({0.1.2.3.4.5.6.7.8.9};A1);""))-1)

Tellement rapide !
Merci beaucoup !

 

[SEG]

Bonjour,

Je n'arrive pas à extraire l'ensemble des caractères d'une cellule qui se trouve après des chiffres !

Par exemple en A1 :

Rue du Savoureulx 37350 Le Petit-Pressigny

Je voudrais que en A2 soit extrait : Le Petit-Pressigny

J'ai essayé avec droite et trouve mais impossible.

Pouvez vous m'aider pour me faire gagner plusieurs heures de travail? !

Merci d'avance

 

[SEG]

Formule STXT
STXT(E8;25;21)
Contenu de E8 : Rue du Savoureulx 37350 Le Petit-Pressigny
Début de la recherche : caractère 25 (L)
Nombre de caractère : 18 (Le Petit-Pressigny)

 

[SEG]

Nombre de caractère 21 et non 18

 

[Jouxte]

Bonjour, je réouvre ce fil car la formule ne fonctionne pas avec :
33 rue de la Salle 05000 GAP = 000 Gap
Quelqu'un a-t-il une idée ?
Bonne journée à toutes et tous

 

[natorp]

Bjr le fil

Comme ça : (merci à notre regretté J. Boisgontier) :

=STXT(A1;NBCAR(A1)-EQUIV(VRAI;ESTNUM(--(STXT(A1;NBCAR(A1)-LIGNE($1:$255);1)));0)+2;99)

A valider par Maj+ctrl+entrée

Cordialement, Gérard

 

[Jouxte]

Bonjour natorp,

Merci Gérard pour cette réponse. j'aimais bien l'idée que la formule ne soit pas matricielle.
Mais est-ce possible ?

 

[Jouxte]

je viens de tester une formule qui me paraît fonctionner :

=DROITE(A1;NBCAR(A1)-(CHERCHE("µ";SUBSTITUE(A1;{0.1.2.3.4.5.6.7.8.9};"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;{0.1.2.3.4.5.6.7.8.9};"")))))-1)

 

[Hasco]

Bonjour

Vous devez avoir excel 365 si vous ne la validez pas avec CTRL+MAJ+ENTRER car votre formule est tout de même matricielle dans une version antérieure il faudrait la valider en matricielle.

Tout comme celle-ci

=DROITE(A1;NBCAR(A1)-MAX(SIERREUR(CHERCHE({0.1.2.3.4.5.6.7.8.9};A1)+1;0)))

 

[R@chid]

Bonjour @ tous,

=SUPPRESPACE(STXT(A1;EQUIV(10;--STXT(A1;SEQUENCE(NBCAR(A1));1))+1;99))

Cordialement