Compter le nombre semaine passé sur un projet

[Babou90]

Bonjour,

J'aimerais un peu d'aide pour savoir comment compter le nombre qu'il y a de semaine dans une liste donnée.
Je récupère le nombre d'heures que mes gars pointes tous les jours sur leurs projets, j'aimerais savoir combien de semaines ont été passées sur chaque projet et combien de semaine à été passées en tout.

J'utilise actuellement des petits "1" devant chaque nouvelle semaine qui apparaît sur un TCD, cette technique n'est pas très appropriée car je veux que tout soit automatique dans mon cas.

Je pense qu'une petite formule existe bien pour faire cette petite tâche hélas je ne la connais pas

Ci joint fichier excel d'exemple

 

[hoerwind]

Re : Compter le nombre semaine passé sur un projet

Bonjour,

Essaie cette formule :
=ENT(SOMME(DROITE(B5:B13;10)-GAUCHE(B5:B13;10))/6)
à la valider en matricielle (Ctrl+Maj+Entrée)
elle renvoie 9

Quelques petites remarques :
- qu'est-ce que le nombre d'heures vient faire sous la question (nombre de semaines) ?
- il n'est pas précisé sous la question qu'il s'agit toujours de semaines entières.
- pourquoi ne pas avoir précisé qu'il s'agit de semaines de 6 jours ?
- la formule pourrait être simplifiée si les dates sous une même cellule étaient saisies dans des colonnes différentes.
- pourquoi l'exemple ne comporte-t-il que des délais d'une semaine ?

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

Quelques petites remarques :
- qu'est-ce que le nombre d'heures vient faire sous la question (nombre de semaines) ?
- il n'est pas précisé sous la question qu'il s'agit toujours de semaines entières.
- pourquoi ne pas avoir précisé qu'il s'agit de semaines de 6 jours ?
- la formule pourrait être simplifiée si les dates sous une même cellule étaient saisies dans des colonnes différentes.
- pourquoi l'exemple ne comporte-t-il que des délais d'une semaine ?

- Le nombre d'heures c'était pour préciser le contexte, le pk du comment que j'en viens à votre aide
- Il s'agira toujours de semaine entière
- C'est des semaines de 7 jours Du 24/09 au 30/09, par exemple, il y a bien 7 jours ...
- (voir fichier PJ)
- Car je veut compter le nombre de semaine passé sur chaque projet, il n'y a pas de délais, seulement des semaines du XX/XX/XXXX au YY/YY/YYYY.


J'essaie ta formule et te retiens au courant, merci.

 

[hoerwind]

Re : Compter le nombre semaine passé sur un projet

Re,

Du 24/09/2012 au 30/09/2012 il n'y a que 6 jours !

En effet : ="30/09/2012"-"24/09/2012" = 6,
parce qu'en l'absence d'heures Excel considère les heures comme étant égales à 00:00
donc : "30/09/2012 00:00"-"24/09/2012 00:00) = 6

Pour établir le calcul bornes comprises il faut ajouter 1 jour à la date de fin.
Cela peut se faire soit dans la cellule, soit dans la formule.

 

[R@chid]

Re : Compter le nombre semaine passé sur un projet

Bonjour @ tous,
Salut Hoerwind,
Voir c'est exemple si il te convient???
Amicalement

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

Super ça avance,

Je ne savais pas que excel comptait des semaines de 6 jours, quelle idée ?!?
Bref, merci Rachid, ton tableau m'aide bien.

Dans mon cas, j'utilise ce résultat, pour le synthétisé sur un graphe, j'ai essayé un truc, mais ça me donne du 8.7 pour 9 semaines, et du 0.7 pour une semaine, pas top.

Regarde et dit moi si tu peux "arrondie" ça à la semaine supérieur.

Merci pour vos réponses !

 

[hoerwind]

Re : Compter le nombre semaine passé sur un projet

Re, salut Rachid,

Je ne vois comment je pourrais mieux te l'expliquer : de la façon dont tu saisis tes dates, il faut ajouter un jour à la date de fin.

