Copier des cellules d'une page sur une autre à la suite

[vince05]

Bonjour à tous,
tout d'abord je tenais à vous félicité pour ce site qui apporte beaucoup pour les personnes novices comme moi.
J'ai un probléme que je n'arrive pas à résoudre et ceci malgré les nombreuses aide qu'il existe ici.
Le voici :
Je voudrais copier les valeurs de la page "suivi hebdomadaire" sur la page "BD ne pas toucher"
Je vous joint le fichier help je men sort pas (en faisant un petit tableau j'y arrive mais la ca depasse mes compétences) please HELP
J'ajoute le petit exemple qui marche pour comprendre le fond de mon probleme

 

[kjin]

Re : Copier des cellules d'une page sur une autre à la suite

Bonjour,
Je ne vois qu'un moyen d'éviter de copier plusieurs fois les mêmes infos, c'est de vider le suivi après transfert

Sub sel()
Dim Rgnumform As Range
With Feuil5
    If .Range("A3") = "" Then Exit Sub 'on quitte si A3 est vide
    Set Rgnumform = .Range("A3:Q" & .Range("A65536").End(xlUp).Row)
End With
With Feuil7
    dl = .Range("A65000").End(xlUp).Row + 1
    .Range("A" & dl & ":Q" & dl) = Rgnumform.Value
End With
Rgnumform.ClearContents 'on efface le suivi
End Sub

A+
kjin

 

[Papou-net]

Re : Copier des cellules d'une page sur une autre à la suite

Bonjour vince05, et bienvenue sur le site,

Peut-être qu'en modifiant ton code comme ci-dessous ?

Sub sel()
Dim Rgnumform As Range
Set Rgnumform = Feuil5.Range("A3:Q" & Feuil5.Range("A65536").End(xlUp).Row)
If Feuil7.Range("A3") = "" Then
  With Rgnumform
    .Copy Feuil7.Range("A3")
  End With
  Feuil7.Select
  Else
    With Rgnumform
    .Copy Feuil7.Range("A2").End(xlDown).Offset(1, 0)
  End With
  Feuil7.Select
End If
End Sub

Espérant avoir répondu.

Cordialement.

Edit : bonjour kjin.

 

[vince05]

Re : Copier des cellules d'une page sur une autre à la suite

Merci vous êtes des dieux avec vos deux réponses je vais pouvoir faire quelque chose de trés bien et quelle rapidité de réponse si je vous avait à mes coté je vous aurais fait une bise

 

[vince05]

Re : Copier des cellules d'une page sur une autre à la suite

Re je viens de faire des essais vos deux codes fonctionnent ils permettent bien de copier et colle à la suite dasn la feuille BD ne pas toucher mais le probleme c'est qu'il ne copie uniquement a ligne 3 si je met des valeurs dans les lignes 4 5 6 ...... elles ne sont pas copiées comment faire svp Help bis

 

[Papou-net]

Re : Copier des cellules d'une page sur une autre à la suite

Re : vince05

Tu dois modifier ton code comme suit, car il faut tenir compte du nombre de lignes incluses dans ta plage "Rgnumform" :

Sub sel()
 Dim Rgnumform As Range
 With Feuil5
     If .Range("A3") = "" Then Exit Sub 'on quitte si A3 est vide
     Set Rgnumform = .Range("A3:Q" & .Range("A65536").End(xlUp).Row)
 End With
 With Feuil7
     dl = .Range("A65536").End(xlUp).Row + 1
     .Range("A" & dl & ":Q" & dl + Rgnumform.Rows.Count - 1).Value = Rgnumform.Value
 End With
 End Sub

Ca marche, j'ai testé.

Cordialement.

 

[vince05]

Re : Copier des cellules d'une page sur une autre à la suite

Super merci j'ai modifié un petit peu le code parcque je ne voulais pas mettre le numero de la semaine sur chaque ligne en tout cas ca fonctionne je vous remercie énormement.
Mais puis-je encors abuser de vos compétences, est-il possible qu'une fois avoir cliqué sur le bouton les données s'enregistre dans la page "BD ne page toucher" comme ca fonctionne actuellement, les données de la page "suivi hebdomadaire" s'efface sans supprimer les formules des colones D G J et N, afin de laisser une page vierge prete a re saisir des données.
Eu j'espere que c clair lol en tout cas merci pour tout ca fait 2 mois que je suis dessus et je ne regrette vraiment pas de mettre inscris sur le forum que du bonheur
Je vous joint mon fichier actuel qui fonctionne

 

[Papou-net]

Re : Copier des cellules d'une page sur une autre à la suite

Re vince05,

Tu as été clair, voici donc ton code complété :

Sub sel()
  Dim Rgnumform As Range
  Dim nbLg As Integer
  With Feuil5
    If .Range("B3") = "" Then Exit Sub 'on quitte si A3 est vide
    Set Rgnumform = .Range("A3:Q" & .Range("B65536").End(xlUp).Row)
    nbLg = Rgnumform.Rows.Count
  End With
  With Feuil7
    dl = .Range("B65536").End(xlUp).Row + 1
    .Range("A" & dl & ":Q" & dl + nbLg - 1).Value = Rgnumform.Value
  End With
  Feuil5.Range("A3:Q" & nbLg + 2).SpecialCells(xlCellTypeConstants) = ""
End Sub

Cordialement.

 

[Staple1600]

Re : Copier des cellules d'une page sur une autre à la suite

Bonsoir

Par sécurité , préférez
Dim nbLg As Long
à
Dim nbLg As Integer

 

[Papou-net]

Re : Copier des cellules d'une page sur une autre à la suite

Bonsoir

Par sécurité , préférez
Dim nbLg As Long
à
Dim nbLg As Integer

Bonsoir Staple1600,

Tout-à-fait d'accord avec toi, c'est d'ailleurs ce que je fais habituellement.

Mais dans ce cas précis, j'ai utilisé Integer car je me suis dit que notre ami Vince ne renseignera jamais plus de quelques dizaines ou quelques centaines de lignes, et que la variable nbLg désigne un nombre de lignes et non des numéros de lignes.

Cordialement.

 

[vince05]

Re : Copier des cellules d'une page sur une autre à la suite

Super merci pour tout ca marche impecable je tenais à vous féliciter pour votre disponibilité et votre implication Je reviendrais vous voir avec plaisir A++