Déduction du sexe

[huotg01]

Je crois qu'avec l'âge je perds mes capacités ...

J'ai un fichier Excel généalogique et je dois y ajouter une colonne "Sex".

Le format est le suivant:

Num Sex Nom Prenom Pere Mere

et un exemple du fichier est joint.

Je veux compléter la colonne "Sex" en la déduisant à partir des colonnes "Père" et "Mère". Ces colonnes contiennent le pointeur sur le Num du père et de la mère.

Votre aide sera appréciée.

Pourquoi je ne le fais pas manuellement ? Il y a 26 000 fiches à compléter.

Merci

Gaston

 

[Clochard]

Re : Déduction du sexe

Salut le forum,


Pour ma part, voici comment je m'en serais sorti


Excusez... j'ai répondu trop vite.....

Bonne nuit..

Clochard

 

[frtoussaint]

Re : Déduction du sexe

Si j'ai bien compris, tu veux déterminer le sexe d'une personne grâce au fait qu'une personne soit père ou mère.

Voici selon moi la formule à mettre dans la cellule B2 pour que ça fasse cette déduction.

=SI(ET(ESTERREUR(RECHERCHEV(A2;$F$2:$F$65000;1;FAUX));ESTERREUR(RECHERCHEV(A2;$E$2:$E$65000;1;FAUX)));"???";SI(SIERREUR(RECHERCHEV(A2;$F$2:$F$65000;1;FAUX);"H")="H";"H";"F"))

Il ne te reste plus qu'a étirer la formule à l'ensemble de la colonne b...

Cela dit, si une personne n'a pas eu d'enfant, on ne peut pas déduire son sexe. Dans cette hypothèse, ça affiche ??? dans la colonne sex. Tu devras alors parcourir ta liste de 26000 pour déterminer toi même si c'est un homme ou une femme... mais avec un filtre, ce sera facile de les retrouver.

 

[job75]

Re : Déduction du sexe

Bonjour le fil, le forum,

Formule en B2 à tirer vers le bas :

=CHOISIR(1+SIGNE(NB.SI(E:E;A2))+2*SIGNE(NB.SI(F:F;A2));"";"M";"F")

La cellule prend la valeur "" si A2 n'existe ni en colonne E ni en colonne F.

S'il existe dans ces 2 colonnes, elle prend la valeur #VALEUR! (erreur d'écriture évidemment).

Edit : version anglaise au cas où :

=CHOOSE(1+SIGN(COUNTIF(E:E,A2))+2*SIGN(COUNTIF(F:F,A2)),"","M","F")

A+

 

[abcd]

Re : Déduction du sexe

Bonjour,

En B2 : =SI(NB.SI(E$2:E$11;A2);"M";"F")
formule à copier vers le bas.

Il me semble que l'exemple n'est pas représentatif de tous les cas de figure, à moins quie je n'ai rien compris, toujours possible :
Le père de Cantin Jacques (1) est Cantin Philias (2)
Le père de Cantin Philias (2) est Cantin Frédéric (7)
Le père de Cantin Frédéric (7) est Cantin Jacques (1)
Drole de famille où le petit-fils (1) est le père de son grand-père (7)

Au cas où le père ou la mère ne serait pas spécifié :
=SI(NB.SI(E2:F11;A2)=0;"inconnu";SI(NB.SI(E$2:E$11;A2);"M";"F"))

abcd

 

[huotg01]

Re : Déduction du sexe

Merci à tous pour vos suggestions et commentaires.

Grâce à vous je vais pouvoir compléter (à tout le moins faire progresser) le chargements des 26 000 fiches généalogiques.

N.B.: effectivement le tableau soumis contient des aberrations que ne contient pas le tableau original, beaucoup plus volumineux. J'ai essayé de "faire court", et ce au détriment de l'intégrité ...

Gaston