Attention au poids

[Edouard]

Bonsoir le forum

Je suis à la recherche d’une formule qui me permette de calculer rapidement une note en fonction de 2 critères.
Voir sur l’exemple ci-joint. Je pense que la formule index devrait convenir mais je n’arrive pas à la mettre en œuvre. Merci bien à celle ou celui qui pourra m’aider.

 

[Monique]

Bonjour,

Les fichier joints ne passent plus sur le forum.
Si tu veux Index Equiv et si tu as 2 critères :
1er critère à rechercher en A2:A10
1è critère à rechercher en B2:B10
Note en C2:C10
=INDEX(C2:C10;EQUIV(D1&E1;A2:A10&B2:B10;0))
Formule matricielle, à valider par ctrl, maj et entrée
(les 2 critères sont en D1 et E1)

Sans données précises, ce n'est pas facile, mais tu peux essayer ça :
=SOMMEPROD((A2:A10=D1)*(B2:B10=E1);C2:C10)
Non matriciel, à valider par la touche entrée, de façon classique.

 

[Monique]

Re,

Tu parles de poids et de 2 critères.
Tu peux avoir un critère en ligne et l'autre en colonne
De A2 à A10 : la taille
En B1, la lettre H
En C1, la lettre F
De B2 à B10 : le poids des hommes correspondant à la taille tapée en colonne A
De C2 à C10 : le poids des femmes
1er critère, la taille, en D1
2è critère, le sexe, en E1

Valeur exacte :
=INDEX(B2:C10;EQUIV(D1;A1:A10;0);EQUIV(E1;A1:C1;0))

Valeur approchée (les données des colonnes A et B doivent être triées) :
=INDEX(B2:C10;EQUIV(D1;A1:A10;1);EQUIV(E1;A1:C1;1))
=RECHERCHEH(E1;A1:C10;EQUIV(D1;A1:A10;1);1)
=RECHERCHEV(D1;A1:C10;EQUIV(E1;A1:C1;1);1)

En donnant un nom aux différentes plages utilisées par ta formule Index Equiv :
Table $B$2:$C$10
Taille $A$1:$A$10
Sexe $A$1:$C$1
=INDEX(Table;EQUIV(D1;Taille;1);EQUIV(E1;Sexe;1))

En nommant GdeTable la plage A$1:$C$10 utilisée par les formules Recherche Index :
=RECHERCHEH(E1;GdeTable;EQUIV(D1;Taille;1);1)
=RECHERCHEV(D1;GdeTable;EQUIV(E1;Sexe;1);1)

 

[Edouard]

Je pense avoir fait une erreur avec la pièce jointe.
Le tableau de la page « barème » est un abaque qui affecte une note (colonne A) a un individu en fonction de sa taille (ligne1) et de son poids matrice (B 2 : BE 22).
Exemple : pour une taille de 1,71 m et un poids de 51,3 Kg, la note sera de 7.

Cette note devra s’afficher en B 3 de la page « note » après avoir saisie la taille en A1 et le poids en B1.

J’espère que mes explications sont plus claires. Merci tout de même a Monique.