Besoin d'aide pour une formule

[Blek]

Bonjour à tous,
je veux créer une formule et pense être pas loin de la solution mais quelques détails me posent problèmes.
J'ai créé une liste d'agent de en colonne A. En colonne B devant chaque agent, je peux retrouver la lettre "J" que je rentre moi-même.
En colonne C je veux que s'affiche automatiquement "J1" si en colonne B j'ai "J", mais aussi qu'il s'affiche "J2" si j'ai "J" en colonne B et que j'ai déjà "J1" dans la colonne C etc...
ci-joint le fichier car c pas facile d'expliquer.
Merci d'avance pour votre aide

 

[vgendron]

Re : Besoin d'aide pour une formule

bonjour

essaie avec cette formule en C16

=SI(B16="J";"J"&NBVAL($B$15:B15)+1;"")

 

[Blek]

Re : Besoin d'aide pour une formule

Génial, merci beaucoup c'est ce qu'il me faut.

Par contre si dans la même formule je veux également intégrer des "G" et que ça me mette "G1"; "G2" etc c'est possible?
En fait cumuler plusieurs conditions avec si.
j'ai essayer j'arrive à imbriquer mais après J3 par exemple ça me met G4.

 

[Blek]

Re : Besoin d'aide pour une formule

Par contre si dans la même formule je veux également intégrer des "G" et que ça me mette "G1"; "G2" etc c'est possible?
En fait cumuler plusieurs conditions avec si.
j'ai essayer j'arrive à imbriquer mais après J3 par exemple ça me met G4.

 

[mapomme]

Re : Besoin d'aide pour une formule

Bonjour Blek, vgendron,

Un essai avec la formule suivante en C16 à tirer vers le bas :

=SI(B16="";"";B16&NB.SI($B$16:B16;B16&"*"))

nota : la formule précédente fonctionne pour n'importe quelle valeur de cellule de la colonne B. Si on veut limiter à "F" et "G", il faudra rajouter une condition. Voir la formule en colonne D :

=SI(OU(B16="G";B16="J");B16&NB.SI($B$16:B16;B16&"*");"")

 

[Blek]

Re : Besoin d'aide pour une formule

Bonjour mapomme et merci pour ta réponse. Ta deuxième formule correspond absolument à ce que je recherchais. En plus j'en ai même rajouté.
Mais j'ai encore une dernière question et ma formule sera complète.
Si en colonne B je veux mettre soit "SHR4" soit "SHR5" soit "SHR7" ou "SHR8" et que je veux quand colonne C s'affiche bien la continuité "SHR1"; "SHR2" etc... peux importe le type de "SHR" est ce que c possible?
Je te joint le fichier que j'ai modifié en D16.

 

[mapomme]

Re : Besoin d'aide pour une formule

Bonjour Blek,

(...) La deuxième formule correspond absolument à ce que je recherchais. En plus j'en ai même rajouté.
Mais j'ai encore une dernière question et ma formule sera complète.
Si en colonne B je veux mettre soit "SHR4" soit "SHR5" soit "SHR7" ou "SHR8" et que je veux quand colonne C s'affiche bien la continuité "SHR1"; "SHR2" etc... peux importe le type de "SHR" est ce que c possible? (...)

J'avoue que je n'ai sans doute pas tout compris . En tout cas, voici mon interprétation :
.
En colonne B, on peut séparer les codes en cinq types:

1. ceux qui sont invariables et dont chaque occurrence provoque la copie du code en colonne C, suffixé par le rang d'apparition en colonne B (L_incre)
2. ceux qui sont invariables et dont chaque occurrence provoque la copie du code en colonne C (L_repro)
3. ceux qui sont variables (un préfixe - constitué de caractères - suivi d'un nombre quelconque de chiffres) et dont chaque occurrence provoque la copie du préfixe en colonne C, suffixé par le rang d'apparition du préfixe en colonne B (L_nbval)
4. les codes égaux à la chaine vide qui laisse la colonne C vide également
5. Les autres codes qui laissent aussi la colonne C à vide.

Pour cela, on a créé trois listes correspondant chacune à l'un des trois premiers types ci-dessus. Chaque liste a été nommée et définie dynamiquement (liste à 98 codes max - modifiable en changeant la définition des noms):

Nom de liste	Définition de la liste
L_incre	=DECALER(Feuil1!$P$1;1;0;NBVAL(Feuil1!$P$1:$P$99)-1;1)
L_repro	=DECALER(Feuil1!$Q$1;1;0;NBVAL(Feuil1!$Q$1:$Q$99)-1;1)
L_nbval	=DECALER(Feuil1!$R$1;1;0;NBVAL(Feuil1!$R$1:$R$99)-1;1)

Enfin création d'une formule matricielle en C16 à valider par Ctrl+Maj+Entrée puis à tirer vers le bas :

 =SI(B16="";"";SI(ESTNUM(EQUIV(B16;L_incre;0));B16&NB.SI($B$16:B16;B16&"*");SI(ESTNUM(EQUIV(B16;L_repro;0));B16;SI(ESTNUM(EQUIV((SIERREUR(GAUCHE( B16;   MIN(SI(ESTNUM(0+STXT(B16;LIGNE(INDIRECT("$1:$"&NBCAR(B16)));1));LIGNE(INDIRECT("$1:$"&NBCAR(B16)));""))-1);B16)) & "*";L_nbval;0) ); (SIERREUR(GAUCHE( B16;   MIN(SI(ESTNUM(0+STXT(B16;LIGNE(INDIRECT("$1:$"&NBCAR(B16)));1));LIGNE(INDIRECT("$1:$"&NBCAR(B16)));""))-1);B16)) & NB.SI($B$16:B16;(SIERREUR(GAUCHE( B16;   MIN(SI(ESTNUM(0+STXT(B16;LIGNE(INDIRECT("$1:$"&NBCAR(B16)));1));LIGNE(INDIRECT("$1:$"&NBCAR(B16)));""))-1);B16)) & "*");""))))

 

[Blek]

Re : Besoin d'aide pour une formule

Et bien que dire... chapeau!!!
Cette formule est très difficile pour moi mais c'est tout simplement génial!
J'ai réussi à la déplacer sur mon programme et ça marche bien.
Encore un grand merci!!!