Aide syntaxe sommaire automatique

lga

XLDnaute Nouveau
Bonjour,

Je viens solliciter l'aide de pratiquants aguerris qui pourraient m'aider à me dépatouiller dans la création de code.

Pour le travail j'ai du créer un fichier excel afin de générer la création de feuilles de relevé d'heures de notre personnel sur les sites de travail.

Chaque feuille est soit affectée à un personne ( qui se rend sur plusieurs micro sites), soit affectée à un site ( gros site avec de nombreuses personnes qui travaillent conjointement).

Chaque feuille est truffée de mises en formes et de formules qui calculent des valeurs de temps standard, ce qui alourdi terriblement le poids du fichier lui même placé sur un serveur de fichiers.

j'ai donc scindé le fichier en plus 5 petits , un qui contient les grandes bases de calcul et les feuilles individuelles, quatre ( a, b, c, d) qui contiennent les feuilles "sites".

J'ai désactivé par le biais de macro les calculs automatiques car nos machines ne sont pas de première génération ( la mienne celeron 2.4 ghz 1 go) met actuellement 4-5 minutes pour procéder à un recalcul généralisé de tout l'ensemble des 5 fichiers.

Se pose le problème pour les utilisateurs quotidiens ( dont je ne fais pas partie) de trouver les feuilles dans ces 5 fichiers.
Au delà du Ctrl+f appliqué à chaque classeur, j'ai trouvé le principe du sommaire avec le lien hypertexte beaucoup plus pratique...

J'ai utilisé le code ( excellent) trouvé sur votre site, et commencé à le modifier pour mon usage.
Code:
Sub ListFeuil()
'ChrisV, mpfe
Application.ScreenUpdating = False
Set nSht = Sheets.Add(Before:=Sheets(1))
    On Error GoTo GesErr
DebProc:
    nSht.Name = "Sommaire"
    [A1] = "Liste des onglets du classeur"
        With Selection.Font
            .Bold = True
            .Size = 12
        End With
    For i = 2 To Sheets.Count
        nSht.Cells(i, 1).Value = Sheets(i).Name
        With Worksheets(nSht.Name)
            ActiveSheet.Hyperlinks.Add Anchor:=.Cells(i, 2), _
                Address:="", SubAddress:=Sheets(i).Name & "!A1", _
                    TextToDisplay:="Lien vers " & Sheets(i).Name
        End With
    Next i
    With Rows("1:1")
        .RowHeight = 40
        .VerticalAlignment = xlCenter
    End With
    [E2].Activate
    ActiveWindow.DisplayGridlines = False
    Exit Sub
GesErr:
    Application.DisplayAlerts = False
    Sheets("Sommaire").Delete
    Application.DisplayAlerts = True
    GoTo DebProc
End Sub

J'ai réussi à le replacer, à modifier la page du sommaire, pour puisse s'afficher les données des quatre autres fichiers, mais ma réussite perso s'arrête là car il m'est difficile de formuler du code que je peine à décrypter et dont je ne maîtrise pas la syntaxe.

Code:
Sub ListFeuil()
'ChrisV, mpfe
Application.ScreenUpdating = False
Set nSht = Sheets.Add(Before:=Sheets(1))
    On Error GoTo GesErr
DebProc:
    nSht.Name = "Sommaire"
    [A1] = "Liste des onglets du classeur BASE HEURES"
    [F1] = "Liste des onglets du classeur FEUILLES A"
    [K1] = "Liste des onglets du classeur FEUILLES B"
    [P1] = "Liste des onglets du classeur FEUILLES C"
    [U1] = "Liste des onglets du classeur FEUILLES D"
        Range("A1:U1").Select
        Selection.Font.Bold = True
        With Selection.Font
            .Size = 12
        End With
    For i = 2 To Sheets.Count
        nSht.Cells(i, 1).Value = Sheets(i).Name
        With Worksheets(nSht.Name)
        ActiveSheet.Hyperlinks.Add Anchor:=.Cells(i, 2), _
            Address:="", SubAddress:=Sheets(i).Name & "!A1", _
                TextToDisplay:="Lien vers " & Sheets(i).Name
        End With
    Next i
    With Rows("1:1")
        .RowHeight = 40
        .VerticalAlignment = xlCenter
    End With
    [E2].Activate
    ActiveWindow.DisplayGridlines = False
    Exit Sub
