Bouton "sauvegarder" qui ne sauvegarde pas !!

[Creepy]

Bonjour all,

Comme j'ai besoin de faire des manipulations avant de sauvegarder mon fichier Excel (Effacer la macro d'initialisation de la feuille !), j'ai fait un bouton sauvegarder.

Ce bouton efface ma macro d'initialisation (qui remet tout à 0) et m'ouvre la boite de dialogue sauvegarde.

Cependant, dans la boite de dialogue de excel, je rentre un nom de fichier, je valide, mais rien ... Pas de sauvegarde de fichier. Par contre quand je passe par l'icone "officiel" de XL, pas de problème, ma sauvegarde est bien faites !!! Je ne comprends pas pourquoi puisque je fait juste appel à la fonction de sauvegarde de Excel !! ?? !!

Merci de votre aide voila le code

++

Creepy

-------------------------------
rivate Sub BtnSAve_Click()

Dim Debut As Integer, Lignes As Integer
On Error GoTo Suite ' Si deja effacé !!!
With ThisWorkbook.VBProject.VBComponents("ThisWorkbook").codemodule
Debut = .ProcStartLine("Workbook_Open", 0)
Lignes = .ProcCountLines("Workbook_Open", 0)
.DeleteLines Debut, Lignes
End With

Suite:
Application.GetSaveAsFilename

End Sub

 

[wally]

Bonjour Creepy et le forum,

Extrait de l'aide Microsoft concernant GetSaveAsFilename
--------------------------------------------------------
Affiche la boîte de dialogue standard Enregistrer sous et lit un nom de fichier tapé par l'utilisateur sans réellement enregistrer les fichiers.

Les 5 derniers mots de la phrase suggèrent que la sauvegarde des fichiers doit être faite séparément :

MonClasseur = Application.GetSaveAsFilename

If MonClasseur <> False Then
ActiveWorkbook.SaveAs MonClasseur
End If

La boîte de dialogue "Enregistrer sous" peut également être paramétrée (p.ex. en ajoutant des filtres). Tu trouveras plus de détails dans l'aide Microsoft.


Slts

wally

 

[EMG]

Salut Wally, Crepy

La boîte de dialogue "Enregistrer sous" peut également être paramétrée voici comment à toi de l'adapter pour tes besoin.

Sub Sauvegarde_Fichier_Courant()
'EMG pour XLD février 2004
If ActiveWorkbook.Path = "" Then GoTo Original
On Error GoTo Sortir
Application.EnableEvents = False
ChDrive Left(ActiveWorkbook.Path, 1)
ChDir ActiveWorkbook.Path
Original:
Sauvegarde = Application.GetSaveAsFilename(ActiveWorkbook.Path & "\" _
& ActiveWorkbook.Name, fileFilter:="Classeur Excel (*.xls), *.xls", Title:="Bibliothèque Macros EXCEL - Sauvegarder le fichier courant")
If Sauvegarde = False Then Exit Sub
ActiveWorkbook.SaveAs Filename:=Sauvegarde, FileFormat:=xlWorkbookNormal, CreateBackup:=False, AddToMru:=True
Sortir:
Application.StatusBar = False
Application.EnableEvents = True
End Sub

@+Gérard