Concaténer colonnes en utilisant les tableaux (Array)

[cathodique]

Bonjour,

Serait-il possible d'effectuer une concaténation de colonnes en utilisant les tableaux?

J'ai une BD assez conséquente (aujourd'hui + de 6000 lignes), je voudrai concaténer les valeurs des colonnes I et J avec les valeurs existantes dans la colonne B dans cette même colonne, puis supprimer les colonnes I et J.
Et ce, en utilisant les tableaux que je ne maîtrise pas du tout.

Je vous en remercie beaucoup.

Cordialement,

 

[gilbert_RGI]

Re : Concaténer colonnes en utilisant les tableaux (Array)

Bonjour

Avec VBA peut-être comme ça

se mettre sur une cellule de la colonne B et lancer la macro avec Alt +F8

Sub test()
    r = ActiveCell.Row
    ActiveCell = Cells(r, 2) & Space(50) & Cells(r, 9) & Space(50) & Cells(r, 10)
    ActiveCell.Select
    With Selection
        .HorizontalAlignment = xlCenter
        .VerticalAlignment = xlCenter
        .WrapText = True
    End With
End Sub

 

[mécano41]

Re : Concaténer colonnes en utilisant les tableaux (Array)

Bonjour à tous,

Avec ceci dans le code de la feuille. A lancer par ce que tu veux (code, bouton...)

Option Explicit
Option Base 1

Sub GroupeInfos()
Dim T As Variant
Dim T1()
Dim PlageDonn As Range
Dim Cpt As Long

Set PlageDonn = Range(Range("B8"), Range("J65536").End(xlUp))
T = PlageDonn.Value
ReDim T1(UBound(T, 1))
For Cpt = 1 To UBound(T)
    T1(Cpt) = T(Cpt, 1) & Chr(10) & T(Cpt, 8) & Chr(10) & T(Cpt, 9)
Next Cpt
Range("B8").Resize(UBound(T), 1).Value = WorksheetFunction.Transpose(T1)
Columns("I:J").Delete Shift:=xlToLeft
End Sub

Edit : si cela ne commence plus à la ligne 8 ou si ce ne sont plus les colonnes B, I et J, il faudra modifier le code...

Cordialement

 

[cathodique]

[Résolu] : Concaténer colonnes en utilisant les tableaux (Array)

Messieurs Bonjour,

Je vous remercie pour vos solutions. C'est exactement, le code que je voulais en utilisant les tableaux qui hélàs, je ne maitrise pas du tout. je pense que le code de Mécano41, sera très rapide pour les 6000 lignes présente sur ma feuille originale.

Le code de Gilbert_RGI est intéressant. Mais si je dois démarrer l’exécution pour les + de 6000 lignes, je ne serai pas sortie de l'auberge de si tôt. Mais merci quand même ça pourrait me servir sur un autre fichier.

Je vous remercie beaucoup. Toute ma gratitude.

Cordialement,

 

[cathodique]

Re : [Résolu] : Concaténer colonnes en utilisant les tableaux (Array)

Oups! Désolé une fausse manipulation, j'ai oublié la notation. C'est super!

Cordialement,