cellules contenant des nom sans chiffres

[hakimenne]

Bonsoir a Tous

j'aimerais bien que les cellules du tableau ( Pseudos Acceptés ) n'affiche que les pseudos en lettres uniquement
et les cellules qui contiennent des lettres et des chiffres sont remplacés par une cellule vide



Merci

 

[R@chid]

Re : cellules contenant des nom sans chiffres

Bonsoir,
En F5,

=SIERREUR(INDEX(D$5:D$21;PETITE.VALEUR(SI(ESTERREUR(DROITE(D$5:D$21)*1);LIGNE(INDIRECT("1:"&LIGNES(D$5:D$21))));LIGNES($5:5)));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
@ + +

 

[excfl]

Re : cellules contenant des nom sans chiffres

Bonsoir hakimenne, R@chid,

MFC :

=$B5<>CNUM(DROITE(B5;4))

S'applique à =$F$5:$F$21
excfl

 

[hakimenne]

Re : cellules contenant des nom sans chiffres

Bonjour R@chid, excfl

j'ai des problèmes a adapter la Matriciel de Rachid
la Matriciel élimine les cellules vides du tableau ( il faut conserver l'ordre des lignes )

la mise en forme n'est valide que s'il y'a un espace entre les lettres et les chiffres


Merci

 

[excfl]

Re : cellules contenant des nom sans chiffres

Re,

Bonjour R@chid, excfl
la mise en forme n'est valide que s'il y'a un espace entre les lettres et les chiffres

???

Espace ou pas espace : les seuls pseudos affichés ne contiennent que des lettres.

excfl

 

[hakimenne]

Re : cellules contenant des nom sans chiffres

Bonsoir

je vous renvois le fichier avec exemples


merci

 

[excfl]

Re : cellules contenant des nom sans chiffres

Re,

Dans ton fichier joint du post 1 : les pseudos alphanumériques comprennent à la fin des nombres de 4 chiffres (années ?).

excfl

 

[job75]

Re : cellules contenant des nom sans chiffres

Bonjour hakimenne, salut R@chid, excfl,

Formule de la MFC sur F5:F21 (police de couleur blanche) :

=SOMME(-ESTNUM(TROUVE(LIGNE($1:$10)-1;F5)))

Fichier joint.

A+

 

[job75]

Re : cellules contenant des nom sans chiffres

Re,

La formule précédente suppose que l'on ne supprime aucune des lignes 1 à 10 et qu'on n'insère pas de lignes.

Pour éviter cette contrainte utiliser INDIRECT :

=SOMME(-ESTNUM(TROUVE(LIGNE(INDIRECT("1:10"))-1;F5)))

Fichier (2).

A+

 

[job75]

Re : cellules contenant des nom sans chiffres

Re,

Bien entendu, au lieu d'une MFC, on peut entrer une formule en F5 :

=REPT(D5;NON(SOMMEPROD(-ESTNUM(TROUVE(LIGNE(INDIRECT("1:10"))-1;D5)))))

Nouveau fichier joint.

A+

 

[excfl]

Re : cellules contenant des nom sans chiffres

Re,

G5 : =RECHERCHE(9^9;--("0"&STXT(D5;MIN(CHERCHE({0.1.2.3.4.5.6.7.8.9};D5&"0 123456789"));LIGNE($1:$100))))

MFC : =$B5<>CNUM(DROITE(F5;NBCAR(G5)))

excfl

EDIT : bonjour job75