GesErr:
    Application.DisplayAlerts = False
    Sheets("Sommaire").Delete
    Application.DisplayAlerts = True
    GoTo DebProc
End Sub

Je souhaiterai modifier la portion de code affectée au listing des feuilles du classeur en cours par le listing des feuilles pour les 4 autres classeurs ouverts et répertoriés.

Code:
For i = 2 To Sheets.Count
        nSht.Cells(i, 1).Value = Sheets(i).Name
        With Worksheets(nSht.Name)
            ActiveSheet.Hyperlinks.Add Anchor:=.Cells(i, 2), _
                Address:="", SubAddress:=Sheets(i).Name & "!A1", _
                    TextToDisplay:="Lien vers " & Sheets(i).Name
        End With
    Next i
    With Rows("1:1")
        .RowHeight = 40
        .VerticalAlignment = xlCenter
    End With
    [E2].Activate
    ActiveWindow.DisplayGridlines = False
    Exit Sub

fonctionne très bien pour le classeur de base, où se trouve le sommaire, affiche les en têtes de mes futurs sommaires!

Mais qu'elle doit être la syntaxe pour affecter les valeurs des autres classeurs???

J'ai bien trouvé des éléments sur des forums ( dont celui ci) mais aucune de mes réadaptations ne fonctionne.

je suppute que dans la formule je dois remplacer
- mon "i" par une autre lettre à chaque fois.
- mon sheets.count doit comporter le nom du fichier [ Workbooks("101125-TA-LGA-FEUILLES_RELEVE_HEURES_STANDARD_SITES-A-V1.xls").Sheets.Count]
-mais que la valeur "2" doit aussi se référer à la feuille 2 de ce classeur et non de celui qui est actif or comment l'écrire.
-que mes valeurs [A1] et [E2] doivent être modifiées également ( je suppute un [F1] et un [J2]), d’ailleurs au passage si quelqu'un pouvait m'explique le rôle de E2...
-et que d'autres paramètres sont peut être à modifier...


Petit point de remarque le nom du fichier "standard A" doit être bon puisse que je déclenche son ouverture lors de l'ouverture du fichier "BASE"

Nom et adresse du fichier relevé

Code:
ChDir "\\Serveur\serveur_personnel_et_salaires\Temps_Partiels\Tableaux_heures"
    Workbooks.Open Filename:= _
        "\\Serveur\serveur_personnel_et_salaires\Temps_Partiels\Tableaux_heures\101125-TA-LGA-FEUILLES_RELEVE_HEURES_STANDARD_SITES-A-V1.xls"

je serai très reconnaissant à toute personne pouvant m'aiguiller et / ou m'expliquer comment faire car toutes mes tentatives se soldent invariablement par des rejets du débogueur:confused:

LGA
 
Dernière édition:

Dranreb

XLDnaute Barbatruc
Re : Aide syntaxe sommaire automatique

Bonjour
Trop long.
Mais n'hésitez pas à affecter vos expressions Worbook("NomDeClasseurLongCommeUnJourSansPain.xls") à des variables déclarées As Workbook pour ne pas avoir à les répeter tout le temps.
Retentez quelque chose, citez l'instruction rejetée par le débogueur, comme vous dites, avec le message qui va avec, ce que vous vouliez que ça fasse, et j'étudierai.
À+
 

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

Bonjour et merci de m'apporter un peu d'aide.

