Extraire les caractères dès la première valeur numérique

[SOYA]

Bonjour à tous,

Je viens d'éplucher les 6 premières pages de réponses renvoyées par le moteur de recherche avec le mot "Extraire", "Extraction", "valeur numérique"... Rien trouvé qui comblerait mon besoin...

J'ai environ 75 lignes de ce type, en colonne A :

Documents d'approbation 170 jours Lun 12-06-04 Ven 13-01-25
JL & RA Plan de projet révisé 10 jours Lun 12-05-21 Ven 12-06-01
Equipe design Plans d'exécution et estimé 40 jours Lun 12-10-29 Ven 12-12-21

Je voudrais pouvoir extraire les caractères à partir de la première valeur numérique de la chaîne de caractères, par exemple "170 jours Lun 12-06-04 Ven 13-01-25"

Est-ce que c'est faisable avec une formule ?

Également, est-ce qu'il serait possible de n'extraire que le "170 jours" ou "40 jours" (sachant que "jour" n'est pas toujours au pluriel. J'ai quelques fois "1 jour" dans ma chaîne de caractères).

Merci beaucoup de votre aide !

 

[R@chid]

Re : Extraire les caractères dès la première valeur numérique

Salut,
supposant que le texte est en A1 , alors en B1 :

=GAUCHE($A1;TROUVE("jours";$A1)+4)

Amicalement

 

[SOYA]

Re : Extraire les caractères dès la première valeur numérique

Bonjour Rachid ! Je voudrais ce qui se trouve après la première valeur numérique, pas avant.
Merci de l'attention tout de même !

 

[R@chid]

Re : Extraire les caractères dès la première valeur numérique

Re,
un fichier exemple + resultats souhaites serait plus explicite...

 

[mapomme]

Re : Extraire les caractères dès la première valeur numérique

bonsoir,
Essayer cette formule (extraire le nombre de jours) ?:

=CNUM(SUPPRESPACE(DROITE(SUBSTITUE(SUPPRESPACE(GAUCHE(A1;CHERCHE("jour";A1)-1));" ";REPT(" ";"255"));255)))

 

[R@chid]

Re : Extraire les caractères dès la première valeur numérique

Salut @ tous,
toujours en B1 avec le tsexte en A1 :
voir si ca te convient :

=STXT(A1;TROUVE("+";SUBSTITUE(A1;" ";"+";2))+1;5^5)

 

[R@chid]

Re : Extraire les caractères dès la première valeur numérique

Salut @ tous,
@ ma pomme si ce qu'il cherche notre ami alors on peut refaire ta formule comm suite :

=CNUM(GAUCHE(A1;TROUVE(" ";A1)-1))

Amicalement

 

[mapomme]

Re : Extraire les caractères dès la première valeur numérique

Bonsoir à tous et à Rachid,

ou pour extraire la chaine après 'nnn jour':

=STXT(A1;CHERCHE(SUPPRESPACE(DROITE(SUBSTITUE(SUPPRESPACE(GAUCHE(A1;CHERCHE("jour";A1)-1));" ";REPT(" ";"255"));255));A1 & " jour");999)

ou pour extraite 'nnn jours' ou '1 jour':

=STXT(A1;CHERCHE(SUPPRESPACE(DROITE(SUBSTITUE(SUPPRESPACE(GAUCHE(A1;CHERCHE("jour";A1)-1));" ";REPT(" ";"255"));255)) & " jour";A1);NBCAR(SUPPRESPACE(DROITE(SUBSTITUE(SUPPRESPACE(GAUCHE(A1;CHERCHE("jour";A1)-1));" ";REPT(" ";"255"));255)) & " jour")+1)

bonsoir Rachid. J'ai considéré que le 'nnn jours' était noyé dans une phrase et ne débutait pas la phrase. Mais est-ce cela ? Comme tu l'as suggéré, un fichier serait le bienvenu!

 

[BOISGONTIER]

Re : Extraire les caractères dès la première valeur numérique

Bonjour,

Voir PJ

=STXT(A1;EQUIV(VRAI;ESTNUM(--(STXT(A1;LIGNE($1:$255);1)));0);99)
Valider avec maj+ctrl+entrée

=STXT(A1;EQUIV(VRAI;ESTNUM(--(STXT(A1;LIGNE($1:$255);1)));0);CHERCHE("jour";A1)-EQUIV(VRAI;ESTNUM(--(STXT(A1;LIGNE($1:$255);1)));0))& " Jours"
Valider avec maj+ctrl+entrée

JB

 

[SOYA]

Re : Extraire les caractères dès la première valeur numérique

Bonjour à tout ce bien beau monde

Et merci de votre aide ! Voici un fichier exemple... Je teste actuellement les dernières formules que vous avez proposées. L'exemple vous éclairera cependant mieux sur mes attentes.
Bonne journée !

 

[SOYA]

Re : Extraire les caractères dès la première valeur numérique

Boisgontier et Mapomme, vos formules fonctionnent très bien. Merci !

Pour la chaîne de date à la fin, je vais essayer avec =Droite car je crois qu'elle contient toujours le même nombre de caractères. Mais si vous voulez profiter de votre élan pour plancher là-dessus, ne vous gênez pas

Encore merci !

 

[R@chid]

Re : Extraire les caractères dès la première valeur numérique

Salut @ tous,
voir Pj avec adaptation de la premiere formule de Boisgontier.

 

[JBOBO]

Re : Extraire les caractères dès la première valeur numérique

Bonjour,

Pas vu les autres solutions mais à tester en B13 :

=GAUCHE(SUBSTITUE(STXT(A13;CHERCHE(" ";A13;CHERCHE("jour";A13)-8)+1;200);" ";" ";2);CHERCHE(" ";SUBSTITUE(STXT(A13;CHERCHE(" ";A13;CHERCHE("jour";A13)-8)+1;200);" ";" ";2);1)-1)

et en C13 :

=STXT(A13;CHERCHE(B13;A13)+1+NBCAR(B13);200)