Clignotement sur 2 colonnes

[gregg5l]

Bonjour à tous.
Je vous sollicite à nouveau pour améliorer une portion de code.

Explication du code :
Dans une feuille de pointage, si pour un nom se trouvant en cellule C11, l'heure de sortie, en F11 n'est pas renseignée, C11 se met à clignoter brièvement

Sub Clignotement()

' si le contenu de F11 est vide et C11 non vide
If Range("F11").Value = "" And Range("C11").Value <> "" Then
PauseTime = 3 ' Définit la durée.
Start = Timer ' Définit l'heure de début.
Do While Timer < Start + PauseTime
Range("C11").Interior.ColorIndex = 46 ' couleur rouge
Range("C11").Interior.ColorIndex = xlNone
Loop
End If

End Sub

Je voudrais que le test se fasse sur la colonne C, de C11 à C30, et par conséquent de F11 à F30

Merci d'éclairer ma lanterne. Bon week-end à tous

 

[Eric 45]

Re : Clignotement sur 2 colonnes

Bonjour à tous

Essaie ce code :

Sub Clignotement()

' si le contenu de F11 est vide et C11 non vide
For i = 11 To 30
If Range("F" & i).Value = "" And Range("C" & i).Value <> "" Then
PauseTime = 3 ' Définit la durée.
Start = Timer ' Définit l'heure de début.
Do While Timer < Start + PauseTime
Range("C" & i).Interior.ColorIndex = 46 ' couleur rouge
Range("C" & i).Interior.ColorIndex = xlNone
Loop
End If
Next i
End Sub

A+

Eric

 

[gregg5l]

Re : Clignotement sur 2 colonnes

Bonjour eric.

Je te remercie pour les modifications que tu as apporté à cette portion de code, ça marche super bien.
C'est exactement le résultat escompté.

Encore merci à tous, ce forum est une véritable mine d'or
++

 

[JeanMarie]

Re : Clignotement sur 2 colonnes

Bonjour

Il y a d'autres possibilités tu trouveras ici
sur un superbe site.
myDearFriend! Excel Pages - Mon univers Excel... - Téléchargements

ou sur le forum
https://www.excel-downloads.com/threads/message-clignotant.39657/
Dans ce lien, il faut re-cliquer sur un lien pour avoir le fichier démo, j'aurais peut être dû mettre le lien d'origine, mais c'était supprimer le fichier démo de mdf, et des explications qui seraient utiles.

PS : Perso, je ne trouve pas l'effet aussi "beau" que ça, et attendre la fin du clignotement (maxi 1 mn) pour pouvoir saisir une donnée dans une cellule, c'est pas top.

@+Jean-Marie

 

[gregg5l]

Re : Clignotement sur 2 colonnes

Bonjour Jean Marie,

Voici le code trouvé sur le premier lien que tu as donné ci-dessus.

Option Explicit
'---------------------------------------------------------------------------------------
' Auteur : Didier FOURGEOT (myDearFriend!)
' myDearFriend! Excel Pages - Mon univers Excel... - Mon univers Excel...
' Date : 18/06/2006
' Sujet : Cellules et Alertes clignotantes
'---------------------------------------------------------------------------------------
Dim Temps As Variant

Public Sub Clign()
'Programmation de l'évènement toutes les secondes
Temps = Now + TimeValue("00:00:01")
Application.OnTime Temps, "Clign"
'Affiche l'alerte ou la fait disparaître (alternativement)
With ThisWorkbook
'Fond
With .Sheets("Fond cellule clignotant").Range("B3")
.Interior.ColorIndex = IIf(.Interior.ColorIndex = 3, xlNone, 3)
End With
'Texte
With .Sheets("Texte clignotant").Range("B3")
.Font.ColorIndex = IIf(.Font.ColorIndex = 2, 3, 2)
End With
'Commentaire
With .Sheets("Commentaire clignotant").Range("B3")
.Comment.Visible = Not .Comment.Visible
End With
'Dessin
With .Sheets("Objet Dessin clignotant")
.Shapes("Alerte").Visible = Not .Shapes("Alerte").Visible
End With
End With
End Sub

Public Sub StopClign()
On Error Resume Next
'Stoppe la gestion de l'évènement OnTime
Application.OnTime Temps, "Clign", , False
On Error GoTo 0
'Cache l'alerte
With ThisWorkbook
'Fond
.Sheets("Fond cellule clignotant").Range("B3").Interior.ColorIndex = xlNone
'Texte
.Sheets("Texte clignotant").Range("B3").Font.ColorIndex = 3
'Commentaire
.Sheets("Commentaire clignotant").Range("B3").Comment.Visible = False
'Dessin
.Sheets("Objet Dessin clignotant").Shapes("Alerte").Visible = False
End With
End Sub

C'est cool, mais comment l'adapté a une colonne complète ?
Ce serait le top.

++

 

[JeanMarie]

Re : Clignotement sur 2 colonnes

Re...

Par exemple :

 Option Explicit
'---------------------------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)
'             [URL="http://www.mdf-xlpages.com/"]myDearFriend! Excel Pages - Mon univers Excel... - Mon univers Excel...[/URL]
' Date      : 18/06/2006
' Sujet     : Cellules et Alertes clignotantes
'---------------------------------------------------------------------------------------
Dim Temps As Variant

Public Sub Clign()
Dim vCell As Range
    'Programmation de l'évènement toutes les secondes
    Temps = Now + TimeValue("00:00:01")
    Application.OnTime Temps, "Clign"
    'Affiche l'alerte ou la fait disparaître (alternativement)
    With ThisWorkbook
        'Fond
        With .Sheets("Fond cellule clignotant").Range("B3")
            .Interior.ColorIndex = IIf(.Interior.ColorIndex = 3, xlNone, 3)
        End With
        'Texte
[COLOR=Red]            For Each vCell In .Sheets("Texte clignotant").Range("C11:C30")
               If vCell <> "" And vCell.Offset(0, 3) = "" Then
                  vCell.Font.ColorIndex = IIf(vCell.Font.ColorIndex = 2, 3, 2)
               End If
            Next vCell[/COLOR]
        'Commentaire
        With .Sheets("Commentaire clignotant").Range("B3")
            .Comment.Visible = Not .Comment.Visible
        End With
        'Dessin
        With .Sheets("Objet Dessin clignotant")
            .Shapes("Alerte").Visible = Not .Shapes("Alerte").Visible
        End With
    End With
End Sub

J'ai mis en rouge la partie du code que j'ai modifié.

@+Jean-Marie

 

[gregg5l]

Re : Clignotement sur 2 colonnes

Merci Jean Marie.
Je testerais plus tard dans la journée, je dois partir au Foot.

++ Merci encore à tous