Equation avec plusieurs conditions SI

[bepaturej]

Bonjour,Je dois compléter cette équation :=SI(ET(C30="PVC";C33="Chemin de Câble");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);3);SI(ET(C30="PR - EPR";C33="Chemin de Câble");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);2);SI(ET(C30="PVC";C33= "Goulotte Fermée");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);7);SI(ET(C30="PR - EPR";C33="Goulotte Fermée");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);6);SI(ET(C30="PVC";C33= "Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);5);SI(ET(C30="PR - EPR";C33="Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);4)))))))et voudrais que la condition ;C33="Enterré+Fourreau") citée dans les 2 dernieres condition SI, face référence à 2 mode de pose du genre;C33="Enterré+Fourreau"Ou"Enterré Direct" Hélas Excel ne comprend pas cette équation et de plus Excel ne peut contenir que 6 conditions SImerci de votre aide

 

[Habitude]

Re : Equation avec plusieurs conditions SI

Regarde du coté de Choisir + Equiv
Ou peut-être même sommeprod.

Difficile à voir sans fichier ni explication

 

[hoerwind]

Re : Equation avec plusieurs conditions SI

Bonjour,

Il me semble qu'il n'est pas nécessaire d'imbriquer les fonctions SI.
Teste ceci :

=SI(ET(C30="PVC";C33="Chemin de Câble");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);3);"")
&SI(ET(C30="PR - EPR";C33="Chemin de Câble");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);2);"")
&SI(ET(C30="PVC";C33= "Goulotte Fermée");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);7);"")
&SI(ET(C30="PR - EPR";C33="Goulotte Fermée");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);6);"")
& ...

 

[bepaturej]

Re : Equation avec plusieurs conditions SI

Merci Habitude et Hoerwind
Sur la proposition de Hoerwind j'ai essayé :
=SI(ET(C30="PVC";C33="Chemin de Câble");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);3);"")
&SI(ET(C30="PR - EPR";C33="Chemin de Câble");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);2);"")
&SI(ET(C30="PVC";C33="Goulotte Fermée");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);7);"")
&SI(ET(C30="PR - EPR";C33="Goulotte Fermée");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);6);"")
&SI(ET(C30="PVC";C33="Enterré Direct");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);5);"")
&SI(ET(C30="PR - EPR";C33="Enterré Direct");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);4);"")
&SI(ET(C30="PVC";C33="Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0)*0,5);"")
&SI(ET(C30="PR - EPR";C33="Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0)*0,4);"")

Hélas je ne peux écrire la dernière condition &SI(ET(C30="PR - EPR";C33="Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0)*0,4);"") l'équation est trop longue

Et là je sèche......

 

[Tibo]

Re : Equation avec plusieurs conditions SI

Bonsoir,

La taille limite des formules (jusqu'à Excel 2003) est de 1024 caractères.

Dans ton cas, on dépasse cette limite.

Mais quoiqu'il en soit, une telle formule devient vite illisible et difficile à mettre à jour.

Comme déjà indiqué, il faudrait que tu joignes ton fichier (avec explications) pour qu'on y voie plus clair.

A te (re)lire

@+

 

[hoerwind]

Re : Equation avec plusieurs conditions SI

Bonjour, salut Tibo,

Essaie en nommant chaque partie de formule (chaque SI) par le menu Insertion - Noms - Définir, puis concatène les noms attribués.

 

[bepaturej]

Re : Equation avec plusieurs conditions SI

Bonjour et merci a tous pour vous pencher sur mon problème

En pièce jointe le fichier
C'est un fichier de calcul de réseaux électriques
La formule qui me pose problème est située en cellule N29 de l'onglet "Calcul réseau HT" je dois ajouter à la fin de l'équation cette ligne :
SI(ET(C30="PVC";C33="Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);5);SI(ET(C30="PR - EPR";C33="Enterré+Fourreau");INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);4)))

Merci d'avance pour votre aide

 

[hoerwind]

Re : Equation avec plusieurs conditions SI

Bonjour,

La pièce jointe, elle est où ?

 

[bepaturej]

Re : Equation avec plusieurs conditions SI

Désolé,

j'ai oublié de la zipper

Merci en attendant

 

[hoerwind]

Re : Equation avec plusieurs conditions SI

Re,

On a ton fichier, c'est déjà ça, mais on ne sait pas où tu as mis cette formule.
Peux-tu préciser ?

 

[bepaturej]

Re : Equation avec plusieurs conditions SI

hoerwind,

La formule se trouve dans la cellule N9 de l'onglet "Calcul Reseau HT" et je dois rajouter a cette formule celle de la cellule M13 du même onglet

Merci d'avance

 

[Habitude]

Re : Equation avec plusieurs conditions SI

Si j'ai bien compris,
Tu dois a la place de toute ces SI

Mettre un Equiv pour la ligne et un Equiv pour la colonne à ton index
Donc

INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);***)

Essaie de remplacer les ***

par

=EQUIV(C30&C33;{"";"";"";"";"PR - EPREnterré Direct";"PR - EPREnterré+Fourreau";"";""};0)-1

Tu concatene C30 et C33
Tu entre dans l'ordre entre les {} tes valeurs concatener
Le equiv va te retourner la valeur
Les valeurs sont de 1 à 7 et tes colonnes de 0 à 6 c'est pourquoi les -1

ca fait
=INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);EQUIV(C30&C33;{"";"";"";"";"PR - EPREnterré Direct";"PR - EPREnterré+Fourreau";"";""};0)-1)

 

[Habitude]

Re : Equation avec plusieurs conditions SI

Bon après voir relu
Tu veux doubler colonne 4 et 5
Donc il faudra utiliser choisir

CHOISIR(EQUIV(C30& " & " & C33;{"PR - EPR & Chemin de Câble";"PVC & Chemin de Câble";"PR - EPR & Enterré+Fourreau";"PVC & Enterré+Fourreau";"PR - EPR & Enterré Direct";"PVC & Enterré Direct";"PR - EPR & Goulotte Fermée";"PVC & Goulotte Fermée"};0);2;3;4;5;4;5;6;7)

Ainsi tu peux copier la formule ci-dessous

=INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);CHOISIR(EQUIV(C30& " & " & C33;{"PR - EPR & Chemin de Câble";"PVC & Chemin de Câble";"PR - EPR & Enterré+Fourreau";"PVC & Enterré+Fourreau";"PR - EPR & Enterré Direct";"PVC & Enterré Direct";"PR - EPR & Goulotte Fermée";"PVC & Goulotte Fermée"};0);2;3;4;5;4;5;6;7))

 

[bepaturej]

Re : Equation avec plusieurs conditions SI

Habitude,

Merci pour ta réponse, j'ai complété ta formule comme ceci

=INDEX('Données tableaux'!$C$174:$I$185;EQUIV(C32;'Données tableaux'!$C$174:$C$185;0);EQUIV(C30&C33;{"PVCGoulotte Fermée";"PR - EPRGoulotte Fermée";"PVCChemin de Câble";"PR - EPRChemin de Câble";"PVCEnterré Direct";"PR - EPREnterré Direct";PVCEnterré+Fourreau";"PR - EPREnterré+Fourreau";"";""};0)-1)

J'ai du oublié quelque chose, elle ne marche

Peux-tu y jeter un oeil

Merci d'avance

 

[Habitude]

Re : Equation avec plusieurs conditions SI

REgarde la réponse en #13