Essaie en H2 : =SI(E2="";"";ENT((G2+1-F2)/7))
formule à copier vers le bas.

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

Re tout le monde,

hoerwind, ta formule colle au poil

J'ai essayé de l'adapter à mon utilisation, pour ça une me faut mettre le tableau sur une feuille différente...

Ece que ça peut marcher ? ou alors faut il qu'il soit sur la même feuille ?? Ci joint fichier exemple.

merci de votre aide les gars

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

J'ai essayé de l'appliquer à mon fichier,

J'ai rentré les nom "Col_Otp' et "Col_Dates" dans le gestionnaire, mais ça ne fonctionne pas ...

Pour Col_Otp :

=DECALER(Pointages AE!$E$2;;;NBVAL(Pointages AE!$E:$E)-1)

Pour Col_Dates

=DECALER(Col_Otp;;5)

Quand je clique dans la référence de mon Col_Otp, il ne me montre aucunes valeur ?! Pk ? Alors que dans le fichier NbSemainev3, il me montre bien la colonne OTP.

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

Okai j'ai rectifié :

=DECALER(Pointages_AE!$E$2;;;NBVAL(Pointages_AE!$E:$E)-1)

En renommant Pointages AE par Pointage_AE

 

[hoerwind]

Re : Compter le nombre semaine passé sur un projet

Re,

Pour le fichier joint sous le message #8, en feuille 'Brassage des données'!B3, il faut valider cette formule en matricielle (Ctrl+Maj+Entrée) et le tout fonctionne fort bien.

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

OK ça fonctionne bien pour le fichier sous #8.

Par contre, dans mon fichier ia un souci, je ne voit pas d'où cela viens,

J'ai bien déclarer correctement les noms, et entrer les formules correctement, mais aucun résultat, vide, en validant bien en matricielle CTRL+MAJ+ENTREE.

Le fichier NbSemaine :

Ici les nom Col_Otp sont bleu

Ce lien n'existe plus

Mon fichier :

Ici les nom Col_Otp sont noir ... ?! un souci ?

Ce lien n'existe plus

La formule est bien en matricielle

Ce lien n'existe plus

Les nom sont bien déclarés pourtant ...

Ce lien n'existe plus

Je sèche pour ma part ... ça devrai marcher, tout est pareil...

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

Okai j'ai enfin compris l'erreur,

J'avais déclarer dans le nom "Col_Otp" une colonne contenant des lettre, donc cela renvoyait une erreur, qui était masquée pas le"SIERREUR".

Souci c'est que j'ai besoin des lettre pour identifier mon projet. ...

Voir PJ

 

[Babou90]

Re : Compter le nombre semaine passé sur un projet

Yo re all,

rien de nouveau pour m'aider ?!

Merci

 

[R@chid]

Re : Compter le nombre semaine passé sur un projet

Bonsoir @ tous,
Merci Salut Hoerwind,


Pour définir la plage Col_Otp, dans le gestionnaire de noms :

=DECALER(Données!$A$2;;;EQUIV("ZZZ";Données!$A:$A;1)-1)

La NBVAL() ici n'est pas pratique du fait qu'il y du vide dans la colonne A



En B3,

=SIERREUR(INDEX(Col_Otp;EQUIV(PETITE.VALEUR(SI((NB.SI(B$2:B2;Col_Otp)=0)*(Col_Otp<>"");NB.SI(Col_Otp;"<"&Col_Otp));1);NB.SI(Col_Otp;"<"&Col_Otp);0));"")

en C3,

=SI(B3="";"";MIN(SI((Col_Otp<>"")*(Col_Otp=B3)*(Col_Dates<>"");Col_Dates)))

en D3,

=SI(B3="";"";MAX(SI((Col_Otp<>"")*(Col_Otp=B3)*(Col_Dates<>"");Col_Dates)))

Les 3 dernières formules sont des matricielles @ tirer vers le bas

Amicalement