compter le nombre d'occurence dans une liste

[Arnaud]

Bonjour,

Voici mon problème:
J'ai une liste de personnes développée sur deux colonnes (A pour le Nom et B pour le prénom)
J'aimerai compter le nombre de personnes présentes dans cette liste sachant que:
certaines personnes différentes ont le même prénom
certaines personnes différentes ont le même nom
certaines personnes apparaissent plusieurs fois dans la liste (même nom, même prénom)

J'espère avoir été clair

Merci par avance à ceux qui se pencheront sur ce problème

 

[andré]

Salut,

A1:A100 : les noms
B1:B100 : les prenoms
C1 : =A1&' '&B1 - formule à copier vers le bas
Dans une cellule quelconque : =SOMMEPROD(1/NB.SI(C1:C100;C1:C100))

Â+

 

[JeanMarie]

Bonjour

C'est possible sans passer par une colonne intermédiaire
=SOMMEPROD((FREQUENCE(EQUIV($A$4:$A$12&$B$4:$B$12;$A$4:$A$12&$B$4:$B$12;0);LIGNE(A$1:A$10))>0)*1)-(NB.VIDE($A$4:$B$12)>0)

$A$4:$A$12 contient les noms
$B$4:$B$12 contient les prénoms
Ces deux plages peuvent avoir des cellules vides.

La plage A$1:A$10 doit toujours commencer en ligne 1 et doit être de même longueur que les plages contenant les données.

@+Jean-Marie

 

[arnaud]

Merci André,
mais un autre problème se pose alors car
ma liste de nom augmente régulièrement

lorsque j'ajoute une ligne (101,102,...) en fin de liste
ou lorsqu'il y a une ligne vide entre deux lignes de la liste

le résultat est faussé...

dans le premier cas la formule ne s'incrémente pas automatiquement de la ligne supplémentaire
dans le second cas, il y a des lignes qui ne sont plus prises en compte.

Merci d'avance pour ton aide

 

[DOMI]

BONJOUR
JE SUIS INTERRESSE PAR CETTE QUESTION SAUF
LES NOMS ET PRENOMS SONT DANS LA MEME COLONNE
COMMENT FAIT ON DANS CE CAS LA
MERCI PAR AVANCE
DOMI

 

[JeanMarie]

Bonjour Domi

Si ta plage ne contient pas de cellules vides
=SOMME(1/NB.SI(A1:A15;A1:A15))

Des cellules vides sont dans la plage.
=SOMME(SI(ESTVIDE(A1:A15);'';1/NB.SI(A1:A15;A1:A15)))
formule à valider par Ctrl+Shift+Entrer

ou dans les deux cas
=SOMMEPROD((FREQUENCE(EQUIV(A1:A15&'';A1:A15&'';0);LIGNE(A1:A15))>0)*1)-(NB.VIDE(A1:A15)>0)
même recommendation pour la plage dans la fonction LIGNE(), commence à la ligne 1 et de même longueur.

@+Jean-Marie

 

[DOMI]

Jean Marie
Ca marche
Merci
Domi

 

[pat1545.]

Salut,

Laurent Longre a écrit un truc tres rapide sur cela:

Morefunc.xll 4.02 (Excel 95, 97 SR-1/2, 2000, 2002, 2003)
téléchargeable sur :
Ce lien n'existe plus

nb.diff est là pour ça

Patrick
mais la soluce de JeanMarie est tres bien aussi bien sur
Bye