export de données excel vers word a l aide de signet

[jeannot68]

Bonjour a tous


Je souhaite mettre les valeurs des cellule A4 :O4 sur un doc word ou les signets sont en place

Ma 1 ere difficulté est de savoir comment faire pour ajouter une ligne en excel pour un nouvel incident

puis comment les info vont sur les signets correspondant

comment faire pour P pettre a la personne de voir le resultat sur word par un lien hypertexte en colonne P


Merci de votre aide ca m'aiderai beaucoup ci joint les fichier correspondan
bonne journée a tous

 

[Compte Supprimé 979]

Re : export de données excel vers word a l aide de signet

Bonjour Jeannot68

Lorsque j'ouvre ton fichier Excel, j'ai beaucoup d'erreurs avec les objets incorporés.
Donc impossible à utiliser pour moi

Perso, je n'utilise pas les signets, trop chi*nt à faire, voilà le code que j'utilise
Dans ma procédure principale

  ' Créer une instance de Word
  Set AppWd = New Word.Application
  ' Ouvrir le fichier et Afficher l'application
  AppWd.Documents.Open VPath & VFic
  AppWd.Visible = True
  Set WdDoc = AppWd.ActiveDocument
  ' Sauvegarder le fichier
  VFic = "L" & MaRef & " R1 - " & NomClt & ".doc"
  WdDoc.SaveAs VPath & VFic
  ' Inscrire toutes les balises
  Ecriture_balise "TIERS", NumClt
  Ecriture_balise "REF", MaRef
  Ecriture_balise "DATE", Format(Now(), "dd/mm/yyyy")
  Ecriture_balise "NOMCLT", "TOTO"
  ' Etc ...
  ' Pour coller un tableau à partir d'Excel
  ' Se positionner sur la balise <TABLEAU>
  With AppWd.Selection.Find
    .ClearFormatting
    .Text = "<TABLEAU>"
    .MatchWildcards = False
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindContinue
  End With
  AppWd.Selection.Find.Execute
  ' Copier le tableau dans excel
  With Sheets("NomFeuille")
    DLigR = .Range("F" & Rows.Count).End(xlUp).Row
    .Range("A1:F" & DLigR).Copy
  End With
  ' Le coller dans Word
  AppWd.Selection.Paste
  'WdDoc.PrintOut Background:=True
  ' Fermer le fichier et effacer la variable objet
  'WdDoc.Close SaveChanges:=True
  Set WdDoc = Nothing
  ' Quitter l'application et effacer la variable objet
  'AppWd.Quit
  Set AppWd = Nothing

Ma procédure d'écriture des balises

'Sélection et remplacement de toutes les balises du modèle word associées à la ligne par la chaîne de caractères associée
Sub Ecriture_balise(LibBalise As String, ValBalise As String)
  Dim Balise As String
  Balise = "<" & LibBalise & ">"
  ' Remplacement de "<Balise>" par "Valeur_balise" dans le document
  WdDoc.Content.Find.Execute FindText:=Balise, ReplaceWith:=ValBalise, Replace:=wdReplaceAll  'Remplacement"
End Sub

Et dans mon fichier word j'inscrit mes balises de cette façon
<MABALISE>

Avec ça arriveras tu à t'en sortir !?

A+