J'ai réécrit la portion de code et cette fois pas de message d'erreur :) par contre rien ne se passe :( , enfin la feuille sommaire est bien supprimée et remplacée par une nouvelle bien formatée mais le sommaire du second classeur n'apparaît pas.

Pour ce qui est des noms trop longs, je comprends et m'en excuse mais ce sont les noms exacts et qui respectent le MSD de l'entreprise, de même pour le chemin des fichiers indiqués depuis le serveur.
J'ai pris le risque de mettre les vrais noms ( chiantissimes certes), mais ce qui me sera plus facile plus tard pour replacer dans le contexte.

Pour ce qui est de la simplification, je vais peut être attendre un peu que le fichier fonctionne, et que mon niveau s'améliore parce que déjà que je ne comprends pas tout ce que je fais, pardon , trouve à droite à gauche et réemploie ...alors quant à affecter les déclarations à des variables...


Code:
    For f = 2 To Workbooks("101125-TA-LGA-FEUILLES_RELEVE_HEURES_STANDARD_SITES-A-V1.xls").Sheets.Count
        nSht.Cells(f, 1).Value = Sheets(f).Name
        With Worksheets(nSht.Name)
        ActiveSheet.Hyperlinks.Add Anchor:=.Cells(f, 2), _
            Address:="", SubAddress:=Sheets(f).Name & "!F1", _
                TextToDisplay:="Lien vers " & Sheets(f).Name
        End With
    Next f
    With Rows("1:1")
        .RowHeight = 40
        .VerticalAlignment = xlCenter
    End With
    [J2].Activate
    ActiveWindow.DisplayGridlines = False
    Exit Sub

Et encore merci
 

Dranreb

XLDnaute Barbatruc
Re : Aide syntaxe sommaire automatique

Pourquoi affectez vous le nom d'une f ième feuille de ActiveWorkbook (non précisé donc assumé) en faisant boucler f selon un nombre de feuille de Workbooks("101125-... etc. ? Est ce parce que ces deux classeurs ont le même nombre de feuilles ?
Conseils: 1) - Qualifier toujours de leurs parents les collections dont vous extrayez un membre
2) - Efforcez vous de ne l'extraire qu'une fois en affectant par un Set l'expression à une variable du type du membre, et utilisez ensuite la variable à la place de l'expression. Ça vaut pour Workbook, Worksheet et même Range.
Pour les feuilles du classeur qui porte la macro, pas besoin d'utilser de variable As Worksheet: ces objet sont déjà définis et connus du projet VBA sous le nom de leur CodeName tel qu'il figure dans les objets Excel (leur nom Excel est rappelé entre parenthèses à leur droite).

Vous pouvez même mettre des collections entières en variable. C'est moins courant mais ça marche.
Si dans votre exemple c'était bien comme je crois une feuille de l'autre classeur dont vous vouliez récupérer le nom vous pourriez mettre toute sa collection de feuilles dans une variable:
VB:
Dim SesFeuilles As Worksheets
Set SesFeuilles = Workbooks("101125-TA-LGA-FEUILLES_RELEVE_HEURES_STANDARD_SITES-A-V1.xls").Worksheets
For F = 2 To SesFeuilles.Count
        nSht.Cells(F, 1).Value = SesFeuilles(F).Name
Mais en mettant seulement
nSht.Cells(F, 1).Value = Sheets(F).Name
sans préciser de qualificateur il extrait le nom d'une feuille du classeur actif et pas de l'autre classeur.
À+
 
Dernière édition:

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

Je précise avant toute chose que je ne connais quasi rien au code bien que plutôt bon utilisateur d'Excel à côté.

Je récapitule, je cherche à obtenir un sommaire automatique en première feuille du premier classeur, d'un groupe de 5 classeurs qui seront systématiquement ouvert de concert. Il y à plus d'une centaine de feuilles au total, et selon le classement elles pourront être déplacées dans un des cinq classeurs selon nécessité, supprimées ...

Les différents classeurs n'ont pas forcement le même nombre de feuilles.

Pourquoi affectez vous le nom d'une f ième feuille de ActiveWorkbook (non précisé donc assumé) en faisant boucler f selon un nombre de feuille de Workbooks("101125-... etc. ? Est ce parce que ces deux classeurs ont le même nombre de feuilles ?

En fait si j'ai bien compris le principe de base du code de ChrisV que j'ai repris il liste le nom des feuilles d'un classeur de la feuille 1 à la feuille n.
Je cherche simplement à faire la même chose pour le classeur A de la feuille 2 à la feuille n.

Et de même pour les classeurs B, C, D.

Et comme je suis une grosse truffe dans ce domaine et que le freestyle ça ne rend pas grand chose dans l'écriture de lignes de code...

Je vais donc intégrer la nouvelle portion avec les déclarations dans mon fichier et voir ce que cela va donner. Par contre je ne pourrais donner de résultats avant lundi car les fichiers sont au travail.
 
Dernière édition:

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

