Conversion degré décimal en degré minute décimales (> 3 décimales)

[Gwass]

Bonjour,

Grace à ce forum (ce post), j'ai pu comprendre comment convertir des dégrés décimaux en dégrés minutes décimales avec la formule :
=TEXTE(A2/1440;"[m]° s,00'")

J'aurais aimé avoir plus de 3 décimales après la virgule mais j'ai une erreur en retour lorsque j'essaie ça :
=TEXTE(A2/1440;"[m]° s,0000'")

Est-ce que quelqu'un aurait une idée sur la question ?

Merci pour vos réponses !

 

[Salmander]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

Bonjour,
Le format Excel ne semble en effet pas permettre l'affichage au-delà de trois décimales. Je propose donc de recalculer les °, ' & " comme à l'époque ou les systèmes n'étaient pas automatisés :

=ENT(A2)&"°"&ENT((A2-ENT(A2))*60)&"'"&ENT((A2*60-ENT(A2*60))*60)&","&ENT((A2*3600-ENT(A2*3600))*10^5)&""""

Le nombre de décimale est défini par l'exposant de 10 en fin de formule.

 

[Gwass]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

Bonjour,

Merci Salmander, c'est parfait, ça marche très bien.

J'ai juste fait une petite modification comme je peux avoir des valeurs négatives en degré décimaux, j'ai remplacé A2 par ABS(A2).

La conversion Degré>Degré minute seconde :
= ENT(ABS(A2))&"°"&ENT((ABS(A2)-ENT(ABS(A2)))*60)&"'"&ENT((ABS(A2)*60-ENT(ABS(A2)*60))*60)&","&ENT((ABS(A2)*3600-ENT(ABS(A2)*3600))*10^6)&""""

La conversion Degré>Degré minute :
=ENT(ABS(A3))&"°"&ENT((ABS(A3)-ENT(ABS(A3)))*60)&","&ENT((ABS(A3)*60-ENT(ABS(A3)*60))*10^6)&"'"

 

[Modeste geedee]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

Bonjour,

Grace à ce forum (ce post), j'ai pu comprendre comment convertir des dégrés décimaux en dégrés minutes décimales avec la formule :
=TEXTE(A2/1440;"[m]° s,00'")

J'aurais aimé avoir plus de 3 décimales après la virgule mais j'ai une erreur en retour lorsque j'essaie ça :
=TEXTE(A2/1440;"[m]° s,0000'")

Est-ce que quelqu'un aurait une idée sur la question ?

Merci pour vos réponses !

alors essaie ça :
=TEXTE(A2/1440;"[m]°")&TEXTE(MOD(A2/1440/"0:0:1";60);"00,000000000")
tu précisera dans le dernier argument le nombre de décimales (max 15 chiffres significatifs)

 

[Gwass]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

alors essaie ça :
=TEXTE(A2/1440;"[m]°")&TEXTE(MOD(A2/1440/"0:0:1";60);"00,000000000")
tu précisera dans le dernier argument le nombre de décimales (max 15 chiffres significatifs)[/QUOTE]

Ah oui, ça marche très bien et c'est très court comme formule : merci encore !
Il faut que j'essaie de comprendre comment ça fonctionne... je suis dépassée.

Et la formule peut être adaptée pour avoir du degré minute seconde :
=TEXTE(A2/24;"[h]° m'")&TEXTE(MOD(A2/24/"0:0:1";60);"00,000000000")

 

[Salmander]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

En effet, beaucoup plus simple, je ne sais pas pourquoi, je mettais les secondes.

=ENT(A2)&"°"&ENT((A2-ENT(A2))*60)&","&ENT((A2*60-ENT(A2*60))*10^20)&"'"

Celle-ci tient 20 décimales au maximum, au delà des exposants apparaissent...

 

[job75]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

Bonjour Gwass, Salmander, Modeste geedee,

Il me semble que ceci devrait convenir aussi pour les degrés/minutes :

=ENT(A2)&TEXTE(60*MOD(A2;1);"° 0,0000'")

ou, s'il peut y avoir des valeurs négatives :

=SIGNE(A2)*ENT(ABS(A2))&TEXTE(60*MOD(ABS(A2);1);"° 0,0000'")

Pas testé car je suis en voyage et l'ordi n'a pas Excel.

NB : si le séparateur décimal est le point ne pas oublier d'écrire "° 0.0000'"

A+

 

[job75]

Re : Conversion degré décimal en degré minute décimales (> 3 décimales)

Bonjour le forum,

De retour de voyage je constate que mes 2 formules vont bien.

La 2ème peut cependant s'écrire plus simplement :

=TRONQUE(A2)&TEXTE(60*MOD(ABS(A2);1);"° 0,0000'")

Si l'on veut aussi les secondes d'arc :

=TRONQUE(A2)&TEXTE(MINUTE(ABS(A2)/24);"° 0' ")&TEXTE(60*MOD(60*MOD(ABS(A2);1);1);"0,0000''")

A+

 

[dodineau]

Bonjour,
Petit déterrage de post mais je recherchais une formule de conversion DDD vers DMS.
La formule de JOB75

=TRONQUE(A2)&TEXTE(60*MOD(ABS(A2);1);"° 0,0000'")

fonctionne bien mais si on veut aussi les secondes la formule :

=TRONQUE(A2)&TEXTE(MINUTE(ABS(A2)/24);"° 0' ")&TEXTE(60*MOD(60*MOD(ABS(A2);1);1);"0,0000''")

me donne 1 minute de trop.
par exemple pour 47.783333 la conversion donne avec la 1ere formule : 47°47.0000' et avec la 2eme formule le résultat est 47° 47' 59.9988''.
Quelqu'un aurait-il une solution pour avoir la 2eme formule correcte ?
Merci pour votre aide.
A+

 

[job75]

Bonsoir dodineau,

Après presque 10 ans c'est vraiment du réchauffé.

Mais pour afficher les degrés minutes secondes on peut utiliser simplement :

=TEXTE(A2/24;"[h]° mm' ss\""")

A+