exporter 2 onglets dans un même fichier pdf

[akene]

Bonjour à tous,

Je débute sur le vba et les macros.
J'ai un tableau dans lequel j'ai un devis (le nom de l'onglet est feuil1) et un bouton pour l'exporter en pdf. Jusque là pas de problème.
Je veux ajouter à ce pdf ma page de conditions générales de ventes (le nom de l'onglet est cgv), mais là je coince...

Je précise que j'aimerais ne pas passer par pdfcreator.

Pour l'instant j'ai :

Sub Bouton38_Clic()
'sauvegarde devis
Dim Fichier As String
Dim Chemin As String
Chemin = Sheets("parametre").Range("A79").Value
x = Range("D12").Value
Fichier = "devis_" & x
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
Chemin & "\" & Fichier, Quality:= _
xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
OpenAfterPublish:=False
End Sub

J'ai déjà pas mal cherché sur internet et dans les forums, mais je n'ai rien trouvé de probant (ou bien je n'ai pas réussi à le faire fonctionner)

Merci beaucoup pour votre aide.

 

[Guest]

Re : exporter 2 onglets dans un même fichier pdf

Bonjour,

Il faut sélectionner tes feuilles au préalable:

Sheets(Array("Feuil1", "Feuil2")).Select
ActiveSheet.ExportAsFixedFormat _
                Type:=xlTypePDF, _
                Filename:=ThisWorkbook.Path & "\test.pdf", _
                Quality:=xlQualityStandard, _
                IncludeDocProperties:=True, _
                IgnorePrintAreas:=False

Je te conseille fortement de définir des zones d'impression dans chaque feuille pour qu'il n'imprime pas de page vide.

A+

 

[akene]

Re : exporter 2 onglets dans un même fichier pdf

Super ! Merci pour ta réponse ! c'est parfait !

 

[kiki29]

Re : exporter 2 onglets dans un même fichier pdf

Salut, un détail , rajouter par exmple un

Sheets("Feuil1").Select

en fin de procédure pour éviter de garder la sélection des feuilles à imprimer active

 

[Guest]

Re : exporter 2 onglets dans un même fichier pdf

Re,

Puisque semble-t-il il faut aller vers le purisme:

    Dim sh As Worksheet
    Set sh = ActiveSheet
    Sheets(Array("Feuil1", "Feuil2")).Select
    ActiveSheet.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:=ThisWorkbook.Path & "\test.pdf", _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False
    sh.Select

Mais on peut toujours trouver mieux.

A+

 

[kiki29]

Re : exporter 2 onglets dans un même fichier pdf

Salut, sans parler de purisme, j'ai eu le cas d'un utilisateur qui après une impression faisait des saisies dans une des feuilles sans se rendre compte que cela se repercutait dans toutes les feuilles restées sélectionnées