XL 2013 compter Nb jours ouvrés sur période

[mix770]

Bonjour Le Forum,

avant tout, je souhaite une bonne et heureuse année à tous

j'ai un tableau ou sont renseignés des période de travail ex: 2/01/19 au 15/03/19, j'aimerai pouvoir faire ressortir sur la tableau ou avec un TCD le nombre de jours ouvrés travaillés mois par mois.

pouvez vous m'aider pour cette demande
merci à vous
en pj un tableau

 

[Dudu2]

Bonjour,

Je ne suis pas assez familier des TCD pour t'orienter vers cette solution.
Si j'avais à traiter de ce problème, je ferais des colonnes pour chaque mois concerné par ton tableau et je donnerais comme titre à chacune de ces colonnes le mois-année concerné en format personnalisé "mmm-aa", par exemple:
en K1: janv-19
en L1: févr-19
en M1: mars-2019
etc...

Et comme formule en K2, la formule extensible à toutes les colonnes mois et à toutes les lignes concernées:
=SI([@[Date de début]]<>0;MAX(0;NB.JOURS.OUVRES(MAX([@[Date de début]];FIN.MOIS(K$1;-1)+1);MIN(FIN.MOIS(K$1;0);[@[Date de fin]])));"")

 

[Dudu2]

Tu peux aussi respecter la syntaxe "tableau" mais les formules ne sont plus copiables d'une colonne à l'autre car il faut modifier le nom de la colonne du mois.

En K2:
=SI([@[Date de début]]<>0;MAX(0;NB.JOURS.OUVRES(MAX([@[Date de début]];FIN.MOIS(Tableau1[[#En-têtes];[janv-19]];-1)+1);MIN(FIN.MOIS(Tableau1[[#En-têtes];[janv-19]];0);[@[Date de fin]])));"")

En L2
=SI([@[Date de début]]<>0;MAX(0;NB.JOURS.OUVRES(MAX([@[Date de début]];FIN.MOIS(Tableau1[[#En-têtes];[févr-19]];-1)+1);MIN(FIN.MOIS(Tableau1[[#En-têtes];[févr-19]];0);[@[Date de fin]])));"")

En M2:
=SI([@[Date de début]]<>0;MAX(0;NB.JOURS.OUVRES(MAX([@[Date de début]];FIN.MOIS(Tableau1[[#En-têtes];[mars-19]];-1)+1);MIN(FIN.MOIS(Tableau1[[#En-têtes];[mars-19]];0);[@[Date de fin]])));"")

 

[mix770]

bonjour Dudu2,

merci pour ta réponse je regarde pour mettre en application et te tiens informé
bien cordialement

 

[mix770]

dudu2,
super ça marche
merci beaucoup à toi

 

[chris]

Bonjour à tous

Si tu peux installer l'add on PowerQuery (intégré à Excel à partir de la version 2016) on peux traiter sans ajouter des colonnes à la source