Bonjour Dranreb,

Me revoila devant mon fichier

J'ai inséré la portion de code, mais ça ne semble pas changer grand chose

Faut il bien changer "worksheet" par "feuillesA" comme je l'ai fait?

Pour info je joins le code tel qu'inséré , j'ai remplacé la valeur 2 ( feuille 2) par 1 car si jamais j'arrive à faire fonctionner cela sur les 4 classeurs , je pourrais me passer d'un sommaire individualisé.

Code:
Dim FeuillesA As Worksheets
Set FeuillesA = Workbooks("101125-TA-LGA-FEUILLES_RELEVE_HEURES_STANDARD_SITES-A-V1.xls").Worksheets
For f = 1 To FeuillesA.Count
        nSht.Cells(f, 1).Value = FeuillesA(f).Name

        With FeuillesA(nSht.Name)
        FeuillesA.Hyperlinks.Add Anchor:=.Cells(f, 2), _
            Address:="", SubAddress:=Sheets(f).Name & "!F1", _
                TextToDisplay:="Lien vers " & Sheets(f).Name
        End With
    Next f
    With Rows("1:1")
        .RowHeight = 40
        .VerticalAlignment = xlCenter
    End With
    [J2].Activate
    ActiveWindow.DisplayGridlines = False
    Exit Sub

Merci encore pour l'aide.

LGA
 

Dranreb

XLDnaute Barbatruc
Re : Aide syntaxe sommaire automatique

Bonjour.
Si vous ne dites pas où ça plante et avec quel message d'erreur...
Sans dire de façon concise ce que vous voulez faire et qui ne marche pas, je ne peux faire grand chose pour vous aider.
D'autant qu'il n'y a jamais eu de fichier joint à étudier...
À+
 

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

J'ai inséré le code après la première portion relative au sommaire du premier classeur et avant le traitement des erreurs ( Exit sub et Geserr).

Si je supprime ma page de sommaire, elle est recrée dans le premier classeur,les lignes de titres sont créées, mais seul le sommaire du premier classeur est indiqué ( colonnes A, B). Le sommaire du second est vide ( colonnes F,G).
la procédure semble s'exécuter correctement, je n'ai pas de message d'erreur.

Par exemple si j'enlève le "exit sub" de la fin de la fin de la première partie j'ai une erreur d’exécution et une msgbox qui dit erreur 13 "incompatibilité de type", même chose si je le déplace après cette nouvelle portion.

Mais la pour le coup pas de message, pas de changement???...


Pour ce qui est de mettre une copie de mon tableau je suis d'accord, par contre il faut que je prenne le temps de faire sauter toutes les données "entreprise", et il est vrai que ce lundi matin, ça a plutôt été le fait du traitement des urgences...

LGA
 

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

Voila pour ce qui est du fichier, je joins la base de calculs, les autres classeurs sont composés des copies des feuilles de relevé.

j'ai juste alégé la feuille de relevé de la plupart des choses supreflues....

Pour ce qui est de mettre l'espion je veux bien, mais où, car en temps que tel, on ne peut pas dire que cela plante, c'est juste que rien ne se passe....
 

Pièces jointes

  • 101125-TA-BASE_HEURES.zip
    47.9 KB · Affichages: 37

Dranreb

XLDnaute Barbatruc
Re : Aide syntaxe sommaire automatique

vous persistez à utiliser des Sheets(f) du classeur actif.
Mettez Option Explicit en tête du module pour vous obliger à déclarer correctement toutes les variables par des Dim
Ecoutez, votre code est tellement imprécis que moi non plus je n'arrive pas à comprendre ce que vous voulez faire.
Le lien hypertexte est à mettre dans quelle plage de quelle feuille de quel classeur et doit renvoyer vers quelle cellule de quelle feuille de quel classeur ?
Il n'y pas que pour VBA qu'il faut toujours tout préciser pour que ce soit clair (au moins jusqu'à l'avoir mis une bonne fois pour toutes par Set dans des variables objets pour éviter de le répéter)
Écrivez plutôt votre boucle en commençant comme ça:
VB:
Dim Feui As Worksheet
For Each Feui In Workbooks("SITES-A-V1.xls").Worksheets
Comme ça vous n'aurez plus de variable f utilisée de travers avec des méthodes Sheets sans classeur précisé devant: vous serez obligé d'utiliser Feui comme expression Worksheet partout.
et puis enlevez le On Error Goto GesErr. Il est mal écrit de toute façon parce qu'il ne se termine pas par une instruction Resume. Pas étonnant que vois ne voyez pas d'erreur: vous les sautez !

