Extraire données variables à partir de la droite d'une cellule

[nickos2406]

Bonjour,

Je n'arrive pas à résoudre un pb certainement très simple.

Dans une cellule, je dois extraire le dernier nom d'une liste de nom entrecoupés de ">".

Ca pourrait être simple avec la combinaison des fonctions droite et cherche, mais mon soucis est que le caractères > peut revenir plusieurs fois, car plusieurs noms sont marqués (nombre aléatoire)...

Ex:
Alain > Bertrand > Martine
Alain > Bertrand > Martine > Jérémy
Roger > Paulette

Pour chacune de ces lignes, je voudrais extraire le dernier nom à droite.
Connaissez-vous une combinaison de fonctions qui me permettent de parvenir à cette fin?

Merci d'avance pour votre aide
Cordialement
Nicolas

 

[david84]

Re : Extraire données variables à partir de la droite d'une cellule

Bonjour
une possibilité (si l'exemple fourni correspond bien aux données de ton fichier original) à placer en B1 avec les données à traiter en colonne A :
=DROITE(A1;EQUIV(">";STXT(A1;NBCAR(A1)-LIGNE($1:$255);1);0)-1)
Valider en appuyant simultanément sur Ctrl Maj et entrée

ou : =STXT(A1;CHERCHE(CAR(255);SUBSTITUE(A1;">";CAR(255);NBCAR(A1)-NBCAR(SUBSTITUE(A1;">";""))))+2;99)
Validation classique

 

[david84]

Re : Extraire données variables à partir de la droite d'une cellule

Si les espaces vides ne sont pas réguliers ou n'existent pas dans toutes les valeurs :
=DROITE(SUBSTITUE(A1;" ";"");EQUIV(">";STXT(SUBSTITUE(A1;" ";"");NBCAR(SUBSTITUE(A1;" ";""))-LIGNE($1:$255);1);0))
validation matricielle, ou
=STXT(SUBSTITUE(A1;" ";"");CHERCHE(CAR(255);SUBSTITUE(SUBSTITUE(A1;" ";"");">";CAR(255 );NBCAR(SUBSTITUE(A1;" ";""))-NBCAR(SUBSTITUE(SUBSTITUE(A1;" ";"");">";""))))+1;99)
Validation classique

 

[nickos2406]

Re : Extraire données variables à partir de la droite d'une cellule

Bonjour,

Merci c'est nickel!
Je ne connaissais pas ls fonctions SUBSTITUE et LIGNE...

Je vais potasser un peu pour comprendre ce qu'elles impliquent. En tout cas merci
Nicolas