Calcul d'un acompte

[Serge]

Comment calculer les conditions suivantes:

Pour commander de travaux suite à un devis un client doit verser un acompte dans les conditions suivantes:

1 : 50% de la tranche inférieure à 1000 E

2 : 10% de la tranche comprise entre 1000 E et 15000 E

3 : 5% de la tranche excedant 15000 E

Je pense avoir trouver pour 1 et 3 (c2 etant le montant du devis)

1 : Si(c2>1000;500;c2*50/100)

2 : ????????

3 : Si(c2>15000;(c2-15000)*5/100;0)

Je bute sur la condition 2

Merci pour vos réponses

@+

 

[Jean-Marie]

Bonjour Serge

Plusieurs solutions :
=C2*SI(C2<1000;50;SI(C2>15000;5;10))%
ou
=C2*INDEX({50;10;5};EQUIV(C2;{0;1000;15001};1))%

Il doit y en avoir d'autre

@+Jean-Marie

 

[Pascal76]

Bonjour

Esayes cette formule

=SI(A1>15000;1900+(A1*0,05);SI(A1>1000;500+(A1*0,1);A1*0,5))

J'ai fait avec somme du devis en A1

Bon courage

Pascal

 

[Pascal76]

Bon Jean-Marie on se croise sur le chat et les posts ce matin

Serge aura plusieurs possibilités comme cela

Pascal

 

[JCA06]

Tu devrais avoir du succés avec ta question, les xldiens aiment bien les problème.

Je te propose une solution à base de Min et Max, après avoir nommé ta cellule contenant la valeur du devis :
= +MIN(devis;1000)*0,5 + (MIN(15000;devis)-MIN(devis;1000))*0,1 + MAX(devis-15000;0)*0,05

Avec quelques explications car ces fonctions posent souvent des problèmes au départ :
Pas de problème pour la 1ère tranche : les 50 % (= 0,5) s'appliquent sur le minimum des valeurs suivantes : le devis, ou 1 000
Pas de soucis non plus pour la dernière tranche avec la fonction max : si le devis est supérieur à 15 000, (devis-15 000) est positif et les 5 % s'appliquent dessus. Si le devis n'atteint pas 15 000, la fonction max dit qu'il faut appliquer le calcul à la plus grande valeur qui sera alors 0.

Pour la tranche du milieu, elle s'arrête à 15 000, ce que l'on obtient avec la borne MIN(15000;devis), mais il faut lui enlever la valeur de la première tranche, c'est pourquoi on retrouve le MIN(devis;1000)

 

[JCA06]

Bonjour Jean-Marie, Pascal,

Attention, il y avait des pièges, ou alors je n'ai pas compris la question.

Quand Serge dit 10 % pour la tranche 1 000 à 15 000 et 5 % pour la tranche au-dessus, je comprends, pour un devis de 20 000 :
- Tranche 0 à 1 000 x 50 % = 500
+ Tranche 1 000 à 15 000 (soit 14 000) x 10 % = 1 400
+ Tranche 15 000 à 20 000, soit 5 000 x 5 % = 250
Total 2 150

Ceci-dit, bravo pour les fonctions index / equiv que j'ai du mal à utiliser !

A plus

 

[Pascal76]

Oups

Oui c'est comme cela que je l'avais vu mais je me suis planté dans la formule

Cela donne donc

=SI(A1>15000;1900+((A1-15000)*0,05);SI(A1>1000;500+((A1-1000)*0,1);A1*0,5))

Mille pardons

Pascal

 

[JB]

Salut Serge,

moi, en tenant compte des tranches, je vois ta formule comme suit:

=SI(A1>=15000;1900+((A1-15000)*0,05);SI(A1>=1000;500+((A1-1000)*0,1);SI(A1<1000;A1*0,5)))

Tout en arrondissant tes tranches à 1000, 15000 et + de 15000.

Choisis celle que tu préfères..

A+

JB