Plus haut je vois:
With Worksheets(nSht.Name)
Complètement idiot ! rigoureusement équivalent à :
VB:
With nSht
tout simplement. Parce que l'objet qui porte le nom de l'objet x, et bien c'est l'objet x, vous comprenez ? Avec le souci de l'ambiguité en moins à cause de l'absence d'expression Workbook devant votre Workseets(...
Mais moi je ne mettrais pas de With pour si peu: je préciserais partout mon nSht devant les points.
Ce sera peut être plus clair aussi quand vous aurez déclaré d'abord:
Dim nSht As Worksheet. Ça vous fixera l'idée qu'une variable déclarée d'un certain type et correctement initalisée peut ensuite être utilisée comme expression de ce type. Et ce, partout où dans l'aide vous voyez aux rubriques "s'applique à" expession de tel type, vous pouvez toujour employer une variable de ce type correctement initialisée par un Set.
 
Dernière édition:

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

Bonsoir

Petite précision ( et au passage merci encore pour votre soutien) je conçois que le code employé soit imprécis ( j'aurai personnellement employé des termes beaucoup moins flatteurs) je prendrais presque cela pour un compliment; comme je l'ai déjà écrit plus haut je ne sais pas coder ( et quand je dis je ne sais pas il ne faut pas lire "je suis un amateur en code et je cherche à progresser", il faut bien lire "je ne connais rien à rien en code et programmation, je n'en ai jamais fait et je ne suis pas sûr que je puisse apprendre en quelques minutes glanées au fil des heures de mon travail, je souhaiterais certes apprendre et évoluer mais c'est le fruit certain de nombreuses heures de travail et d'acharnement, choses dont je n'ai pas disposé jusqu’à présent, et là j'ai un p***** de fichier à faire fonctionner" .

Sachez que je ne m'en tête en rien ,c'est juste que les indications que vous m'apportez, vous semblent certainement limpides, mais que pour quelqu'un qui est en bute à du code pour la première fois ,il m'est très difficile de formuler les besoins en employant le jargon informatique ( et j’emploie ce terme à bon escient) et que comprendre ce que vous désirez / souhaitez comme modification n'est pas si simple, il me faut intégrer le concept,savoir comment rédiger, et pour atteindre un résultat hypothétique à mes yeux.

C'est un peu comme si demain matin vous souhaitiez que j'écrive une dissertation en caractères cyrilliques sans avoir étudié les langues slaves, j'aurai et vous le conviendrez certainement quelques difficultés...
Par contre et j'ignore quelles sont vos compétences / appétences, mais si vous me demandez de vous organiser un transport, de vous quantifier des charges machines, de procéder à des gains logistiques ou tout couillon de gerber une palette dont le pied serait à douze mètres, là je pense que je suis votre homme et que l'on pourra se placer sur un terrain d'égalité et s'entendre sur une méthodologie commune et raisonnée.

Et je ne m’apitoie pas ni ne m'énerve , j'explique calmement :cool: ...


Le code initial n'est pas de moi je le répète je cherche juste à l'adapter à mes besoins.


Mon niveau en Excel me permet tout juste de créer des formules ( que vous pourrez visualiser en partie dans la feuille modèle du classeur), mais qui me semblent être le fait d'un utilisateur de niveau honnête.

Pour ce qui est de mon besoin c'est très simple (si vous ne me demandez pas de le formuler en code info).

Je me trouve avec 5 classeurs liés , un qui me sert de base de données, les quatre autres détiennent des séries de feuilles de relevés.

le code de ChrisV ( trouvé sur ce même site je crois ) permet de récupérer le nom des feuilles d'un classeur et de les lister en générant des liens dans une feuille nommée sommaire qui sera placée en tête du classeur.

Un bouton permet de générer le sommaire

Il doit bien exister une méthode pour lister de la même façon les feuilles d'autres classeurs ( spécifiquement désignés et juste ceux là ) et qui placera ces listes dans la même page sommaire du premier classeur à coté des autres liens ( cf fichier). Pour permettre à l'utilisateur lambda d'aller directement à la bonne feuille parmi la centaine sans devoir faire un Ctrl + F dans chaque classeur...


Demain je reprends l'ensemble des conseils que vous m'avez apporté et je tâche d'essayer de comprendre les bases avec un bouquin que je me suis procuré ( une bible vba pour office, d’ailleurs pour info j'ai eu le temps d'en compulser une 20 aine de pages en trois ans à mon grand dam - loisirs compris-) ; ça me permettra de mieux cerner les problématiques exposées ou tout du moins de traduire et de comprendre les interactions des variables, les expressions, les déclarations...et surtout de savoir de quoi vous me parlez.

Parce que pour l'instant force est de reconnaitre que je n'y comprends rien malgré toute ma bonne volonté et la qualité de vos explications !!!
 
Dernière édition:

Dranreb

XLDnaute Barbatruc
Re : Aide syntaxe sommaire automatique

Oui, là je comprends mieux.
je vais vous écrire une procédure capable de mettre un tel sommaire dans le classeur actif.
d'abord la liste des feuilles du classeur actif, puis à sa droite les listes des feuilles de tous les classeurs ouverts avec confirmation pour chacun.

Voilà le code:
VB:
Sub EtablirLiens()
Dim FSmr As Worksheet, L As Long, Feui As Worksheet, C As Long, Clas As Workbook
On Error Resume Next
ActiveWorkbook.Worksheets("Sommaire").Activate
If Err = 0 Then
   If MsgBox("Ce classeur possède déja une feuille ""Sommaire""." _
      & "Voulez vous la remplacer ?", vbYesNo + vbQuestion, "Établir les Liens") = vbNo Then Exit Sub
   On Error GoTo 0
   Application.DisplayAlerts = False
   ActiveSheet.Delete
   Application.DisplayAlerts = True
   End If
On Error GoTo 0
Set FSmr = ActiveWorkbook.Worksheets.Add(Before:=ActiveWorkbook.Sheets(1))
FSmr.Name = "Sommaire"
FSmr.Cells(2, 2).Value = "Ce Classeur"
L = 3
For Each Feui In ActiveWorkbook.Worksheets
   If Feui.Name <> "Sommaire" Then
      L = L + 1
      FSmr.Hyperlinks.Add Anchor:=FSmr.Cells(L, 2), Address:="", _
         SubAddress:="'" & Feui.Name & "'!$A$1", TextToDisplay:=Feui.Name
      End If
   Next Feui
FSmr.Columns.AutoFit
C = 2
For Each Clas In Workbooks
   If Clas.Name <> ActiveWorkbook.Name Then
      If MsgBox("Voulez vous ajouter les liens vers les feuilles de """ & Clas.Name & """ ?", _
         vbYesNo + vbQuestion, "Établir les Liens") = vbYes Then
         C = C + 1
         FSmr.Cells(2, C).Value = Replace(Clas.Name, ".xls", "")
         L = 3
         For Each Feui In Clas.Worksheets
            L = L + 1
            FSmr.Hyperlinks.Add Anchor:=FSmr.Cells(L, C), Address:=Clas.FullName, _
               SubAddress:="'" & Feui.Name & "'!$A$1", TextToDisplay:=Feui.Name
            Next Feui
         End If
      End If
   FSmr.Columns.AutoFit
   Next Clas
End Sub
Que cela ne vous dispense pas d'étudier comment ça marche.
À+
 
Dernière édition:

lga

XLDnaute Nouveau
Re : Aide syntaxe sommaire automatique

Bonjour

Et tout d'abord MERCI!

je ne le dis pas je le crie....

Ça fonctionne parfaitement...je suis soufflé...

Je serais effectivement à proprement parler incapable de faire cela. Je viens de prendre une fournée de rendez vous pour aujourd'hui, mais des demain je tâche de décortiquer tout cela pour au moins comprendre à défaut de pouvoir refaire.

Il manque tout de même un point celui de signer votre œuvre.

PS mes collègues vous remercie au passage.

Très cordialement .

LGA
 
Haut Bas